ESH_ACTIVITYTYPE_BASIS

@AbapCatalog.sqlViewName: 'ESHACTIVITYTYPEB'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@EndUserText.label: 'Basis view for ESH ActivityType'
@Metadata.ignorePropagatedAnnotations: true
define view ESH_ACTIVITYTYPE_BASIS
  as select from I_CostCenterActivityType

  association [0..1] to ESH_N_USER_USER     as _EnteredByUser                 on  $projection.EnteredByUser = _EnteredByUser.bname

  association [0..1] to I_UnitOfMeasure     as _CostCtrActyTypeOutpQtyUnit    on  $projection.CostCtrActivityTypeOutpQtyUnit = _CostCtrActyTypeOutpQtyUnit.UnitOfMeasure

  association [0..*] to ESH_N_XFELD_3_XFELD as _ActivityTypeIsBlockedText     on  $projection.ActivityTypeIsBlocked = _ActivityTypeIsBlockedText.domvalue_l

  association [0..1] to dd07t               as _CostCenterActivityTypeCatText on  $projection.CostCtrActivityTypeCategory = _CostCenterActivityTypeCatText.domvalue_l
                                                                              and _CostCenterActivityTypeCatText.domname  = 'LATYP'

  association [1..1] to tka01               as _ControllingArea               on  $projection.ControllingArea = _ControllingArea.kokrs

{
  key ControllingArea,
  key CostCtrActivityType,
  key ValidityEndDate,
      ValidityStartDate,
      _Text[ 1:Language = $session.system_language ].CostCtrActivityTypeName,
      _Text[1:Language = $session.system_language].CostCtrActivityTypeDesc,
      CostCtrActivityTypeQtyUnit,
      _UnitOfMeasure._Text[1:Language = $session.system_language].UnitOfMeasureName,
      CostCtrActivityTypeValidCat,
      CostCtrActivityTypeCategory,
      _CostCenterActivityTypeCatText[1:ddlanguage = $session.system_language].ddtext             as CostCtrActivityTypeCatName,
      AllocationCostElement,
      _ControllingArea.ktopl                                                                     as ChartOfAccounts,
      CreationDate,
      EnteredByUser,
      _EnteredByUser._TO_USER_NAME.name_text                                                     as FullName,

      PriceAllocationMethod,
      ActualPriceAllocationMethod,
      ActivityTypeIsBlocked,
      _ActivityTypeIsBlockedText[ 1: DOMALANGU = $session.system_language ].VALUE_TEXT           as ActivityTypeIsBlockedName,

      CostCtrActivityTypeOutpQtyUnit,
      _CostCtrActyTypeOutpQtyUnit._Text[1:Language = $session.system_language].UnitOfMeasureName as CostCtrActyTypeOutpQtyUnitName,
      OutputQuantityFactor,

      _Text,
      _ControllingArea,
      _CostCenterCategory,
      _CostCtrActivityTypeCategory,
      _CostCenterActivityTypeCatText,
      _UnitOfMeasure,
      _ControllingAreaText,
      _EnteredByUser,
      _ActivityTypeIsBlockedText
}