C_SrcgProjAwardingScenarioTP

@AccessControl.authorizationCheck: #MANDATORY

@Search.searchable: true

@VDM: { viewType  :#CONSUMPTION,
        usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]  }

@ObjectModel: { semanticKey      : ['SrcgProjectAwardingScenario'],
                representativeKey: 'SrcgProjAwardingScenarioUUID',
                usageType:{ dataClass: #MIXED,
                            serviceQuality: #C,
                            sizeCategory: #L }
                }

@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser' ]

@Metadata.allowExtensions: true

@EndUserText.label: 'Awarding Scenario in Sourcing Project - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_SrcgProjAwardingScenarioTP'],
  allowNewDatasources: false,
  elementSuffix: 'SAH',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }


define root view entity C_SrcgProjAwardingScenarioTP
  provider contract transactional_query
  as projection on R_SrcgProjAwardingScenarioTP as _SrcgProjAwardingScenarioTP

  association [0..*] to C_SrcgProjQuotationCompare     as _SrcgProjQuotationCompare     on $projection.SourcingProjectUUID = _SrcgProjQuotationCompare.SourcingProjectUUID



  association [1..*] to C_SrcgProjItemHierarchy        as _SrcgProjItemHierarchy        on $projection.SourcingProjectUUID = _SrcgProjItemHierarchy.SourcingProjectUUID
  association [0..*] to I_SrcgProjAllowedCurrency      as _SrcgProjAllowedCurrency      on $projection.SourcingProjectUUID = _SrcgProjAllowedCurrency.SourcingProjectUUID
  association [0..*] to C_SrcgProjAwdgScenQtnItemSmmry as _SrcgProjAwdgScenQtnItemSmmry on $projection.SrcgProjAwardingScenarioUUID = _SrcgProjAwdgScenQtnItemSmmry.SrcgProjAwardingScenarioUUID
  association [0..1] to I_UserContactCard              as _CreatedByUser                on $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1] to I_UserContactCard              as _ChangedByUser                on $projection.LastChangedByUser = _ChangedByUser.ContactCardID
{
  key      SrcgProjAwardingScenarioUUID,
           @ObjectModel: { text.element: ['SrcgProjectAwardingScenName' ]}
           SrcgProjectAwardingScenario,
           SrcgProjectAwardingScenName,
           @ObjectModel.text.element: ['DomainValueName']
           SrcgProjAwardingScenIsPrfrd,
           _SrcgProjAwdgScenIsPreferred._Text.DomainValueName as DomainValueName : localized,

           SourcingProjectUUID,
           @Semantics.currencyCode: true
           _SourcingProject.DocumentCurrency                  as DocumentCurrency,
           @Semantics.amount.currencyCode: 'DocumentCurrency'
           _SourcingProject.SrcgProjTotalTargetAmount         as SrcgProjTotalTargetAmount,
           @ObjectModel: { text.element: ['SrcgProjVersionConcatenated'] }
           @Consumption.semanticObject: 'SourcingProject'
           _SourcingProject.SourcingProject                   as SourcingProject,
           _SourcingProject.SrcgProjVersionConcatenated       as SrcgProjVersionConcatenated,
           _SourcingProject.SourcingProjectVersion,
           @ObjectModel.text.element: ['SrcgProjLifecycleStatusName']
           _SourcingProject.SrcgProjLifecycleStatus           as SrcgProjLifecycleStatus,
           _SrcgProjLifecycleStatusText.SrcgProjLifecycleStatusName              : localized,

           @ObjectModel.text.element: ['SrcgProjAwdgScenLfcycStsName']
           SrcgProjAwdgScenLifecycleSts,
           @UI.hidden: true
           _SrcgProjAwdgScenLfcycStsText.SrcgProjAwdgScenLfcycStsName            : localized,

           @ObjectModel.text.element: ['SrcgProjAwdgScenApprvlStsName']
           SrcgProjAwdgScenApprovalStatus,
           @UI.hidden: true
           SrcgProjAwdgScenAwardingStatus,
           @UI.hidden: true
           _SrcgProjAwdgScenApprvlStsTxt.SrcgProjAwdgScenApprvlStsName           : localized,


           @UI.hidden: true
           _SourcingProject.SourcingProjectType,
           @UI.hidden: true
           _SourcingProject.PurchasingGroup,
           @UI.hidden: true
           _SourcingProject.PurchasingOrganization,
           @UI.hidden: true
           _SourcingProject.CompanyCode,
           @UI.hidden: true
           _SourcingProject.MaterialGroup,

           @ObjectModel: {
                           virtualElement,
                           virtualElementCalculatedBy: 'ABAP:CL_MM_SPAWD_ISAWARDABLE_EXIT'
                         }

  virtual  SrcgProjAwardingScenIsAwdbl   : vdm_spawdscenawardable,

           @Semantics.amount.currencyCode: 'DocumentCurrency'
           @ObjectModel: {
                           virtualElement,
                           virtualElementCalculatedBy: 'ABAP:CL_MM_SPAWD_AMTDEVIATION_EXIT' }
  virtual  SrcgProjAwardingScenTotNetAmt : vdm_spawdscentotalnetamount,

           @Semantics.booleanIndicator: true
           @ObjectModel: {
                           virtualElement,
                           virtualElementCalculatedBy: 'ABAP:CL_MM_SPAWD_AMTDEVIATION_EXIT' }
  virtual  IsChangeDocumentsEnabled      : abap.char( 1 ),

           @ObjectModel: {
                           virtualElement,
                           virtualElementCalculatedBy: 'ABAP:CL_MM_SPAWD_NUMOFAWRDAWDSCENEX' }
  virtual  NumberOfAwardedAwdgScenarios  : vdm_spawdscenawardedcount,

           @UI.hidden: true
           @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_SPAWD_HDR_NOTE_EXIT'
  virtual  NoteTypeListText              : abap.char( 450 ),

           CreatedByUser,
           CreationDateTime,
           LastChangedByUser,
           LastChangeDateTime,
           SrcgProjAwdgScenAwardingDate,

           /*Associations*/
           _SrcgProjQuotationCompare,
           @ObjectModel.filter.enabled: false
           _SrcgProjItemHierarchy,
           _SrcgProjAllowedCurrency,
           _SrcgProjAwardingScenQtn : redirected to composition child C_SrcgProjAwardingScenQtnTP,
           @UI.hidden:true
           _SrcgProjAwdgScenIsPreferred,

           @ObjectModel.filter.enabled: false
           @ObjectModel.sort.enabled: false
           _SrcgProjAwdgScenQtnItemSmmry,
           _CreatedByUser,
           _ChangedByUser,
           @Consumption.hidden: true
           _SourcingProject,
           @UI.hidden: true
           _SourcingProjectTP
}