C_SourcingProjectItemDocVarbl

@AbapCatalog.sqlViewName: 'CSRCGPROJITMVB'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel:{ representativeKey: 'SourcingProjectItemUUID',
               semanticKey: ['SourcingProjectItem'],
               usageType.dataClass: #MIXED,
               usageType.serviceQuality: #C,
               usageType.sizeCategory: #M }

@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Doc Varbl for Item in Sourcing Project'

define view C_SourcingProjectItemDocVarbl
  as select from R_SourcingProjectItem

 //foreign key associations

  association [1..1] to R_SourcingProject            as _SrcgProj            on  $projection.SourcingProjectUUID = _SrcgProj.SourcingProjectUUID
  association [0..1] to C_SourcingProjectDocVarbl    as _SourcingProject            on $projection.SourcingProjectUUID = _SourcingProject.SourcingProjectUUID

  association [1..1] to I_MaterialGroup               as _MaterialGroup               on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_ProductTypeCode             as _ProductType                 on  $projection.ProductType = _ProductType.ProductTypeCode
  association [0..1] to I_BackendPlantForPurg         as _BackendPlantForPurg         on  $projection.Plant                      = _BackendPlantForPurg.Plant
                                                                                        and $projection.CompanyCode                = _BackendPlantForPurg.CompanyCode
                                                                                        and $projection.ProcurementHubSourceSystem = _BackendPlantForPurg.ProcurementHubSourceSystem
  association [1..1] to I_BackendCoCodeForPurg        as _BackendCoCodeForPurg        on  $projection.ProcurementHubSourceSystem = _BackendCoCodeForPurg.ProcurementHubSourceSystem
                                                                                        and $projection.CompanyCode                = _BackendCoCodeForPurg.CompanyCode
  association [0..1] to I_ProcmtHubPurgOrg            as _ProcmtHubPurgOrg            on  $projection.PurchasingOrganization     = _ProcmtHubPurgOrg.ProcmtHubPurchasingOrg
                                                                                        and $projection.ProcurementHubSourceSystem = _ProcmtHubPurgOrg.ProcurementHubSourceSystem
  association [0..1] to I_PurgDocumentCategoryText    as _PurgDocumentCategoryText    on $projection.SrcgProjFollowOnDocumentCat = _PurgDocumentCategoryText.PurchasingDocumentCategory
                                                                                         and _PurgDocumentCategoryText.Language = $session.system_language
  association [0..1] to I_PurchasingDocumentTypeText   as _PurchasingDocumentTypeText   on  $projection.SrcgProjFollowOnDocumentType = _PurchasingDocumentTypeText.PurchasingDocumentType
                                                                                       and $projection.SrcgProjFollowOnDocumentCat  = _PurchasingDocumentTypeText.PurchasingDocumentCategory
                                                                                       and _PurchasingDocumentTypeText.Language = $session.system_language  
{

  key SourcingProjectItemUUID           as SourcingProjectItemUUID,
      SourcingProjectItem               as SourcingProjectItem,
      SourcingProjectUUID               as SourcingProjectUUID,

      SourcingProjectItemType           as SourcingProjectItemType,
      _SourcingProjectItemType._SourcingProjectItemTypeText[1: Language = $session.system_language ].SourcingProjectItemTypeName,

      SrcgProjItemClassification        as SrcgProjItemClassification,
      _SrcgProjItemClassification._SrcgProjItemClassfctnText[1: Language = $session.system_language ].SrcgProjItemClassificationName,
      
      SourcingProjectItemStableUUID     as SourcingProjectItemStableUUID,

      SrcgProjItemDescription           as SrcgProjItemDescription,

      Material                          as Material,
//      _Material._Text[1: Language = $session.system_language ].MaterialName, 

      
      ProductType                       as ProductType,
      _ProductType._Text[1: Language = $session.system_language ].Name as ProductTypeName,
      
      MaterialGroup                     as MaterialGroup,
      _MaterialGroup._Text[1: Language = $session.system_language ].MaterialGroupName,
      _MaterialGroup._Text[1: Language = $session.system_language ].MaterialGroupText,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      SrcgProjItemTargetAmount          as SrcgProjItemTargetAmount,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      SrcgProjItemTotalTargetAmount     as SrcgProjItemTotalTargetAmount,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      RequestedQuantity                 as RequestedQuantity,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      MaximumRequestedQuantity          as MaximumRequestedQuantity,

      @Semantics.unitOfMeasure: true
      RequestedQuantityUnit             as RequestedQuantityUnit,
      _RequestedQuantityUnit._Text[1: Language = $session.system_language ].UnitOfMeasureLongName,
      _RequestedQuantityUnit._Text[1: Language = $session.system_language ].UnitOfMeasureName,
      
      RequestedDeliveryDate             as RequestedDeliveryDate,
      PerformancePeriodStartDate        as PerformancePeriodStartDate,
      PerformancePeriodEndDate          as PerformancePeriodEndDate,

      OrderItemQtyToBaseQtyNmrtr        as OrderItemQtyToBaseQtyNmrtr,
      OrderItemQtyToBaseQtyDnmntr       as OrderItemQtyToBaseQtyDnmntr,

      Plant                             as Plant,
      _BackendPlantForPurg.PlantName,
      
      CompanyCode                       as CompanyCode,
      _BackendCoCodeForPurg.CompanyCodeName, 
      
      PurchasingGroup                   as PurchasingGroup,

      PurchasingOrganization            as PurchasingOrganization,
      _ProcmtHubPurgOrg.ProcmtHubPurgOrgName,

      StorageLocation                   as StorageLocation,

      SourcingProjectItemParent         as SourcingProjectItemParent,
      HierarchyNodeLevel                as HierarchyNodeLevel,
      AlternativeItemID                 as AlternativeItemID,
      FormattedItemID                   as FormattedItemID,

      PurchaseRequisition               as PurchaseRequisition,
      PurchaseRequisitionItem           as PurchaseRequisitionItem,

      SrcgProjFollowOnDocumentCat       as SrcgProjFollowOnDocumentCat,
      _PurgDocumentCategoryText.PurchasingDocumentCategoryName,

      SrcgProjFollowOnDocumentType      as SrcgProjFollowOnDocumentType,
      _PurchasingDocumentTypeText.PurchasingDocumentTypeName,
      
      SrcgProjItemDemandConfCode        as SrcgProjItemDemandConfCode,
      SrcgProjItemUnconfdDemandRsn      as SrcgProjItemUnconfdDemandRsn,

      @UI.hidden: true
      ProcurementHubSourceSystem,
      
      @Semantics.currencyCode: true
      _SrcgProj.DocumentCurrency as DocumentCurrency,
      _ItemDocumentCurrency._Text[1: Language = $session.system_language ].CurrencyName,
      _ItemDocumentCurrency._Text[1: Language = $session.system_language ].CurrencyShortName,
    
      /* Associations */
      
      @Consumption.hidden:true
      _SourcingProject

}