C_SrcgProjItmDemandDistrTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@Metadata.allowExtensions: true

@ObjectModel: { semanticKey: ['Plant', 'CompanyCode', 'ProcurementHubSourceSystem', 'ProcurementProject'],
                representativeKey: 'SrcgProjDmndDistributionUUID',
                usageType.dataClass: #MIXED,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #M }

@VDM: { viewType:#CONSUMPTION,
        usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]  }

@EndUserText.label: 'Demand Distr for Srcg Proj Item - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['SrcgProjDemandDistributionTP'],
  allowNewDatasources: false,
  elementSuffix: 'SPD',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }

define view entity C_SrcgProjItmDemandDistrTP
  as projection on R_SrcgProjItmDemandDistrTP as SrcgProjDemandDistributionTP
{
  key      SrcgProjDmndDistributionUUID,
           SourcingProjectUUID,
           SourcingProjectItemUUID,

           @ObjectModel.text.element: ['ProcurementProjectName']
           ProcurementProject,
           ProcurementProjectUUID,

           @ObjectModel.text.element: ['PlantName']
           Plant,

           _SourcingProject.SourcingProjectType,

           @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
           MaxAnnualRequestedQuantity,
           _SourcingProjectItem.RequestedQuantityUnit,

           @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
           RequestedQuantity,

           _Plant.PlantName,

           cast( _ProcurementProject.ProcurementProjectName as vdm_procurementprojectnamelong preserving type ) as ProcurementProjectName,
           _ProcurementProjectPlant.ProductionStartDate,
           _ProcurementProjectPlant.ProductionEndDate,

           CompanyCode,
           _ProcmtHubCompanyCode.CompanyCodeName,

           @ObjectModel.text.element: ['ProcmtHubPurgOrgName']
           PurchasingOrganization,
           _ProcmtHubPurgOrg.ProcmtHubPurgOrgName,

           PurchasingGroup,
           StorageLocation,

           ProcurementHubSourceSystem,
           _ProcmtHubCompanyCode.ProcurementHubSourceSystemName,
           ProcmtHubPlantUniqueID,

           @UI.hidden: true
           SrcgProjFollowOnDocumentCat,
           @UI.hidden: true
           SrcgProjFollowOnDocumentType,

           CentralPurchaseContract,
           CentralPurchaseContractItem,
           DistributionKey,

           @ObjectModel.text.element: ['SrcgProjSourcingOriginText']
           SourcingOrigin,
           _SrcgProjSourcingOriginText.SrcgProjSourcingOriginText                                                                            : localized,
           @ObjectModel.text.element: ['SrcgProjSourcingScenarioText']
           SourcingScenario,
           _SrcgProjSourcingScenarioText.SrcgProjSourcingScenarioText                                                                        : localized,

           ProcmtPlanningPlantIsFixed,
           
           _SourcingProjectReasonText.ProductSourcingReasonText                                                 as SourcingProjectReasonText : localized,
           @ObjectModel.text.element: ['SourcingProjectReasonText']
           @Feature: 'BF:SOURCINGPROJECTREASONCODES'
           SrcgProjItemUnconfdDemandRsn,
           _SrcgProjItemDmndConfCodeText.SrcgProjItemDemandConfCodeName                                                                      : localized,
           @ObjectModel.text.element: ['SrcgProjItemDemandConfCodeName']
           SrcgProjItemDemandConfCode,

           @ObjectModel.virtualElement: true
           @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SRCGPROJ_DD_TRANS_EXIT'
  virtual  SrcgProjItmDmndConfCodeCritlty : mm_pur_srcgproj_uncnfdmdcrilty,

           @UI.hidden: true
           @ObjectModel.virtualElement: true
           @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SRCGPROJ_DD_TRANS_EXIT'
  virtual  UICT_ConfirmDmndIsDisabled     : abap_boolean,

           @UI.hidden: true
           @ObjectModel.virtualElement: true
           @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SRCGPROJ_DD_TRANS_EXIT'
  virtual  UICT_ConfirmDmndRsnIsEnabled   : abap_boolean,

           @UI.hidden: true
           @ObjectModel.virtualElement: true
           @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SRCGPROJ_DD_TRANS_EXIT'
  virtual  UICT_ConfirmDmndRsnIsDsbld     : abap_boolean,

           _PurchasingDocumentCategory,
           _PurchasingDocumentType,
           _ProcurementProjectPlant,

           _SrcgProjDmndDistrDetails : redirected to composition child C_SrcgProjItmDmndDistrDetailTP,
           @ObjectModel: { filter.enabled: false, sort.enabled: false }
           _SourcingProjectItem      : redirected to parent C_SourcingProjectItemTP,
           _SourcingProject          : redirected to C_SourcingProjectTP
}