C_WorkCenterObjPgCap

@AbapCatalog.sqlViewName: 'CWRKCNROBJPGCAP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Work Center Object Page Capacities'
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'CapacityInternalID'
@ObjectModel.semanticKey: ['CapacityInternalID']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}

define view C_WorkCenterObjPgCap

  as select from I_Capacity as _Capacity

  //   Convert CapacityQuantity from S -> database value

  association [0..1] to I_Wrkcntrobjpgtimeunitconv as _UconfCapform on  _UconfCapform.StandardWorkQuantityUnit1 = 'S'
                                                                    and _UconfCapform.StandardWorkQuantityUnit2 = _Capacity.CapacityQuantityUnit

{
      @UI.hidden: true
  key CapacityInternalID,
      @UI.lineItem:{position: 10}
      @UI.identification: [{position:10}]
      @ObjectModel.text.element: 'CapacityCategoryName'
      CapacityCategoryCode,
      CapacityResponsiblePlanner,
      case FactoryCalendar
                          when '' then _Capacity._Plant.FactoryCalendar
                            else FactoryCalendar
                        end                                                                                                                        as  FactoryCalendar,
      @UI.hidden
      _CapacityCategory._Text[1:Language=$session.system_language].CapacityCategoryName                                                            as  CapacityCategoryName,
      -- StartTimeSec converted in Format HH:MM
      @UI.identification: [{position:20}]
      @EndUserText.label: 'Start Time'
      cast(
        concat(
            concat(
                  right(concat('0',cast(floor(div(CapacityStartTime,3600)) as sstring)),2),
                  right(concat('0',cast(floor(div(mod(CapacityStartTime,3600),60)) as sstring)),2)
                ),
                right(concat('0',cast(floor(mod(mod(CapacityStartTime,3600),60)) as sstring)),2)
            )  as abap.tims)                                                                                                                       as  PlannedStartDateTo,

      -- EndTimeSec converted in Format HH:MM
      @UI.identification: [{position:30}]
      @EndUserText.label: 'End Time'
      cast(
        concat(
            concat(
                  right(concat('0',cast(floor(div(CapacityEndTime,3600)) as sstring)),2),
                  right(concat('0',cast(floor(div(mod(CapacityEndTime,3600),60)) as sstring)),2)
                ),
                right(concat('0',cast(floor(mod(mod(CapacityEndTime,3600),60)) as sstring)),2)
            )  as abap.tims)                                                                                                                       as  PlannedEndDateTo,

      @UI.identification: [{position:35}]
      @EndUserText.label: 'Time Zone'
      cast( _Plant._OrganizationAddress[AddressRepresentationCode = ''].AddressTimeZone as co_plant_timezone ) as AddressTimeZone,
      @Semantics.quantity.unitOfMeasure: 'DurationUnit'
      @EndUserText.label: 'Total Break Duration'
      @UI.identification: [{position:40}]
      @Semantics.calendarItem.duration: true
      cast(_Capacity.CapacityBreakDuration * cast(_UconfCapform.ConversionFactor as abap.dec(26,14)) as abap.quan( 10, 2 ))                        as  CapacityBreakDuration,

      @UI.lineItem: [{position: 20}]
      @Semantics.quantity.unitOfMeasure: 'DurationUnit'
      @UI.fieldGroup: [ { qualifier: 'CapacityInformation', position: 10 } ]
      @EndUserText.label: 'Operating Duration'
      cast(div((CapacityEndTime - CapacityStartTime - CapacityBreakDuration)
       * cast(round(_UconfCapform.ConversionFactor, 10) as abap.quan(10,10))
       * cast(CapacityPlanUtilizationPercent as abap.dec( 3,0)), 100) as abap.quan(10, 2))                                                         as  OperationDuration,

      // Value in seconds from dbtable kako converted to minutes

      @Semantics.unitOfMeasure: true
      _UconfCapform.StandardWorkQuantityUnit2                                                                                                      as  DurationUnit,

      @UI.lineItem: [{position:30}]
      @UI.fieldGroup: [ { qualifier: 'CapacityInformation', position: 20 } ]
      @EndUserText.label: 'Utilization(%)'
      CapacityPlanUtilizationPercent,

      @UI.lineItem: [{position:40}]
      @UI.fieldGroup: [ { qualifier: 'CapacityInformation', position: 30 } ]
      @EndUserText.label: 'Number of individual Capacities'
      CapacityNumberOfCapacities,

      @UI.lineItem: [{position:50}]
      @Semantics.quantity.unitOfMeasure: 'CapacityQuantityUnit'
      @UI.fieldGroup: [ { qualifier: 'CapacityInformation', position: 40 } ]
      @EndUserText.label: 'Capacity'
      cast(div((CapacityEndTime - CapacityStartTime - CapacityBreakDuration)
        * cast(round(_UconfCapform.ConversionFactor, 10) as abap.quan(10,10))
        * cast(CapacityPlanUtilizationPercent as abap.dec( 3,0))
        * CapacityNumberOfCapacities, 100) as abap.quan(10, 2))                                                                                    as  WorkCenterAvailableCapacity,

      @Semantics.unitOfMeasure: true
      CapacityQuantityUnit                                                                                                                         as  CapacityQuantityUnit,

      _CapacityCategory,
      _CapacityResponsiblePlanner
};