FMLV_MLAUFCRH_UCT_UNION

@AbapCatalog.sqlViewName: 'FMLAUFCRHUCTSDM'
@EndUserText.label: 'History table for summerized MLAUFCR data w. correct CURPT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST,#UNION]
define view FMLV_MLAUFCRH_UCT_UNION
  as select from    mlaufcrldh    as MLD
    left outer join finsv_unique_cvtyps as curr on  curr.ext_curtype = MLD.ext_curtype
                                          and curr.rldnr       = MLD.rldnr
{
  key mlvnr,
  key vgabe,
  key gjahr,
  key belnr,
  key buzei,
  key kalnr,
  key sumdno,
  key curr.curtype as curtp,
      waers,
      shkzg,
      wrbtr,
      arewr,
      reewr,
      cast( '01' as fins_ml_sdm_version ) as sdm_version
}

union all

select from       mlaufcrh                 as MLCRH
  inner join      mlorderhist              as hist     on hist.mlvnr = MLCRH.mlvnr
  inner join      aufk                     as aufk     on aufk.aufnr = hist.aufnr
  left outer join fmlv_external_curtype_ml as curtp_ml on  curtp_ml.rbukrs      = aufk.bukrs
                                                       and curtp_ml.ext_curtype = MLCRH.curtp
  left outer join finsv_unique_cvtyps      as curtp    on  (     curtp.ext_curtype = MLCRH.curtp
                                                             and curtp.rldnr       = curtp_ml.rldnr )
                                                       or  (     MLCRH.curtp = '00' 
                                                             and curtp.curtype = '00' )
                                                       
                                                       
                                                       
{
  key MLCRH.mlvnr,
  key vgabe,
  key gjahr,
  key belnr,
  key buzei,
  key kalnr,
  key sumdno,
  key curtp.curtype as curtp,
      MLCRH.waers,
      shkzg,
      wrbtr,
      arewr,
      reewr,
      sdm_version
}
where
  sdm_version < '01';