C_SourcingProjectContactTP

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData.blocking: #REQUIRED
}

@VDM: { viewType:   #CONSUMPTION,
        usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]  }

@ObjectModel: { representativeKey: 'SourcingProjectContactUUID',
                usageType: {
                  dataClass:      #TRANSACTIONAL,
                  serviceQuality: #C,
                  sizeCategory:   #L
                }
}

@Metadata.allowExtensions: true

@EndUserText.label: 'Contact for Sourcing Project - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['SourcingProjectContactTP'],
  allowNewDatasources: false,
  elementSuffix: 'SPC',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }

define view entity C_SourcingProjectContactTP 
  as projection on R_SourcingProjectContactTP as SourcingProjectContactTP

  association [0..1] to I_EmplContactCard as _ContactCard on $projection.BusinessPartner = _ContactCard.Person
{
  key     SourcingProjectContactUUID,
          SourcingProjectUUID,

          _SourcingProject.SourcingProjectType,

          @ObjectModel.text.element: ['BusinessPartnerFullName']
          cast (BusinessPartner as mm_pur_srcgproj_contact_id  preserving type ) as BusinessPartner,
          _BusinessPartner.PersonFullName,
          
          @UI.hidden:true
          _BusinessPartner.BusinessPartnerFullName,


          @ObjectModel.text.element: ['SourcingProjectContactCatName']
          SourcingProjectContactCategory,

          _ContactCatText.SourcingProjectContactCatName              : localized,


          @Semantics:{ eMail.type:  [ #WORK ] }
          @Semantics.eMail.address: true
          @Semantics.text: true
          @ObjectModel.virtualElement: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_PUR_SRCGPROJ_CONTCT_EXIT'
  virtual EmailAddress             :mm_pur_srcgproj_contact_email,

          @Semantics.telephone.type: [#WORK, #PREF]
          @Semantics.text: true
          @ObjectModel.virtualElement: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MM_PUR_SRCGPROJ_CONTCT_EXIT'
  virtual InternationalPhoneNumber :mm_pur_srcgproj_contact_phone,
          SrcgProjCntctIsVisibleToSuplr,
          SrcgProjContactIsContributor,

          BusinessPartnerUUID,

          IsBusinessPurposeCompleted,

          AuthorizationGroup,

          @ObjectModel.text.element: ['SrcgProjSourcingOriginText']
          SourcingOrigin,
          _SrcgProjSourcingOriginText.SrcgProjSourcingOriginText     : localized,

          @ObjectModel.text.element: ['SrcgProjSourcingScenarioText']
          SourcingScenario,
          _SrcgProjSourcingScenarioText.SrcgProjSourcingScenarioText : localized,

          _ContactCard,
          @Consumption.hidden:true
          _BusinessPartner,
          _SourcingProject : redirected to parent C_SourcingProjectTP
}