C_SuplInvPurOrdRef

DDL: C_SUPLINVPURORDREF SQL: CSUPLINVPOREF Type: view CONSUMPTION

Supplier Invoice

C_SuplInvPurOrdRef is a Consumption CDS View that provides data about "Supplier Invoice" in SAP S/4HANA. It reads from 1 data source (I_SupplierInvoiceItemPurOrdRef) and exposes 16 fields with key fields SupplierInvoice, FiscalYear. It has 1 association to related views.

1 data source(s) 16 fields

Data Sources (1)

SourceAliasJoin Type
I_SupplierInvoiceItemPurOrdRef _SupplierInvoiceItemPurOrdRef inner

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_SupplierInvoiceStatusText _SupplierInvoiceStatusText $projection.SupplierInvoiceStatus = _SupplierInvoiceStatusText.SupplierInvoiceStatus and _SupplierInvoiceStatusText.Language = $session.system_language

Annotations (9)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.sqlViewName CSUPLINVPOREF view
EndUserText.label Supplier Invoice view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view

Fields (16)

KeyFieldSource TableSource FieldDescription
KEY SupplierInvoice I_SupplierInvoiceItemPurOrdRef SupplierInvoice
KEY FiscalYear I_SupplierInvoiceItemPurOrdRef FiscalYear
PurchaseOrder I_SupplierInvoiceItemPurOrdRef PurchaseOrder
SupplierInvoiceWthnFiscalYear
CompanyCode I_SupplierInvoiceEnh CompanyCode
DocumentHeaderText I_SupplierInvoiceEnh DocumentHeaderText
DocumentCurrency I_SupplierInvoiceEnh DocumentCurrency
SupplierInvoiceIDByInvcgParty I_SupplierInvoiceEnh SupplierInvoiceIDByInvcgParty
DocumentDate DocumentDate
PostingDate PostingDate
DueCalculationBaseDate I_SupplierInvoiceEnh DueCalculationBaseDate
InvoicingParty I_SupplierInvoiceEnh InvoicingParty
SupplierInvoiceStatus I_SupplierInvoiceEnh SupplierInvoiceStatus
SupplierInvoiceStatusDesc _SupplierInvoiceStatusText SupplierInvoiceStatusDesc
_SupplierInvoiceStatusText _SupplierInvoiceStatusText
_Currency I_SupplierInvoiceEnh _Currency 
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'CSUPLINVPOREF'
@EndUserText.label: 'Supplier Invoice'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

define view C_SuplInvPurOrdRef
  as select distinct from I_SupplierInvoiceEnh

  inner join I_SupplierInvoiceItemPurOrdRef as _SupplierInvoiceItemPurOrdRef on I_SupplierInvoiceEnh.SupplierInvoice = _SupplierInvoiceItemPurOrdRef.SupplierInvoice
                                                                             and I_SupplierInvoiceEnh.FiscalYear = _SupplierInvoiceItemPurOrdRef.FiscalYear
  //  association [0..*] to I_SupplierInvoiceStatusText as _SupplierInvoiceStatusText

  //  on $projection.SupplierInvoiceStatus =  _SupplierInvoiceStatusText.SupplierInvoiceStatus


  association [0..1] to I_SupplierInvoiceStatusText as _SupplierInvoiceStatusText on  $projection.SupplierInvoiceStatus   = _SupplierInvoiceStatusText.SupplierInvoiceStatus
                                                                                  and _SupplierInvoiceStatusText.Language = $session.system_language

{
      @UI.lineItem: [{
                 qualifier: 'SuplInvPurOrderRefT',
                 position: 10,
                 label: 'Invoice', label_AsOtr: 'FA163EC90EE61ED588913EFB632A0C5E',
                 importance: #HIGH }, {
                 position: 10,
                 label: 'Invoice', label_AsOtr: 'FA163EC90EE61ED588913EFB632A0C5E',
                 importance: #HIGH }]
      @Consumption.semanticObject: 'SupplierInvoice'
  key _SupplierInvoiceItemPurOrdRef.SupplierInvoice,
  key _SupplierInvoiceItemPurOrdRef.FiscalYear,
      _SupplierInvoiceItemPurOrdRef.PurchaseOrder,

      cast( concat(_SupplierInvoiceItemPurOrdRef.SupplierInvoice, concat('/', _SupplierInvoiceItemPurOrdRef.FiscalYear) ) as mmiv_belnr_gjahr ) as SupplierInvoiceWthnFiscalYear,

      I_SupplierInvoiceEnh.CompanyCode,

      I_SupplierInvoiceEnh.DocumentHeaderText,

      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      I_SupplierInvoiceEnh.DocumentCurrency,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @DefaultAggregation: #NONE
      @UI.lineItem: [{
                 qualifier: 'SuplInvPurOrderRefT',
                 position: 60,
                 importance: #HIGH }, {
                 position: 60,
                 importance: #HIGH }]
      case 
      when I_SupplierInvoiceEnh.IsInvoice = 'X'
      then I_SupplierInvoiceEnh.InvoiceGrossAmount
      else cast(-I_SupplierInvoiceEnh.InvoiceGrossAmount as rmwwr )
      end as InvoiceGrossAmount,
      //I_SupplierInvoiceEnh.InvoiceGrossAmount,


      @UI.lineItem: [{
                 qualifier: 'SuplInvPurOrderRefT',
                 position: 20,
                 importance: #HIGH }, {
                 position: 20,
                 importance: #HIGH }]
      I_SupplierInvoiceEnh.SupplierInvoiceIDByInvcgParty, //Referenz Invoice ID


      @UI.lineItem: [{
                 qualifier: 'SuplInvPurOrderRefT',
                 position: 30,
                 importance: #HIGH }, {
                 position: 30,
                 importance: #HIGH }]
      DocumentDate,

      @UI.lineItem: [{
                 qualifier: 'SuplInvPurOrderRefT',
                 position: 40,
                 importance: #HIGH }, {
                 position: 40,
                 importance: #HIGH }]
      PostingDate,
      // Tax_Amount ?????

      //sum(I_SupplierInvoiceEnh._SupplierInvoiceTax[ SupplierInvoice = SupplierInvoice and FiscalYear = FiscalYear ] ) as TaxAmount,


      @Semantics.businessDate.at
      I_SupplierInvoiceEnh.DueCalculationBaseDate,

      I_SupplierInvoiceEnh.InvoicingParty,

      I_SupplierInvoiceEnh.SupplierInvoiceStatus,

      @UI.lineItem: [{
                 qualifier: 'SuplInvPurOrderRefT',
                 position: 50,
                 label: 'Status', label_AsOtr: '005056B2532A1EE585B97A4F343C0274',
                 importance: #HIGH } , {
                 position: 50,
                 label: 'Status', label_AsOtr: '005056B2532A1EE585B97A4F343C0274',
                 importance: #HIGH }]
      _SupplierInvoiceStatusText.SupplierInvoiceStatusDesc,


      //associations

      _SupplierInvoiceStatusText,
      I_SupplierInvoiceEnh._Currency
}

Learn More