FCLM_BAL_ACCT_SETTING_DETAILS

@AbapCatalog.sqlViewName: 'VBACCTSETDET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank Account Setting Details'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
define view FCLM_BAL_ACCT_SETTING_DETAILS as select from FCLM_BAL_ACCOUNT_SETTINGS as setting
left outer join I_BankAccount     as _Account                   on  setting.BankAccountInternalID = _Account.BankAccountInternalID                       
left outer join I_BankAccountText as _AccountText on setting.BankAccountInternalID = _AccountText.BankAccountInternalID
                                                                    and _AccountText.Language = $session.system_language
association [0..1] to I_SingleActiveHouseBankAccount as _HouseBankAccount on setting.BankAccountInternalID = _HouseBankAccount.BankAccountInternalID
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_CountryText as _Country on $projection.BankCountry = _Country.Country and _Country.Language = $session.system_language
association [0..1] to I_CurrencyText as _Currency on $projection.BankAccountCurrency = _Currency.Currency and _Currency.Language = $session.system_language
association [0..1] to I_Bank as _Bank on $projection.BankCountry = _Bank.BankCountry and $projection.Bank = _Bank.BankInternalID
association [0..1] to I_BankAccountTypeText as _BankAccountTypeText on $projection.BankAccountType = _BankAccountTypeText.BankAccountType and _BankAccountTypeText.Language = $session.system_language
association [0..1] to I_BankAccountStatus as _BankAccountStatus on $projection.BankAccountStatus = _BankAccountStatus.BankAccountStatus and _BankAccountStatus.Language = $session.system_language
association [0..1] to I_User as _LastChangeUser on $projection.LastChangedByUser = _LastChangeUser.UserID
association [0..1] to I_CashBalancePostingTypeText  as _BankStatementPostingType  on  $projection.BankStatementPostingType = _BankStatementPostingType.BankStatementPostingType
                                                                                    and _BankStatementPostingType.Language   = $session.system_language
association [0..1] to I_CashBalanceTransferModeText as _BankStatementTransferMode on  $projection.BankStatementTransferMode = _BankStatementTransferMode.BankStatementTransferMode
                                                                                    and _BankStatementTransferMode.Language   = $session.system_language
association [0..1] to I_BankStmntSettingSourceText as _SettingSource on  $projection.BankStatementSettingSource = _SettingSource.BankStatementSettingSource
                                                                                    and _SettingSource.Language   = $session.system_language
association [0..1] to I_IntradayBkStmntPostgTxt  as _IntradayBSPostingType  on  $projection.IntradayBankStatementPosting = _IntradayBSPostingType.IntradayBankStatementPosting
                                                                                    and _IntradayBSPostingType.Language   = $session.system_language
association [0..1] to I_BankStatementForwardingText  as _BankStatementForwardingType  on  $projection.BankStatementForwardingType = _BankStatementForwardingType.BankStatementForwardingType
                                                                                    and _BankStatementForwardingType.Language   = $session.system_language                                                                                                                                                                       
{
      key setting.BankAccountInternalID,
      setting.ValidityStartDate,
      setting.ValidityEndDate,
      setting.BankStatementPostingType,
      setting.IntradayBankStatementPosting,
      setting.BankStatementForwardingType,
      setting.BankStatementTransferMode,
      setting.BankStatementSettingSource,
      setting.SpecificSettingIsEnabled,
      setting.ManualInputBalanceIsEnabled,
      setting.ExcelImportBalanceIsEnabled,
      setting.InternalAPIBalanceIsEnabled,            
      _Account.CompanyCode,
      _Account.BankCountry,
      _Account.Bank,
      _Account.BankAccountCurrency,
      _Account.BankAccountType,
      _Account.BankAccountStatus,
      _Account.BankAccountNumber,   
      _AccountText.BankAccountDescription,
      setting.LastChangedByUser,
      _LastChangeUser.UserDescription,
      setting.LastChangeDateTime,      
      _CompanyCode.CompanyCodeName,
      _Country.CountryShortName,
      _Currency.CurrencyShortName,   
      _Bank.BankName,
      _BankAccountTypeText.BankAccountTypeText,
      _BankAccountStatus.BankAccountStatusName,      
      _HouseBankAccount.HouseBank,
      _HouseBankAccount.HouseBankAccount,
      _BankStatementPostingType.BankStatementPostingTypeText,
      _IntradayBSPostingType.IntradayBkStatementPostingText,
      _BankStatementForwardingType.BankStatementForwardingText,
      _BankStatementTransferMode.BankStatementTransferModeText,
      _SettingSource.BankStatementSettingSourceText,      
      _CompanyCode,
      _Country,
      _Currency,
      _Bank,
      _BankAccountTypeText,
      _BankAccountStatus,
      _LastChangeUser,
      _HouseBankAccount,
      _BankStatementPostingType,
      _BankStatementTransferMode,
      _IntradayBSPostingType,
      _BankStatementForwardingType,
      _SettingSource      
}