C_TaxRegMigrationTP

DDL: C_TAXREGMIGRATIONTP Type: view_entity CONSUMPTION

Migration Overview

C_TaxRegMigrationTP is a Consumption CDS View that provides data about "Migration Overview" in SAP S/4HANA. It reads from 1 data source (R_TaxRegMigrationTP) and exposes 23 fields with key field TaxRegisterMigrationUUID. It has 3 associations to related views. It is exposed through 1 OData service (UI_MIGRATE_TAX_ITEMS).

1 data source(s) Exposed by 1 service(s) 23 fields

Data Sources (1)

SourceAliasJoin Type
R_TaxRegMigrationTP R_TaxRegMigrationTP projection

Associations (3)

CardinalityTargetAliasCondition
[1..1] C_TaxRegisterActiveTaxCountry _TaxRegisterActiveTaxCountry $projection.TaxCountry = _TaxRegisterActiveTaxCountry.TaxCountry and $projection.TaxationType = _TaxRegisterActiveTaxCountry.TaxationType
[1..1] I_UserContactCard _CreatedByUserContactCard $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
[0..1] I_UserContactCard _LastChangedByUserContactCard $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Migration Overview view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view
Metadata.allowExtensions true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_MIGRATE_TAX_ITEMS UI_MIGRATE_TAX_ITEMS_V2 V2 C1 NOT_RELEASED

Fields (23)

KeyFieldSource TableSource FieldDescription
KEY TaxRegisterMigrationUUID TaxRegisterMigrationUUID
TaxRegisterMigrationNumber TaxRegisterMigrationNumber
TaxCountry TaxCountry
TaxationType TaxationType
TaxRegisterMigrationStatus TaxRegisterMigrationStatus
FromPostingDate FromPostingDate Posting Date From
ToPostingDate ToPostingDate Posting Date To
TaxRegMigrtnRptgDateType TaxRegMigrtnRptgDateType
TaxRegMigrtnFlfmtDateType TaxRegMigrtnFlfmtDateType
TxRegMigrtnScheduledDateTime TxRegMigrtnScheduledDateTime
MigrationJobNumber MigrationJobNumber
TaxRegisterMigrationLogHandle TaxRegisterMigrationLogHandle
Criticality Criticality
CreatedByUser CreatedByUser
CreationDateTime CreationDateTime
LastChangedByUser LastChangedByUser
LastChangeDateTime LastChangeDateTime
CountryNameasCountryNamelocalized
_TaxRegisterActiveTaxCountry _TaxRegisterActiveTaxCountry
_TaxCountryText _TaxCountryText
_TaxationTypeText _TaxationTypeText
_CreatedByUserContactCard _CreatedByUserContactCard
_LastChangedByUserContactCard _LastChangedByUserContactCard 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #NOT_REQUIRED,
  privilegedAssociations: ['_CreatedByUserContactCard','_LastChangedByUserContactCard']
  }
@EndUserText.label: 'Migration Overview'
@ObjectModel:{
  semanticKey: ['TaxRegisterMigrationNumber'],
  usageType :{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
  }
}
@VDM:{
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
@Metadata.allowExtensions: true


define root view entity C_TaxRegMigrationTP
  provider contract transactional_query
  as projection on R_TaxRegMigrationTP

  association [1..1] to C_TaxRegisterActiveTaxCountry as _TaxRegisterActiveTaxCountry  on  $projection.TaxCountry   = _TaxRegisterActiveTaxCountry.TaxCountry
                                                                                       and $projection.TaxationType = _TaxRegisterActiveTaxCountry.TaxationType
  association [1..1] to I_UserContactCard             as _CreatedByUserContactCard     on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard             as _LastChangedByUserContactCard on  $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
{
  key TaxRegisterMigrationUUID,
      TaxRegisterMigrationNumber,
      @ObjectModel: {
        text.element: ['CountryName']
        }
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TaxCountryValueHelp', element: 'TaxCountry' }}]
      TaxCountry,
      @ObjectModel: {
        text.element: ['TaxationTypeDescription']
       }
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TaxationTypeValueHelp', element: 'TaxationType' },
                                           additionalBinding: [{ localElement: 'TaxCountry', element: 'TaxCountry'}]}]
      TaxationType,
      @ObjectModel.text.element: ['TaxRegisterMigrationStatusDesc']
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TaxRegisterMigrationStatus', element: 'TaxRegisterMigrationStatus' }}]
      TaxRegisterMigrationStatus,
      @Consumption.filter : { selectionType: #INTERVAL }
      @EndUserText.label: 'Posting Date From'
      FromPostingDate,
      @Consumption.filter : { selectionType: #INTERVAL }
      @EndUserText.label: 'Posting Date To'
      ToPostingDate,
      @ObjectModel.text.element: ['TaxRegMigrtnRptgDateTypeDesc']
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TxRegMigrtnRptgDateType', element: 'TaxRegMigrtnRptgDateType' }}]
      TaxRegMigrtnRptgDateType,
      @ObjectModel.text.element: ['TaxRegMigrtnFlfmtDateTypeDesc']
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TxRegMigrtnFlfmtDateType', element: 'TaxRegMigrtnFlfmtDateType' }}]
      TaxRegMigrtnFlfmtDateType,
      TxRegMigrtnScheduledDateTime,
      MigrationJobNumber,
      TaxRegisterMigrationLogHandle,
      Criticality,
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      CreatedByUser,
      @Consumption.filter : { selectionType: #INTERVAL }
      CreationDateTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      LastChangedByUser,
      LastChangeDateTime,
      _TaxCountryText.CountryName                                   as CountryName                    : localized,
      _TaxationTypeText.TaxationTypeDescription                     as TaxationTypeDescription        : localized,
      _TaxRegisterMigrationStatusTxt.TaxRegisterMigrationStatusDesc as TaxRegisterMigrationStatusDesc : localized,
      _TaxRegisterRptgDateTypeText.TaxRegMigrtnRptgDateTypeDesc     as TaxRegMigrtnRptgDateTypeDesc   : localized,
      _TaxRegisterFlfmtDateTypeText.TaxRegMigrtnFlfmtDateTypeDesc   as TaxRegMigrtnFlfmtDateTypeDesc  : localized,
      _TaxRegisterActiveTaxCountry,
      _TaxCountryText,
      _TaxationTypeText,
      @Consumption.filter.hidden: true
      _CreatedByUserContactCard,
      @Consumption.filter.hidden: true
      _LastChangedByUserContactCard
      //_TaxCountry

}

Learn More