C_SoldToValueHelp

@AbapCatalog: {
   sqlViewName: 'CSDDOCSOLDTOVH',
   compiler.compareFilter: true
}
//

@ClientDependent: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Sold-to Party'

@VDM: {
  viewType: #CONSUMPTION
}

@Search: {
  searchable: true
}

@Consumption.ranked: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.dataCategory: #VALUE_HELP

@UI.headerInfo:{
  typeName:             'Sold-To Party',
  typeName_AsOTR:       '005056AC01D01EE38EFB9D957C3168FF',
  typeNamePlural:       'Sold-To Parties',
  typeNamePlural_AsOTR: '005056AC156F1EE5A6B6C39EF29D288D',
  imageUrl:             'BusinessPartnerImageURL',
  title: {
     type:  #STANDARD,
     value: 'CustomerName'
   },
   description: {
     type:   #STANDARD,
     value:  'Customer'
   }
}

@ObjectModel.representativeKey: 'Customer'


//@UI.presentationVariant:{

//    sortOrder: [

//        { by: 'Customer', direction: #ASC },

//          {by: 'CustomerName', direction: #ASC }]

//}

define view C_SoldToValueHelp
  as select from I_Customer as customer
  association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on  $projection.AddressID                         = _CurrentDfltLandlinePhoneNmbr.AddressID
                                                                                        and _CurrentDfltLandlinePhoneNmbr.AddressPersonID is initial

  association [0..1] to I_AddrCurDefaultEmailAddress   as _CurrentDfltEmailAddress      on  $projection.AddressID                    = _CurrentDfltEmailAddress.AddressID
                                                                                        and _CurrentDfltEmailAddress.AddressPersonID is initial

  association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on  $projection.AddressID                         = _CurrentDfltMobilePhoneNumber.AddressID
                                                                                        and _CurrentDfltMobilePhoneNumber.AddressPersonID is initial

{

      @UI.facet: [ {
          purpose:    #QUICK_VIEW,
          type:       #FIELDGROUP_REFERENCE,
          targetQualifier: 'SoldToQuickView',
          label: 'Standard Address'
        }
      ]

      @UI: {
          lineItem: [{ position:10, importance:#HIGH }],
          selectionField: [{ position: 10 }]
          }
      @EndUserText.label : 'Customer'
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH }
      @Search.fuzzinessThreshold: 0.9
      @ObjectModel.text.element:  [ 'CustomerName' ]
  key customer.Customer,
      @Consumption.hidden: true
      customer.AddressID,

      @UI: {
      identification: [{position: 20, importance: #HIGH}],
      lineItem: [{ position:20, importance:#HIGH }],
      selectionField: [{ position: 20 }] }
      @EndUserText.label : 'Name'
      @Semantics.text:true
      @Semantics.name.fullName: true
      customer.CustomerName,

      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
      customer.OrganizationBPName1,

      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
      customer.OrganizationBPName2,

      @UI.hidden: true
      @Semantics.imageUrl: true
      cast (
      case
      when _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerCategory  = '1'
      then 'sap-icon://customer'

      else  'sap-icon://building'

      end  as abap.sstring( 255 ) )                          as BusinessPartnerImageURL,

      @UI: {
      identification: [{position: 40, importance: #HIGH}],
      lineItem: [{ position: 30, importance: #LOW }],
      selectionField: [{ position: 30 }],
      fieldGroup:     [{ qualifier:'SoldToQuickView', position: 10}]}
      @Semantics.address.zipCode:true
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.9
      }
      customer._AddressDefaultRepresentation.PostalCode,

      @UI: {
      identification: [{position: 50, importance: #HIGH}],
      lineItem: [{ position: 40, importance: #LOW }],
      selectionField: [{ position: 40 }],
      fieldGroup:     [{ qualifier:'SoldToQuickView', position: 20}]}
      @Semantics.address.city:true
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.9
      }
      customer._AddressDefaultRepresentation.CityName,

      @UI: {
      identification: [{position: 60, importance: #HIGH}],
      lineItem: [{ position: 50, importance: #LOW }],
      selectionField: [{ position: 50 }],
      fieldGroup:     [{ qualifier:'SoldToQuickView', position: 30}]}
      @Semantics.address.country:true
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.9
      }
      customer._AddressDefaultRepresentation.Country,

      @Semantics.address.street: true
      @UI.fieldGroup: [{ qualifier:'SoldToQuickView', hidden: true, exclude: true }]
      customer._AddressDefaultRepresentation.StreetName,

      @Semantics.address.number: true
      @UI.hidden: true
      @UI.fieldGroup: [{ qualifier:'SoldToQuickView', hidden: true, exclude: true }]
      customer._AddressDefaultRepresentation.HouseNumber,
      @UI.hidden: true
      @Semantics.telephone.type: [ #PREF, #WORK ]
      _CurrentDfltLandlinePhoneNmbr.InternationalPhoneNumber,

      @UI.hidden: true
      @Semantics.telephone.type: [ #CELL ]
      _CurrentDfltMobilePhoneNumber.InternationalPhoneNumber as InternationalMobilePhoneNumber,

      @UI.hidden: true
      @Semantics.eMail:{ address: true, type: [ #WORK ] }
      _CurrentDfltEmailAddress.EmailAddress,

      //    DCL relevant fields

      @Consumption.hidden: true
      customer.CustomerAccountGroup,
      @Consumption.hidden: true
      customer.AuthorizationGroup,
      @Consumption.hidden: true
      customer.IsBusinessPurposeCompleted,
      //Added for DPP Data Controller

      @Consumption.hidden:true
      customer.DataControllerSet,
      @Consumption.hidden:true
      customer.DataController1,
      @Consumption.hidden:true
      customer.DataController2,
      @Consumption.hidden:true
      customer.DataController3,
      @Consumption.hidden:true
      customer.DataController4,
      @Consumption.hidden:true
      customer.DataController5,
      @Consumption.hidden:true
      customer.DataController6,
      @Consumption.hidden:true
      customer.DataController7,
      @Consumption.hidden:true
      customer.DataController8,
      @Consumption.hidden:true
      customer.DataController9,
      @Consumption.hidden:true
      customer.DataController10

}