C_SupplierListTP_2

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel: { semanticKey: ['SupplierListUUID'],
                representativeKey: 'SupplierListUUID',
                usageType.dataClass: #TRANSACTIONAL,
                usageType.serviceQuality:  #C,
                usageType.sizeCategory: #L }

@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser',  '_SuplrListBusinessPartnerTP', '_SuplrListProposedSupplierTP', '_SuplrListPrpsdCompanyCodeTP' ]
//, '_SuplrListPrpsdCompanyCodeTP' ]


@Search.searchable: true

@Metadata.allowExtensions: true

@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

@EndUserText.label: 'Supplier List - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_SupplierListTP'],
  allowNewDatasources: false,
  elementSuffix: 'SLH',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }

define root view entity C_SupplierListTP_2
  provider contract transactional_query
  as projection on R_SupplierListTP as _SupplierListTP
{
          // @UI.facet: [  { id:              'Facet2-ID',

          //               type:            #LINEITEM_REFERENCE, // Facet shows the referenced items in a list report

          //               label:           'Facet 2 - Bookings',

          //               position:         50,

          //               targetElement:   '_SuplrListPrpsdCompanyCodeTP' }]


  key     _SupplierListTP.SupplierListUUID,

          @ObjectModel.text.element:  [ 'SupplierListName' ]
          _SupplierListTP.SupplierList,

          _SupplierListTP.SupplierListName,
          
           @Consumption.filter.hidden: true
          @ObjectModel.text.element: ['SupplierListTypeText']        
          _SupplierListTP.SupplierListType,

          @ObjectModel.foreignKey.association:'_ChangedByUser'
          @ObjectModel.text.element: ['ChangedByUserName']
          _SupplierListTP.LastChangedByUser,

          @UI.hidden: true
          _ChangedByUser.UserDescription                      as ChangedByUserName,

          @UI.fieldGroup:[{qualifier: 'SuplrListLifecycleStatus', position: 10, label:'Status'}]
          @UI.lineItem: [{ position: 70, importance: #HIGH, label:'Status' }]
          @UI.selectionField: [{ position: 40 }]
          @ObjectModel.text.element: ['SuplrListLifecycleStatusName']

          @EndUserText.label: 'Status'
          @UI.textArrangement: #TEXT_ONLY
          @UI.dataPoint: { title: 'Status' }
          SuplrListLifecycleStatus,

          @ObjectModel.text.element: ['PersonFullName']
          @Consumption.valueHelpDefinition: [{ entity: { name : 'C_SupplierListPurchaserRespVH', element : 'PersonWorkAgreement' }  }]
          _SupplierListTP.PurchaserRespWorkAgreement,

          @Feature:'SW:PROD_SRCG_DEACTIVATE_HCM'
          @ObjectModel.text.element: ['PersonFullName']
          _SupplierListTP.PurchaserResponsiblePerson,

          @ObjectModel: { virtualElement: true,
                          virtualElementCalculatedBy: 'ABAP:CL_MMPUR_SUPLRLIST2_TRANS_EXIT' }
  virtual PersonFullName                 : bu_name1tx,

          _SupplierListTP.PurchaserResponsibleUser            as PurchaserResponsibleUser,

          @ObjectModel.foreignKey.association:'_CreatedByUser'
          @ObjectModel.text.element: ['CreatedByUserName']
          _SupplierListTP.CreatedByUser,

          @UI.hidden: true
          _CreatedByUser.UserDescription                      as CreatedByUserName,

          _SupplierListTP.CreationDateTime,
          _SupplierListTP.LastChangeDateTime,

          _SupplierListTP.SupplierListVersion,

          _SupplierListLatestVersion.SupplierListVersion      as SupplierListLatestVersion,

          @UI.hidden: true
          _SupplierListLatestVersion.SupplierListUUID         as SupplierListLatestVersionUUID,

          @UI.hidden: true
          _SupplierListType._Text.SupplierListTypeText        as SupplierListTypeText         : localized,

          @UI.hidden: true
          _SuplrListStatus._Text.SuplrListLifecycleStatusName as SuplrListLifecycleStatusName : localized,

          _SupplierListTP.SupplierListIsLatest,

          _SupplierListTP.IsDeleted,
          _SupplierListTP.SupplierListIsPublic,

          _SupplierListTP.SupplierListHasAllCompanyCodes,

          _SupplierListTP.IsEndOfPurposeBlocked,

          @Semantics.booleanIndicator: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MMPUR_SUPLRLIST2_TRANS_EXIT'
  virtual IsChangeDocumentsEnabled       : abap_boolean,

          @UI.hidden: true
          @Semantics.booleanIndicator: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MMPUR_SUPLRLIST2_TRANS_EXIT'
  virtual IsRlvtForUsrSpecifiedSuplrList : abap_boolean,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MMPUR_SUPLRLIST2_TRANS_EXIT'
  virtual NumberOfSupplier               : abap.int4,

          @Consumption.valueHelpDefinition: [{ entity: { name : 'C_SupplierListCompanyCodeVH', element : 'CompanyCode' }, useForValidation: true  }]
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SUPLRLIST_SEARCH_FILTER'
          @UI.selectionField: [{ position: 80 }]
          @ObjectModel.filter.transformedBy: 'ABAP:CL_MM_SUPLRLIST_SEARCH_FILTER'

  virtual CompanyCode                    : bukrs,

          @EndUserText.label: 'Material Group'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SUPLRLIST_SEARCH_FILTER'
          @Consumption.valueHelpDefinition: [{ entity: { name : 'C_SupplierListMaterialGroupVH', element : 'MaterialGroup' }  }]
          @UI.selectionField: [{ position: 90 }]
          @ObjectModel.filter.transformedBy: 'ABAP:CL_MM_SUPLRLIST_SEARCH_FILTER'
  virtual MaterialGroup                  : matkl,

          @EndUserText.label: 'Supplier'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SUPLRLIST_SEARCH_FILTER'
          @UI.selectionField: [{ position: 100 }]
          @Consumption.valueHelpDefinition: [{ entity: { name : 'C_SuplrListBusinessPartnerVH', element : 'Supplier' }  }]
          @ObjectModel.filter.transformedBy: 'ABAP:CL_MM_SUPLRLIST_SEARCH_FILTER'
  virtual Supplier                       : lifnr,

          @UI.hidden:true
          @ObjectModel.virtualElement: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MMPUR_SUPLRLIST2_TRANS_EXIT'
  virtual UICT_HCMIsDisabled             : abap_boolean,
 
          @UI.hidden:true
          @Semantics.booleanIndicator: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MMPUR_SUPLRLIST2_TRANS_EXIT'
  virtual UICT_HCMIsDsbldOrIsRlvtForUsr  :  abap_boolean,

          /* Associations */
          _SuplrListBusinessPartnerTP  : redirected to composition child C_SuplrListBusinessPartnerTP_2,

          _SupplierListCompanyCodeTP   : redirected to composition child C_SupplierListCompanyCodeTP_2,

          _SuplrListProposedSupplierTP : redirected to composition child C_SuplrListPrpsdSupplierTP_2,

          _SuplrListPrpsdCompanyCodeTP : redirected to composition child C_SuplrListPrpsdCompanyCodeTP,

          _SupplierListMaterialGroupTP : redirected to composition child C_SuplrListMaterialGroupTP_2,

          _ChangedByUser,
          _CreatedByUser,
          _SupplierListType,
          _SupplierListVersions,
          _WorkAgreement,

          _SupplierListCompanyCode,
          _SupplierListMaterialGroup
}