Fclm_BankAccountGroupNode

@EndUserText.label: 'Nodes of Selected Bank Account Group'
@AbapCatalog.sqlViewName: 'BNKACCTGRPNODE' 
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER
define view Fclm_BankAccountGroupNode 
// leaf nodes are selected with bank account IDs and hierarchy names

as select from I_BankAccountHierarchyNode as nodes
association[0..*] to I_BankAccountHierarchyText as _Text on $projection.BankAccountHierarchy = _Text.BankAccountHierarchy
{
  nodes.BankAccountInternalID,
  nodes.BankAccountHierarchy,
  _Text   
  
} where nodes.BankAccountInternalID <> '0000000000' --select all the leaf nodes

union all
// all the accounts are selected with hierarchy name *. The bank account IDs are duplicated, so that all the nodes can be selected without hierarchy name but with *.

select from I_BankAccount as bam
association[0..*] to I_BankAccountHierarchyText as _Text on $projection.BankAccountHierarchy = _Text.BankAccountHierarchy
{
  bam.BankAccountInternalID,
  cast('*' as abap.char( 12 )) as BankAccountHierarchy, -- * stands for all nodes
  _Text
}