FAA_CompDrvdAreaSplitNum

@AbapCatalog.sqlViewName: 'FAAVPDASN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Compare Derived Area Split Number'

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XXL

define view FAA_CompDrvdAreaSplitNum
  as select from faat_doc_it                 as doc_it
    inner join   I_DepreciationAreaForLedger as CalculatedDeprAreaForLedger on  doc_it.bukrs = CalculatedDeprAreaForLedger.CompanyCode
                                                                            and doc_it.afabe = CalculatedDeprAreaForLedger.AssetDepreciationArea
    inner join   I_AssetValuationView        as AssetValuationView          on  CalculatedDeprAreaForLedger.AssetValuationView = AssetValuationView.AssetValuationView
                                                                            and AssetValuationView.AssetValuationViewType      = 'C01'
    inner join   acdoca                      as acdoca                      on  doc_it.bukrs      = acdoca.rbukrs
                                                                            and doc_it.anln1      = acdoca.anln1
                                                                            and doc_it.anln2      = acdoca.anln2
                                                                            and doc_it.gjahr      = acdoca.gjahr
                                                                            and doc_it.awtyp      = acdoca.awtyp
                                                                            and doc_it.awref      = acdoca.awref
                                                                            and doc_it.aworg      = acdoca.aworg
                                                                            and doc_it.awsys      = acdoca.awsys
                                                                            and doc_it.subta      = acdoca.subta
                                                                            and doc_it.afabe      = acdoca.afabe
                                                                            and doc_it.slalittype = acdoca.slalittype
  //and doc_it.drcrk      = acdoca.drcrk

{
  key doc_it.bukrs,
  key doc_it.anln1,
  key doc_it.anln2,
  key doc_it.gjahr,
  key doc_it.awtyp,
  key doc_it.awref,
  key doc_it.aworg,
  key doc_it.awsys,
  key doc_it.subta,
  key doc_it.afabe,
  key doc_it.slalittype,
  key doc_it.drcrk,
  key cast( '000' as poper preserving type )                   as poper,
      @EndUserText.label: 'Source table'
      @EndUserText.quickInfo: 'Source table'
  key cast( 'DOC_IT              ' as char20 preserving type ) as source_table,
      cast( count( * ) as int4 preserving type )               as counter
}
group by
  doc_it.bukrs,
  doc_it.anln1,
  doc_it.anln2,
  doc_it.gjahr,
  doc_it.awtyp,
  doc_it.awref,
  doc_it.aworg,
  doc_it.awsys,
  doc_it.subta,
  doc_it.afabe,
  doc_it.slalittype,
  doc_it.drcrk

union all select from faagtt_plan_val as plan_values
  inner join          acdoca          as acdoca on  plan_values.bukrs      = acdoca.rbukrs
                                                and plan_values.anln1      = acdoca.anln1
                                                and plan_values.anln2      = acdoca.anln2
                                                and plan_values.gjahr      = acdoca.gjahr
                                                and plan_values.afabe      = acdoca.afabe
                                                and plan_values.poper      = acdoca.depr_period
                                                and plan_values.slalittype = acdoca.slalittype
{
  key plan_values.bukrs,
  key plan_values.anln1,
  key plan_values.anln2,
  key plan_values.gjahr,
  key cast( '     ' as awtyp preserving type )                 as awtyp,
  key cast( '          ' as awref preserving type )            as awref,
  key cast( '          ' as aworg preserving type )            as aworg,
  key cast( '          ' as awsys preserving type )            as awsys,
  key cast( '000000' as fins_subta preserving type )           as subta,
  key plan_values.afabe,
  key plan_values.slalittype,
  key cast( ' ' as shkzg preserving type )                     as drcrk,
  key plan_values.poper,
      @EndUserText.label: 'Source table'
      @EndUserText.quickInfo: 'Source table'
  key cast( 'PLAN_VALUES         ' as char20 preserving type ) as source_table,
      cast( count( * ) as int4 preserving type )               as counter
}
group by
  plan_values.bukrs,
  plan_values.anln1,
  plan_values.anln2,
  plan_values.gjahr,
  plan_values.afabe,
  plan_values.slalittype,
  plan_values.poper