C_SupplierFs

@AbapCatalog.sqlViewName: 'CSUPPLIERFS'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Supplier'

@Metadata.allowExtensions: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

//@UI.headerInfo:{

//  typeName: 'Supplier',

//  typeNamePlural: 'Suppliers',

//  title: {

//   value: 'SupplierName' },

//   description: {

//   value: '_SupplierAddress.Supplier'

//   },

//   typeImageUrl: '/sap/bc/ui5_ui5/sap/MD_SUPPLIERSS1/images/supplier.jpg'  ///check again

//  }


// For increased field length

@UI.headerInfo:{
  typeName: 'Supplier',
  typeNamePlural: 'Suppliers',
  title: {
   value: 'BPSupplierName' },
   description: {
   value: '_SupplierAddress.Supplier'
   },
   typeImageUrl: '/sap/bc/ui5_ui5/sap/MD_SUPPLIERSS1/images/supplier.jpg'  ///check again

  }


@VDM.viewType: #CONSUMPTION

define view C_SupplierFs
  as select from I_Supplier
  association [0..*] to C_SupplierCompanyData      as _SupplierCompanyData      on $projection.Supplier = _SupplierCompanyData.Supplier
  association [0..*] to C_Supplierbankdetails      as _Supplierbankdetails      on $projection.Supplier = _Supplierbankdetails.Supplier
  //association [0..*] to C_BusinessPartnerBank      as _BusinessPartnerBankDetails  on $projection.businesspartner = _BusinessPartnerBankDetails.BusinessPartner

  association [0..*] to C_Supplierpurchasingorg    as _Supplierpurchasingorg    on $projection.Supplier = _Supplierpurchasingorg.Supplier
  association [0..*] to C_PurgCatBySupplier        as _PurchasingCategory       on $projection.businesspartner = _PurchasingCategory.Supplier
  association [0..*] to C_ActivityBySupplier       as _SupplierActivity         on $projection.businesspartner = _SupplierActivity.Supplier
  association [0..*] to C_EvaluationBySupplier     as _SupplierEvalScorecard    on $projection.businesspartner = _SupplierEvalScorecard.Supplier
  association [0..*] to C_Suppliercontracts        as _PurchaseContract         on $projection.Supplier = _PurchaseContract.Supplier
  association [0..*] to C_SupplierPurOrder         as _SupplierPurOrder         on $projection.Supplier = _SupplierPurOrder.Supplier
  association [0..*] to C_SupplierSuplrInvoice     as _SupplierSuplrInvoice     on $projection.Supplier = _SupplierSuplrInvoice.InvoicingParty
  association [0..*] to C_SupplierMaterial         as _SupplierMaterial         on $projection.Supplier = _SupplierMaterial.Supplier
  association [0..*] to I_SupplierAccountGroupText as _SupplierAccountGroupText on $projection.SupplierAccountGroup = _SupplierAccountGroupText.SupplierAccountGroup
  association [0..*] to I_SupplierIndustryText     as _SupplierIndustryText     on $projection.Industry = _SupplierIndustryText.SupplierIndustry
  //  association [1..1] to I_SupplierAddress          as _SupplierAddress          on $projection.Supplier = _SupplierAddress.Supplier

  association [0..1] to C_SupplierAddress          as _SupplierAddress          on $projection.Supplier = _SupplierAddress.Supplier
  association [0..*] to C_SupplierSchedgAgrmtHdr   as _SupplierSchedgAgrmtHdr   on $projection.Supplier = _SupplierSchedgAgrmtHdr.Supplier
  association [0..*] to C_BPDataController         as _BPDataController         on $projection.businesspartner = _BPDataController.BusinessPartner
{

  key I_Supplier.Supplier,
      I_Supplier._SupplierToBusinessPartner._BusinessPartner.BusinessPartner,
      I_Supplier.AuthorizationGroup,
      @ObjectModel.text.association: '_SupplierIndustryText'
      I_Supplier.Industry,
      cast(concat_with_space(concat_with_space(I_Supplier.InternationalLocationNumber1, I_Supplier.InternationalLocationNumber2, 1), I_Supplier.InternationalLocationNumber3, 1) as mm_pur_supplier_iln) as InternationalLocationNumber,
      I_Supplier.InternationalLocationNumber1,
      I_Supplier.InternationalLocationNumber2,
      I_Supplier.InternationalLocationNumber3,
      I_Supplier.TaxNumber1                                                                                                                                                                              as SupplierTaxID1,
      I_Supplier.TaxNumber2                                                                                                                                                                              as SupplierTaxID2,
      I_Supplier.TaxNumber3                                                                                                                                                                              as SupplierTaxID3,
      I_Supplier.TaxNumber4                                                                                                                                                                              as SupplierTaxID4,
      I_Supplier.TaxNumber5                                                                                                                                                                              as SupplierTaxID5,
      I_Supplier.TaxJurisdiction,
      I_Supplier.VATRegistration,
      // cast(cast(_SupplierAddress.AddressID as abap.char(10)) as contactcardaddress)                                                                                                                            as AddressID, //Output conversion for formatted address

      //      cast(cast(I_Supplier._SupplierToBusinessPartner._BusinessPartner._CurrentDefaultAddress.AddressID as abap.char(10)) as contactcardaddress)                                                                                                                            as AddressID, //Output conversion for formatted address

      // I_Supplier._SupplierToBusinessPartner._BusinessPartner._CurrentDefaultAddress.BPAddressIsProtected,

      //Annual Spend KPI

      @Semantics.amount.currencyCode: 'DisplayCurrency'
      cast(cast(0 as abap.curr( 13, 2 )) as bwert)                                                                                                                                                       as TotalSpendAmount, //filled in DPC_EXT

      //   _SupplierAddress._StandardAddress.CityName,

      @Semantics.currencyCode: true
      cast(cast('EUR  ' as abap.cuky( 5 )) as waers)                                                                                                                                                     as DisplayCurrency, //filled in DPC_EXT

      //      coalesce(_SupplierAddress._StandardAddress._DefaultPrivatePhoneNumber.InternationalPhoneNumber, I_Supplier._StandardAddress._DefaultCorporatePhoneNumber.InternationalPhoneNumber)                       as InternationalPhoneNumber,

      //      coalesce(_SupplierAddress._StandardAddress._DefaultPvtMobilePhoneNumber.InternationalPhoneNumber, I_Supplier._StandardAddress._DefaultCorpMobilePhoneNumber.InternationalPhoneNumber)                    as InternationalMobilePhoneNumber,

      //      coalesce(_SupplierAddress._StandardAddress._DefaultPrivateFaxNumber.InternationalFaxNumber,I_Supplier._StandardAddress._DefaultCorpFaxNumber.InternationalFaxNumber)                                     as InternationalFaxNumber,

      //      coalesce(_SupplierAddress._StandardAddress._DefaultPvtEmailAddress.EmailAddress,I_Supplier._StandardAddress._DefaultCorpEmailAddress.EmailAddress)                                                       as EmailAddress,

      I_Supplier.PostingIsBlocked,
      I_Supplier.PurchasingIsBlocked,
      @ObjectModel.text.association: '_SupplierAccountGroupText'
      I_Supplier.SupplierAccountGroup,
      I_Supplier.SupplierName,

      //    For increased field length

      I_Supplier.BPSupplierName,

      I_Supplier.CreatedByUser,
      I_Supplier.CreationDate,
      I_Supplier.IsOneTimeAccount,
      I_Supplier.AccountIsBlockedForPosting,
      I_Supplier.Customer,

      ////////////// Start of Datacontroller 10+1 fields -  Not to be consumed by any other views//////////

      @UI.hidden:true
      @Consumption.hidden:true
      I_Supplier.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      I_Supplier.DataController10,
      ////////////// End of Datacontroller 10+1 fields//////////


      _SupplierIndustryText,
      _SupplierAccountGroupText,
      _Supplierbankdetails,
      _Supplierpurchasingorg,
      _SupplierCompanyData,
      _SupplierMaterial,
      _SupplierPurOrder,
      _SupplierSuplrInvoice,
      _PurchaseContract,
      _PurchasingCategory,
      _SupplierActivity,
      _SupplierEvalScorecard,
      _SupplierToBusinessPartner,
      _SupplierAddress,
      _SupplierSchedgAgrmtHdr,
      _BPDataController
      //_BusinessPartnerBankDetails

}