C_SubstanceTradeSecretTextTP

@EndUserText.label: 'Trade Secret Name'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY 
 
@AbapCatalog: {
  sqlViewName: 'CSUBTSTTP',
  compiler.compareFilter: true,
  preserveKey:            true 
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata: {
  allowExtensions: true
}

@ObjectModel: {
   dataCategory: #TEXT,
   transactionalProcessingDelegated: true,
   createEnabled:                    true,
   updateEnabled:                    true,
   deleteEnabled:                    true,
   representativeKey:                'SubstanceUUID',
   semanticKey:                      ['LanguageForEdit'],
   usageType: {
     dataClass:      #MASTER,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

@UI.headerInfo:{
  typeName: 'Confidential Substance Name',
  //typeNamePlural: 'Confidential Substance Names',

  title: {
    label: 'Confidential Business Information',
    value: 'SubstanceTradeSecretName'
  }
}

@UI.presentationVariant: [{sortOrder: [{by: 'LanguageISOCode', direction: #ASC }] }]

@Search.searchable: true
define view C_SubstanceTradeSecretTextTP 
  as select from I_SubstanceTradeSecretTextTP as tradeSecretText
  association [1..1] to C_SubstanceQryTP as _Substance    on $projection.SubstanceUUID = _Substance.SubstanceUUID
  association [0..*] to I_LanguageText   as _LanguageText on $projection.Language      = _LanguageText.Language
{
  key   tradeSecretText.SubstanceUUID,

        @ObjectModel.foreignKey.association: '_Language'
  key   tradeSecretText.Language,

        @Consumption.valueHelp: '_LanguageForEdit'
        @ObjectModel.text.element: ['LanguageName']
        @ObjectModel.editableFieldFor: 'Language' 
        tradeSecretText.LanguageForEdit                                             as LanguageForEdit,

        @ObjectModel.readOnly: true
//        @Search:

//        {

//          defaultSearchElement: true,

//          ranking: #MEDIUM,

//          fuzzinessThreshold: 0.8

//        }

        _LanguageForEdit._Text[1: Language = $session.system_language].LanguageName as LanguageName,

        @ObjectModel.readOnly: true
        _LanguageForEdit.LanguageISOCode                                            as LanguageISOCode,

        @Semantics.text: true
        @Search:
        {
          defaultSearchElement: true,
          ranking: #LOW,
          fuzzinessThreshold: 0.8
        }
        tradeSecretText.SubstanceTradeSecretName,

        /* Associations */
        @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
        _Substance,
        _Language,
        _LanguageForEdit,
        _LanguageText
}