C_SuVolRtrckgSubstChmlCmpstnTP

@EndUserText.label: 'Retrack Substance Based Composition'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_ReleasedByUser', '_CompletedByUser', '_DecidedByUser']
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.allowExtensions: true

@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] }

--Header information
@UI:
{
  headerInfo:
  {
    typeImageUrl: 'sap-icon://tree',

    title:
    {
      label: 'Chemical Compliance View',
      value: 'ChmlCmplncInfoCombinedName'
    },
    description: {
        label: 'ComplianceRequirement',
        value: 'ComplianceRequirement'
    }
  }
}

@ObjectModel.usageType:{ serviceQuality: #D,
                         sizeCategory:   #L,
                         dataClass:      #MASTER }

@Search.searchable: true
define root view entity C_SuVolRtrckgSubstChmlCmpstnTP
  provider contract transactional_query
  as projection on R_SubstVolRetrackingTP as SubstVolRetrackingTP
  association [0..*] to C_SubstChmlCmpstnSubstVol      as _SubstVolByCRCurrPeriod       on  $projection.chmlcmplncinfouuid             = _SubstVolByCRCurrPeriod.ChmlCmplncInfoUUID
                                                                                        and $projection.ComplianceRequirement          = _SubstVolByCRCurrPeriod.ComplianceRequirement
                                                                                        and _SubstVolByCRCurrPeriod.TrackingPeriodType = 'CURR_PER'

  association [0..*] to C_SubstChmlCmpstnSubstVol      as _SubstVolByCRPrevPeriod       on  $projection.chmlcmplncinfouuid             = _SubstVolByCRPrevPeriod.ChmlCmplncInfoUUID
                                                                                        and $projection.ComplianceRequirement          = _SubstVolByCRPrevPeriod.ComplianceRequirement
                                                                                        and _SubstVolByCRPrevPeriod.TrackingPeriodType = 'PREV_PER'


  association [0..*] to C_SubstChmlCmpstnDailySubstVol as _SubstChmlCmpstnDailySubstVol on  $projection.chmlcmplncinfouuid    = _SubstChmlCmpstnDailySubstVol.ChmlCmplncInfoUUID
                                                                                        and $projection.ComplianceRequirement = _SubstChmlCmpstnDailySubstVol.ComplianceRequirement
{
  key            SubstVolRetrackingUUID,
                 SubstVolRetrackingStatus,
                 ProdCmplncEventUUID,
                 SubstVolRetrackingType,
                 SubstVolRetrackingSourceUUID,
                 SubstVolRetrackingSource,
                 SubstVolRetrckgIsCurTrckgPerd,
                 SubstVolRetrckgIsOpnTrckgPerds,
                 SubstVolRetrackingReasonText,
                 SubstVolRetrackingCategory,
                 ComplianceRequirement,
                 _SubstVolRetrckgChmlCmpstn.ChmlCompositionUUID,
                 SubstVolRetrackingSrceChgdBy                                                                                    as SubstVolRetrackingSrceChgdBy,
                 SuVolRtrckgSrceChgdByFullName,
                 _SubstVolRetrckgChmlCmpstn.SubstVolRetrckgSrceChgdDteTme,
                 cast ( _SubstVolRetrckgChmlCmpstn.ChmlCompositionTypeName as ehpma_svt_retrckg_cmpstn_type preserving type )    as ChmlCompositionTypeName,
                 cast ( _SubstVolRetrckgChmlCmpstn.ChmlCmplncInfoCombinedName as ehpma_svt_retrckg_cmpstn_link preserving type ) as ChmlCmplncInfoCombinedName,
                 SubstVolRetrackingCompletedBy,
                 SuVolRtrckgCmpltdByFullName,
                 SubstVolRetrckgCompletedDteTme,
                 SubstVolRetrackingDecidedBy,
                 SuVolRtrckgDecidedByFullName,
                 SuVolRtrckgDecidedBySystemText,
                 SubstVolRetrckgDecidedDteTme,
                 cast ( SubstVolRetrackingStartDate as ehpma_svt_retrckg_date_from preserving type )                             as SubstVolRetrackingStartDate,
                 _SubstVolRetrckgChmlCmpstn.ChmlCompositionType,
                 _SubstVolRetrckgChmlCmpstn.Material,
                 _SubstVolRetrckgChmlCmpstn.ChmlCmplncInfoUUID,
                 _SubstVolRetrackingTypeTxt.SubstVolRetrackingTypeText,

                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHPMA_SVT_HIDE_RTRCKG_EXIT'
  virtual        SubstVolRetrckgDetsAreHidden : abap_boolean,

                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHPMA_SVT_CCMPS_LINK_EXIT'
  virtual        ObjectLinkURL                : string_unicode,

                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHPMA_SVT_HIDE_RTRCKG_EXIT'
  virtual        SubstVolRetrckgIsRejected    : abap_boolean,

                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHPMA_SVT_HIDE_RTRCKG_EXIT'
  virtual        SubstVolRetrckgIsAccepted    : abap_boolean,
  
                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHPMA_SVT_DECIDED_BY_EXIT'
  virtual        SuVolRtrckgIsDecidedBySystem : abap_boolean,
  
                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHPMA_SVT_DECIDED_BY_EXIT'
  virtual        SuVolRtrckgIsDecidedByUser   : abap_boolean,

                 --Combined name of composition category and combined name of CCI
                 @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CMPS_HEADER_EXIT'
  virtual        ChmlCompositionCombinedName  : ehpma_svt_retrckg_cmpstn_link,

                 _SubstVolByCRCurrPeriod,
                 _SubstVolByCRPrevPeriod,
                 _SubstChmlCmpstnDailySubstVol,
                 _SubstVolRetrckgChmlCmpstn,
                 _ChmlCmplncMatlAssgmt,
                 _ReleasedByUser,
                 _CompletedByUser,
                 _DecidedByUser
}