FAC_DART_Z3_CHARTOFACCOUNTS

@AbapCatalog.sqlViewName: 'FAC_DZCHOFACC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Chart Of Accounts Master'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D

define view FAC_DART_Z3_CHARTOFACCOUNTS
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : sylangu
  as select from I_CompanyCode
    inner join   I_GLAccountInChartOfAccounts on I_CompanyCode.ChartOfAccounts = I_GLAccountInChartOfAccounts.ChartOfAccounts
    inner join   I_GLAccountInCompanyCode     on  I_GLAccountInChartOfAccounts.GLAccount = I_GLAccountInCompanyCode.GLAccount
                                              and I_CompanyCode.CompanyCode              = I_GLAccountInCompanyCode.CompanyCode
  association [0..1] to I_ChartOfAccounts as _ChartOfAccounts      on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [0..*] to I_GLAccountText   as _GLAccountText        on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts
                                                                   and $projection.GLAccount       = _GLAccountText.GLAccount
  association [0..*] to I_GLAccountText   as _CountryGLAccountText on  $projection.CountryChartOfAccounts = _CountryGLAccountText.ChartOfAccounts
                                                                   and $projection.AlternativeGLAccount   = _CountryGLAccountText.GLAccount
  association [0..1] to I_CostElement     as _CostElement          on  $projection.ControllingArea = _CostElement.ControllingArea
                                                                   and $projection.GLAccount       = _CostElement.CostElement

{
  key I_GLAccountInChartOfAccounts.GLAccount,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key I_GLAccountInCompanyCode.CompanyCode,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      I_GLAccountInChartOfAccounts.ChartOfAccounts,
      _ChartOfAccounts._Text[1:Language = $parameters.P_Language].ChartOfAccountsName,

      _GLAccountText[1:Language = $parameters.P_Language].GLAccountName,
      _GLAccountText[1:Language = $parameters.P_Language].GLAccountLongName,


      @ObjectModel.foreignKey.association: '_GLAccountGroup'
      I_GLAccountInChartOfAccounts.GLAccountGroup,
      _GLAccountGroup._GLAccountGroupText[1:Language = $parameters.P_Language].AccountGroupName,
      @ObjectModel.foreignKey.association: '_GlobalCompany'
      I_GLAccountInChartOfAccounts.PartnerCompany,
      I_GLAccountInChartOfAccounts.AccountIsMarkedForDeletion,
      I_GLAccountInChartOfAccounts.AccountIsBlockedForPlanning,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      I_GLAccountInChartOfAccounts.FunctionalArea,


      I_GLAccountInCompanyCode.HouseBank,
      I_GLAccountInCompanyCode.HouseBankAccount,
      I_GLAccountInCompanyCode.ExchRateDifferencesAccountDetn,
      @ObjectModel.foreignKey.association: '_Reconciliationaccttype'
      I_GLAccountInCompanyCode.ReconciliationAccountType,
      @EndUserText.label: 'Reconciliation Account Type Name'
      _Reconciliationaccttype._Text[1:Language = $parameters.P_Language].ReconciliationAccountTypeName,
      @ObjectModel.foreignKey.association: '_TaxCategory'
      I_GLAccountInCompanyCode.TaxCategory,
      _TaxCategory._Text[1:Language = $parameters.P_Language].TaxCategoryName,
      I_GLAccountInCompanyCode.InterestCalculationCode,
      I_GLAccountInCompanyCode.GLAccountCurrency,
      I_GLAccountInCompanyCode.SupplementIsAllowed,
      I_GLAccountInCompanyCode.IsOpenItemManaged,
      I_GLAccountInCompanyCode.InterestCalculationDate,
      I_GLAccountInCompanyCode.IntrstCalcFrequencyInMonths,

      @ObjectModel.foreignKey.association: '_CountryGLAccountText'
      I_GLAccountInCompanyCode.AlternativeGLAccount,
      I_GLAccountInCompanyCode.TaxCodeIsRequired,
      I_GLAccountInCompanyCode.BalanceHasLocalCurrency,
      I_GLAccountInCompanyCode.ClearingIsLedgerGroupSpecific,
      I_GLAccountInCompanyCode.CreationDate,
      I_GLAccountInCompanyCode.CreatedByUser,

      I_CompanyCode.CountryChartOfAccounts,
      @EndUserText.label: 'CS G/L account short text (country/region specific)'
      _CountryGLAccountText[1:Language = $parameters.P_Language].GLAccountName     as AlternativeGLAccountName,
      @EndUserText.label: 'CS G/L account long text (country/region specific)'
      _CountryGLAccountText[1:Language = $parameters.P_Language].GLAccountLongName as AlternativeGLAccountLongName,


      @EndUserText.label: 'System Client'
      $session.client                                                              as SystemClient,
      I_GLAccountInChartOfAccounts.IsBalanceSheetAccount,
      I_GLAccountInChartOfAccounts.GLAccountType,


      I_CompanyCode.ControllingArea,
      _CostElement.CostElementCategory,
      _CostElement.UnitOfMeasure,
      _CostElement.ConsumptionQtyIsRecorded,

      _ChartOfAccounts,
      _GLAccountGroup,
      I_GLAccountInChartOfAccounts._GlobalCompany,
      _FunctionalArea,
      _GLAccountText,
      _CountryGLAccountText,
      _CompanyCode,
      _Reconciliationaccttype,
      _TaxCategory
}