C_SrcgProjNegttnQtanItemTP

@EndUserText.label: 'Qtn Item for Srcg Proj Negotiation - TP'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: false
@Metadata.allowExtensions: true
@ObjectModel: { representativeKey: 'SrcgProjNegttnQtanItemUUID',
                semanticKey: ['SrcgProjNegttnQtanItemUUID'],
                usageType.dataClass: #TRANSACTIONAL,
                usageType.serviceQuality:  #C,
                usageType.sizeCategory: #L }
@UI.headerInfo:{
  typeName: 'SP Negotiation Item',
  typeNamePlural: 'SP Negotiation Item',
  typeImageUrl: '',
  description: { value: 'SPNegotiationItem' }
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_SrcgProjNegttnQtanItemTP'],
  allowNewDatasources: false,
  elementSuffix: 'SNI',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }
  
define view entity C_SrcgProjNegttnQtanItemTP
  as projection on R_SrcgProjNegttnQtanItemTP as _SrcgProjNegttnQtanItemTP
{
          @UI.hidden: true
  key     _SrcgProjNegttnQtanItemTP.SrcgProjNegttnQtanItemUUID,

          _SrcgProjNegttnQtanItemTP.SrcgProjNegttnQuotationUUID,

          _SrcgProjNegttnQtanItemTP.SourcingProjectNegotiationUUID,

          _SrcgProjNegttnQtanItemTP.SrcgProjQtnItemUUID,

          @UI.selectionField: [{ position: 40 }]
          _SrcgProjNegttnQtanItemTP.SourcingProjectQuotationItem,

          @UI.lineItem: [{ position: 10, importance: #HIGH }]
          @Semantics.amount.currencyCode: 'DocumentCurrency'
          _SrcgProjNegttnQtanItemTP.SrcgProjNegttnTargetNetPrcAmt,
           
           @Semantics.currencyCode: true
          _SrcgProjNegttnQtanItemTP.DocumentCurrency,

          _SrcgProjNegttnQtanItemTP.SourcingProjectItemStableUUID,
          
          @UI.hidden: true
          _SrcgProjQtnItemTP.SourcingProjectItemUUID,

          @Semantics.unitOfMeasure: true
          _SrcgProjNegttnQtanItemTP.RequestedQuantityUnit,

          @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
          _SrcgProjNegttnQtanItemTP.RequestedQuantity,

          @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
          _SrcgProjNegttnQtanItemTP.SrcgProjQtnOfferedQuantity,
          
          @UI.hidden: true
          @Semantics.currencyCode: true
          _SrcgProjNegttnQtanItemTP.SrcgProjQtnOfferCurrency,
          
          @UI.hidden: true
          @Semantics.amount.currencyCode: 'SrcgProjQtnOfferCurrency'
          _SrcgProjNegttnQtanItemTP.NetPriceAmount,
          
          @UI.hidden: true
          @Semantics.amount.currencyCode: 'SrcgProjQtnOfferCurrency'
          _SrcgProjNegttnQtanItemTP.SrcgProjQtnItemTotNetAmt,

          @UI.hidden: true
          _SrcgProjNegttnQtanItemTP.SrcgProjQuotationItemType,

          @UI.hidden: true
          _SrcgProjNegttnQtanItemTP.SrcgProjQtnItemClassification,

          @UI.hidden: true
          _SrcgProjNegttnQtanItemTP.SrcgProjQuotationItemParent,

          @UI.hidden: true
          _SrcgProjNegttnQtanItemTP.SrcgProjNegttnItmInclusionType,

          @UI.hidden: true
          _SrcgProjNegttnQtanItemTP.AlternativeItemID,

          @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
          _SrcgProjNegttnQtanItemTP.SrcgProjNegttnTargetQuantity,

          @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
          _SrcgProjNegttnQtanItemTP.SrcgProjNegttnMaxTargetQty,

          @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
          _SrcgProjNegttnQtanItemTP.SrcgProjNegttnTotalTargetQty,
          
          @Consumption.semanticObject: 'Material'
          @UI.lineItem: [{ position: 20, importance: #HIGH }]
          _SrcgProjNegttnQtanItemTP._SrcgProjQtnItemTP.Material,
  
          @Semantics.amount.currencyCode: 'DocumentCurrency'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SPNGNQTNITEM_TRANS_EXIT'
  virtual SPQtnItemTotNetAmtInDocCrcy   : vdm_spqtnitemtotnetamtindoccur,
          
          @Semantics.amount.currencyCode: 'DocumentCurrency'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SPNGNQTNITEM_TRANS_EXIT'
  virtual SPQtnItmNetPrcAmountInDocCrcy : vdm_srcgprojqtnitmnetamtdoccur,

          @Semantics.amount.currencyCode: 'DocumentCurrency'
          _SrcgProjNegttnQtanItemTP._SrcgProjQtnItemTP._SourcingProjectItem.SrcgProjItemTargetAmount,

          _SrcgProjNegttnQuotationTP    : redirected to parent C_SrcgProjNegttnQuotationTP,
          _SourcingProjectNegotiationTP : redirected to C_SourcingProjectNegotiationTP,
          @ObjectModel.sort.enabled: false
          @ObjectModel.filter.enabled: false
          _SrcgProjQtnItemTP            : redirected to C_SrcgProjQtnItemTP,

          _SPNegttnQtnItemDemandDistrTP : redirected to composition child C_SPNegttnQtnItemDemandDistrTP

}