FINOC_SPL_DC_OI

@AbapCatalog.sqlViewName: 'FINOCV_SPL_DC_OI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'OrgChg: Document chains to reconstruct'
define view FINOC_SPL_DC_OI
  as select distinct from fagl_splinfo    as s

    inner join            bkpf            as h  on  s.mandt = h.mandt
                                                and s.bukrs = h.bukrs
                                                and s.belnr = h.belnr
                                                and s.gjahr = h.gjahr

    inner join            bseg            as i  on  s.mandt = i.mandt
                                                and s.bukrs = i.bukrs
                                                and s.belnr = i.belnr
                                                and s.gjahr = i.gjahr
                                                and s.buzei = i.buzei

    left outer join       finoc_split_wl as wl on  wl.mandt = s.mandt
                                               and wl.bukrs = s.bukrs
                                               and wl.belnr = s.belnr
                                               and wl.gjahr = s.gjahr
{
  h.bvorg as bvorg,
  s.bukrs as bukrs,
  s.belnr as belnr,
  s.gjahr as gjahr,
  s.buzei as buzei,
  h.budat as budat,
  i.augdt as augdt,
  i.auggj as auggj,
  i.augbl as augbl,
  i.augcp as augcp,
  i.rebzg as rebzg,
  i.rebzt as rebzt,
  i.rebzz as rebzz,
  i.rebzj as rebzj,
  i.koart as koart,
  h.cpudt as cpudt,
  h.cputm as cputm
}

where   i.xopvw                   =  'X'
  and ( i.koart                   =  'K'
   or   i.koart                   =  'D'  ) // no OI managed G/L accounts

  and   h.glbtgrp                 <> '1'    // no CO documents

  and   wl.status                 is null
  and   s.prctr                   is not initial
  and ( s.prctr_drvtn_source_type is initial

   or ( s.prctr_drvtn_source_type = 'KS' and   s.kostl is initial  )                         // Cost Center

   or ( s.prctr_drvtn_source_type = 'MA' and ( s.matnr is initial or s.werks is initial ) )  // Material

   or ( s.prctr_drvtn_source_type = 'PR' and   s.ps_psp_pnr is initial )                     // Project

   or ( s.prctr_drvtn_source_type = 'PD' and   s.ps_psp_pnr is initial )                     // Project

   or ( s.prctr_drvtn_source_type = 'VB' and ( s.kdauf is initial or s.kdpos is initial ) )  // Sales order item

   or ( s.prctr_drvtn_source_type = 'VX' and ( s.kdauf is initial or s.kdpos is initial ) )  // Sales order item

   or ( s.prctr_drvtn_source_type = 'OR' and   s.aufnr is initial )                          // Order or Network

   or ( s.prctr_drvtn_source_type = 'NP' and   s.aufnr is initial )                          // Order or Network

   or ( s.prctr_drvtn_source_type = 'NV' and ( s.aufpl is initial or s.aplzl is initial ) )  // Network Activity

   or ( s.prctr_drvtn_source_type = 'NV' and   s.nplnr is initial )                          // Network Activity

   or ( s.prctr_drvtn_source_type = 'NP' and   s.nplnr is initial )                          // Network

   or ( s.prctr_drvtn_source_type = 'IS' and   s.imkey is initial )                          // Real Estate Contract

      )

group by
  h.bvorg,
  s.bukrs,
  s.belnr,
  s.gjahr,
  s.buzei,
  h.budat,
  i.augdt,
  i.auggj,
  i.augbl,
  i.augcp,
  i.rebzg,
  i.rebzt,
  i.rebzz,
  i.rebzj,
  i.koart,
  h.cpudt,
  h.cputm