FAC_CDS_FSV_VERSION

@AbapCatalog.sqlViewName: 'FACV_FSV_VERSION'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.dataMaintenance: #DISPLAY_ONLY
//@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #S
}
@EndUserText.label: 'Universal Financial Statement Version'
define view FAC_CDS_FSV_VERSION
  as select from    t011
    left outer join t011t          on  t011.versn  = t011t.versn
                                   and t011t.spras = $session.system_language
    left outer join uhm_hier_id_ov on t011.versn = uhm_hier_id_ov.hier_old_id

{
  t011.versn                       as VersionId,
  t011t.vstxt                      as VersionDescription,
  cast('' as vdtfm )               as ValidityStartDate,
  cast('' as vdtto )               as ValidityEndDate,
  cast(t011.versn as fi_fsv_versn) as Version
}
where
          t011.versn                     not like '$%'
  and(
          uhm_hier_id_ov.hier_type       is null
    or(
          uhm_hier_id_ov.hier_type       = 'FSVN'
      and uhm_hier_id_ov.hier_mig_status <> 'M'
    )
  )

union select from uhdt_vrsn as version
  left outer join uhdt_hier as hier on  version.hier_hid  = hier.hier_hid
                                    and version.hier_catg = hier.hier_catg
                                    and hier.lang         = $session.system_language
{
  cast(version.hier_hid as versn_011 )                                                                                                  as VersionId,
  cast(hier.hier_desc as vstxt_011t )                                                                                                   as VersionDescription,
  version.ver_vldfm                                                                                                                     as ValidityStartDate,
  version.ver_vldto                                                                                                                     as ValidityEndDate,
  cast( concat(concat(version.hier_hid, concat('(',version.ver_vldfm) ), concat(concat('~',version.ver_vldto), ')') ) as fi_fsv_versn ) as Version
}
where
      version.hier_catg  = 'FSVN'
  and version.ver_status = 'A'
  and version.locked_by is initial