FCLM_BAM_ACC_SIGNATORY_DETAILS

DDL: FCLM_BAM_ACC_SIGNATORY_DETAILS SQL: VFCLMBASIGDET Type: view

Bank Account Signatory Details

FCLM_BAM_ACC_SIGNATORY_DETAILS is a CDS View that provides data about "Bank Account Signatory Details" in SAP S/4HANA. It reads from 2 data sources (I_BankAccountSignatoryGroup, I_UserContactCard) and exposes 11 fields with key fields BankAccountInternalID, Sequence, Signatory, SignatoryGroup.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
I_BankAccountSignatoryGroup SigGroup left_outer
I_UserContactCard User left_outer

Parameters (3)

NameTypeDefault
P_KeyDate datum
P_Currency waers
P_ExchangeRateType kurst_curr

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName VFCLMBASIGDET view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Bank Account Signatory Details view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MASTER view
Metadata.ignorePropagatedAnnotations true view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.compiler.compareFilter true view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY BankAccountInternalID AccountSignatory BankAccountInternalID
KEY Sequence AccountSignatory Sequence
KEY Signatory AccountSignatory Signatory
KEY SignatoryGroup AccountSignatory SignatoryGroup
SignatoryPattern AccountSignatory SignatoryPattern
SignatoryGroupName I_BankAccountSignatoryGroup SignatoryGroupName
Currency
BankAcctSignatoryStartDate AccountSignatory BankAcctSignatoryStartDate
BankAcctSignatoryEndDate AccountSignatory BankAcctSignatoryEndDate
MinimumPaymentCurrency
EmailAddress I_UserContactCard EmailAddress 
@AbapCatalog.sqlViewName: 'VFCLMBASIGDET'
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #REQUIRED  
@EndUserText.label: 'Bank Account Signatory Details'
@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory:   #L,
    dataClass:      #MASTER
  }
}
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE 
@AbapCatalog.compiler.compareFilter: true
define view FCLM_BAM_ACC_SIGNATORY_DETAILS 
with parameters
    P_KeyDate: datum,
    P_Currency: waers,
    P_ExchangeRateType: kurst_curr
as select distinct from FCLM_BAM_ACC_SIG_TF as AccountSignatory
left outer join I_UserContactCard as User on User.ContactCardID = AccountSignatory.Signatory
left outer join I_BankAccountSignatoryGroup as SigGroup on AccountSignatory.SignatoryGroup = SigGroup.SignatoryGroup
{
    key AccountSignatory.BankAccountInternalID,
    key AccountSignatory.Sequence,
    key AccountSignatory.Signatory,
    key AccountSignatory.SignatoryGroup,  
    AccountSignatory.SignatoryPattern,
    SigGroup.SignatoryGroupName,
    @Semantics.currencyCode:true 
    :P_Currency as Currency,
    AccountSignatory.BankAcctSignatoryStartDate,
    AccountSignatory.BankAcctSignatoryEndDate,
    @Semantics.amount.currencyCode: 'Currency'
    currency_conversion( amount => AccountSignatory.MaximumPaymentAmount,
    source_currency => AccountSignatory.Currency,
    round => 'X',
    exchange_rate_type => :P_ExchangeRateType,
    target_currency => :P_Currency,
    exchange_rate_date => :P_KeyDate,
    error_handling => 'SET_TO_NULL' )
    as MaximumPaymentAmount,
    @Semantics.amount.currencyCode: 'Currency'
    currency_conversion( amount => AccountSignatory.MaximumPaymentBatchAmount,
    source_currency => AccountSignatory.Currency,
    round => 'X',
    exchange_rate_type => :P_ExchangeRateType,
    target_currency => :P_Currency,
    exchange_rate_date => :P_KeyDate,
    error_handling => 'SET_TO_NULL' )
    as MaximumPaymentBatchAmount,
    @Semantics.currencyCode:true
    :P_Currency as MinimumPaymentCurrency,
    @Semantics.amount.currencyCode: 'Currency'
    currency_conversion( amount => AccountSignatory.MinimumPaymentAmt,
    source_currency => AccountSignatory.MinimumPaymentCurrency,
    round => 'X',
    exchange_rate_type => :P_ExchangeRateType,
    target_currency => :P_Currency,
    exchange_rate_date => :P_KeyDate,
    error_handling => 'SET_TO_NULL' )
    as MinimumPaymentAmt,
    @Semantics.amount.currencyCode: 'Currency'
    currency_conversion( amount => AccountSignatory.MinimumPaymentBatchAmount,
    source_currency => AccountSignatory.MinimumPaymentCurrency,
    round => 'X',
    exchange_rate_type => :P_ExchangeRateType,
    target_currency => :P_Currency,
    exchange_rate_date => :P_KeyDate,
    error_handling => 'SET_TO_NULL' )
    as MinimumPaymentBatchAmount,
    User.EmailAddress    
}
where BankAcctSignatoryStartDate <= :P_KeyDate and BankAcctSignatoryEndDate >= :P_KeyDate

Learn More