C_SoldToSlsOrgDistrChnlDivVH

@ClientHandling.algorithm : #SESSION_VARIABLE

@VDM: {
  viewType: #CONSUMPTION
}

@AbapCatalog: {
  sqlViewName: 'CSPBYSLSORGDCDIV',
  compiler.compareFilter: true,
  preserveKey: true
  }

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking:#REQUIRED,
  personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
  }


@ObjectModel:{
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XXL,
    dataClass: #MASTER },
  dataCategory: #VALUE_HELP }

@Search.searchable: true

@Consumption.ranked: true

@EndUserText.label: 'Customer Sales Area'

@UI.headerInfo:{
  typeName:       'Sold-to by Sales Area',
  typeNamePlural: 'Sold-to by Sales Area'
}

@Metadata.ignorePropagatedAnnotations: true

define view C_SoldToSlsOrgDistrChnlDivVH
  as select from I_CustomerSalesArea as CustomerSalesArea

  association [0..*] to I_SalesArea               as _SalesArea               on  $projection.SalesOrganization_H   = _SalesArea.SalesOrganization
                                                                              and $projection.DistributionChannel_H = _SalesArea.ReferenceDistributionChannel
                                                                              and $projection.Division_H            = _SalesArea.ReferenceDivision

  association [0..*] to I_SalesOrganizationText   as _SalesOrganizationText   on  $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
  association [0..*] to I_DistributionChannelText as _DistributionChannelText on  $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText            as _DivisionText            on  $projection.Division = _DivisionText.Division
{

      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.9
      }
      @ObjectModel.text.element:  [ 'CustomerName' ]
      @UI: {
       lineItem:[{ position: 10, importance: #HIGH }],
       selectionField:[{ position: 10 }] }
  key CustomerSalesArea.Customer,

      @ObjectModel.text.association: '_SalesOrganizationText'
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW }
      @UI: {
       lineItem:[{ position: 30, importance: #HIGH }],
       selectionField:[{ position: 30 }],
       textArrangement: #TEXT_FIRST }
      @Consumption.valueHelpDefault.binding.usage:#FILTER_AND_RESULT
  key _SalesArea.SalesOrganization,

      @ObjectModel.text.association: '_DistributionChannelText'
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW }
      @UI: {
       lineItem:[{ position: 40, importance: #HIGH }],
       selectionField:[{ position: 40 }],
       textArrangement: #TEXT_FIRST }
      @Consumption.valueHelpDefault.binding.usage:#FILTER_AND_RESULT
  key _SalesArea.DistributionChannel,

      @ObjectModel.text.association: '_DivisionText'
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW }
      @UI: {
       lineItem:[{ position: 50, importance: #HIGH }],
       selectionField:[{ position: 50 }],
       textArrangement: #TEXT_FIRST }
      @Consumption.valueHelpDefault.binding.usage:#FILTER_AND_RESULT
  key _SalesArea.Division,

      @Consumption.hidden: true
      CustomerSalesArea.SalesOrganization   as SalesOrganization_H,

      @Consumption.hidden: true
      CustomerSalesArea.DistributionChannel as DistributionChannel_H,

      @Consumption.hidden: true
      CustomerSalesArea.Division            as Division_H,

      @UI:{
        lineItem:[{ position: 20, importance: #HIGH }],
        selectionField:[{ position: 20 }]
      }
      @Semantics.text: true
      @EndUserText.label : 'Name'
      CustomerSalesArea._Customer.CustomerName,

      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
      CustomerSalesArea._Customer.OrganizationBPName1,
     
      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
      CustomerSalesArea._Customer.OrganizationBPName2,
      
      @UI.lineItem: [{ position:60, importance:#LOW }]
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
      CustomerSalesArea._Customer._AddressDefaultRepresentation.AddressSearchTerm1,
      
      @UI.lineItem: [{ position:70, importance:#LOW }]
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
      CustomerSalesArea._Customer._AddressDefaultRepresentation.AddressSearchTerm2,

      @Consumption.filter.hidden: true
      _SalesOrganizationText,
      @Consumption.filter.hidden: true
      _DistributionChannelText,
      @Consumption.filter.hidden: true
      _DivisionText,

      //Needed for DCL

      @Consumption.hidden: true
      AuthorizationGroup,
      @Consumption.hidden: true
      @Semantics.booleanIndicator :true
      IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      _Customer

}
where
  CustomerSalesArea.DeletionIndicator is initial