C_SustCustomerAddressDEX

DDL: C_SUSTCUSTOMERADDRESSDEX Type: view_entity CONSUMPTION

Customer Address data extractor

C_SustCustomerAddressDEX is a Consumption CDS View (Fact) that provides data about "Customer Address data extractor" in SAP S/4HANA. It reads from 1 data source (I_Customer) and exposes 23 fields with key field Customer.

1 data source(s) 23 fields

Data Sources (1)

SourceAliasJoin Type
I_Customer I_Customer from

Annotations (14)

NameValueLevelField
EndUserText.label Customer Address data extractor view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
AccessControl.personalData.blocking #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.sapObjectNodeType.name Customer view
ObjectModel.modelingPattern #NONE view
VDM.viewType #CONSUMPTION view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Analytics.dataCategory #FACT view
Analytics.internalName #LOCAL view
Analytics.dataExtraction.enabled true view

Fields (23)

KeyFieldSource TableSource FieldDescription
KEY Customer Customer
AddressID AddressID
DeletionIndicator DeletionIndicator
BusinessPartner
BusinessPartnerUUID
BusinessPartnerCategory
IsBusinessPurposeCompleted
BusinessPartner2
FirstName
LastName
ValidityStartDate
ValidityEndDate
AddressObjectType _AddressDefaultRepresentation AddressObjectType
AddresseeFullName _AddressDefaultRepresentation AddresseeFullName
CityName _AddressDefaultRepresentation CityName
StreetName _AddressDefaultRepresentation StreetName
HouseNumber _AddressDefaultRepresentation HouseNumber
Country _AddressDefaultRepresentation Country
Region _AddressDefaultRepresentation Region
PostalCode _AddressDefaultRepresentation PostalCode
InternationalPhoneNumber
InternationalFaxNumber
EmailAddress 
@EndUserText.label: 'Customer Address data extractor'

@AccessControl: {
     authorizationCheck:    #PRIVILEGED_ONLY,
     personalData.blocking: #NOT_REQUIRED
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
  usageType:{
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MASTER
  },
  sapObjectNodeType.name: 'Customer',
  supportedCapabilities: [ #EXTRACTION_DATA_SOURCE ],
  modelingPattern: #NONE
}

@VDM: {
      viewType: #CONSUMPTION,
      lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@Analytics: {
        dataCategory: #FACT,
        internalName: #LOCAL,
        dataExtraction: {
          enabled: true,
          delta.changeDataCapture:
            { mapping:
              [
                { role: #MAIN, table: 'KNA1', tableElement: ['kunnr'], viewElement: ['Customer'] },
                { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'but000',   tableElement: ['partner'],      viewElement: ['BusinessPartner'] },
                { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'but050',   tableElement: ['partner2'],     viewElement: ['BusinessPartner2'] },
                { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'adrc',     tableElement: ['addrnumber'],   viewElement: ['AddressID'] },
                { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'adr2',     tableElement: ['addrnumber'],   viewElement: ['AddressID'] },
                { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'adr6',     tableElement: ['addrnumber'],   viewElement: ['AddressID'] },
                { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'adr3',     tableElement: ['addrnumber'],   viewElement: ['AddressID'] }
              ]
            }
        }
}
define view entity C_SustCustomerAddressDEX as select from I_Customer

{

  key Customer,
  AddressID,
  DeletionIndicator,
  _CustomerToBusinessPartner._BusinessPartner.BusinessPartner,
  _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerUUID,
  _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerCategory,
  @Semantics.booleanIndicator: true
  _CustomerToBusinessPartner._BusinessPartner.IsBusinessPurposeCompleted,
  _CustomerToBusinessPartner._BusinessPartner._BPRelationship[IsStandardRelationship = 'X'].BusinessPartner2,
  _CustomerToBusinessPartner._BusinessPartner._BPRelationship[IsStandardRelationship = 'X']._BusinessPartner2.FirstName,
  _CustomerToBusinessPartner._BusinessPartner._BPRelationship[IsStandardRelationship = 'X']._BusinessPartner2.LastName,
  _CustomerToBusinessPartner._BusinessPartner._BPRelationship[IsStandardRelationship = 'X'].ValidityStartDate,
  _CustomerToBusinessPartner._BusinessPartner._BPRelationship[IsStandardRelationship = 'X'].ValidityEndDate,
  _AddressDefaultRepresentation.AddressObjectType,
  _AddressDefaultRepresentation.AddresseeFullName,
  _AddressDefaultRepresentation.CityName,
  _AddressDefaultRepresentation.StreetName,
  _AddressDefaultRepresentation.HouseNumber,
  _AddressDefaultRepresentation.Country,
  _AddressDefaultRepresentation.Region,
  _AddressDefaultRepresentation.PostalCode,
  _AddressDefaultRepresentation._CurrentDfltLandlinePhoneNmbr.InternationalPhoneNumber,
  _AddressDefaultRepresentation._CurrentDfltFaxNumber.InternationalFaxNumber,
  _AddressDefaultRepresentation._CurrentDfltEmailAddress.EmailAddress

}

Learn More