FGL_LIB_P_DOC_HEADER

@AbapCatalog.sqlViewName: 'FILIBPDOCH'
@EndUserText.label: 'Parked Items: Document Header'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST, #UNION]
--@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck:#NOT_REQUIRED
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #L,
  dataClass: #MIXED
}
define view FGL_LIB_P_DOC_HEADER
  as select from    vbkpf
    inner join      t001                on t001.bukrs = vbkpf.bukrs
    left outer join FINS_T001A as t001a on t001a.bukrs = vbkpf.bukrs
    left outer join bkpf                on bkpf.bukrs = vbkpf.ausbk
                                       and bkpf.belnr = vbkpf.belnr
                                       and bkpf.gjahr = vbkpf.gjahr
{
  key vbkpf.belnr,
  key vbkpf.bukrs,
  key vbkpf.gjahr,
  key vbkpf.ausbk,

      vbkpf.waers             as currkey_0d,
      vbkpf.hwaer             as currkey_10,

      cast(
        case
          when  t001a.curtp = '11' then vbkpf.hwae2
          when  t001a.curtp2 = '11' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_11 )
        as currkey_11,

      cast(
        case
          when  t001a.curtp = '12' then vbkpf.hwae2
          when  t001a.curtp2 = '12' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_12 )
        as currkey_12,

      cast(
        case
          when  t001a.curtp = '30' then vbkpf.hwae2
          when  t001a.curtp2 = '30' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_30 )
        as currkey_30,

      cast(
        case
          when  t001a.curtp = '31' then vbkpf.hwae2
          when  t001a.curtp2 = '31' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_31 )
        as currkey_31,

      cast(
        case
          when  t001a.curtp = '32' then vbkpf.hwae2
          when  t001a.curtp2 = '32' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_32 )
        as currkey_32,

      cast(
        case
          when  t001a.curtp = '40' then vbkpf.hwae2
          when  t001a.curtp2 = '40' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_40 )
        as currkey_40,

      cast(
        case
          when  t001a.curtp = '50' then vbkpf.hwae2
          when  t001a.curtp2 = '50' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_50 )
        as currkey_50,

      cast(
        case
          when  t001a.curtp = '60' then vbkpf.hwae2
          when  t001a.curtp2 = '60' then vbkpf.hwae3
          else  ''
        end
      as fagl_currkey_11)
        as currkey_60,

      //fiscal year period

      cast(
        concat(concat(vbkpf.gjahr, '0'), vbkpf.monat)
      as rsfiscper )
        as fiscper,

      // fields from T001A

      t001a.curtp             as curtp,
      t001a.curtp2            as curtp2,

      // fields from vbkpf and bkpf

      bkpf.adisc,
      vbkpf.aedat,
      bkpf.arcid,
      --vbkpf.ausbk,
      vbkpf.awkey,
      bkpf.aworg_rev,
      bkpf.awref_rev,
      vbkpf.awsys,
      vbkpf.awtyp,
      vbkpf.basw2,
      vbkpf.basw3,
      bkpf.belnr_sender,
      vbkpf.bktxt,
      vbkpf.blart,
      vbkpf.bldat,
      vbkpf.brnch,
      vbkpf.bstat,
      vbkpf.budat,
      bkpf.bukrs_sender,
      vbkpf.bvorg,
      bkpf.cash_alloc,
      bkpf.co_alebn,
      bkpf.co_belnr_sender,
      bkpf.co_refbt,
      bkpf.co_valdt,
      bkpf.co_vrgng,
      vbkpf.cpudt,
      vbkpf.cputm,
      vbkpf.ctxkrs,
      vbkpf.curt2,
      vbkpf.curt3,
      bkpf.dbblg,
      bkpf.doccat,
      bkpf.dokid,
      bkpf.duefl,
      vbkpf.fikrs,
      bkpf.follow_on,
      @Semantics.amount.currencyCode: 'CURRKEY_0D'
      vbkpf.frath,
      bkpf.gjahr_sender,
      bkpf.glbtgrp,
      bkpf.glvor,
      vbkpf.grpid,
      vbkpf.hwae2,
      vbkpf.hwae3,
      vbkpf.hwaer,
      bkpf.iblar,
      bkpf.intsubid,
      bkpf.kokrs_sender,
      vbkpf.kur2x,
      vbkpf.kur3x,
      vbkpf.kurs2,
      vbkpf.kurs3,
      vbkpf.kursf,
      bkpf.kurst,
      vbkpf.kursx,
      vbkpf.kuty2,
      vbkpf.kuty3,
      bkpf.kzkrs,
      bkpf.kzwrs,
      vbkpf.ldgrp,
      bkpf.logsystem_sender,
      vbkpf.lotkz,
      vbkpf.monat,
      vbkpf.numpg,
      bkpf.ppdat,
      bkpf.ppnam,
      bkpf.pptcod,
      bkpf.pptme,
      vbkpf.propmano,
      vbkpf.reindat,
      bkpf.reprocessing_status_code,
      bkpf.resubmission,
      bkpf.rldnr,
      bkpf.stblg,
      vbkpf.stgrd,
      bkpf.stjah,
      vbkpf.stodt,
      bkpf.subset,
      vbkpf.tcode,
      vbkpf.txkrs,
      vbkpf.umrd2,
      vbkpf.umrd3,
      vbkpf.upddt,
      vbkpf.usnam,
      vbkpf.vatdate,
      vbkpf.wwert,
      vbkpf.xblnr,
      bkpf.xblnr_alt,
      vbkpf.xmca,
      vbkpf.xmwst,
      bkpf.xnetb,
      vbkpf.xref1_hd,
      bkpf.xref2_hd,
      bkpf.xreorg,
      bkpf.xreversal,
      bkpf.xreversed,
      bkpf.xreversing,
      bkpf.xrueb,
      vbkpf.xsnet,
      bkpf.xsplit,
      bkpf.xstov,
      bkpf.xusvr,
      bkpf.xwvof,

      // fields from T001

      t001.ktopl              as ktopl
}

where bkpf.bstat = 'V'