C_SlsDocFlfmtDelivDocItem

 @ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED 
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.semanticKey: ['DeliveryDocument', 'DeliveryDocumentItem']
@ObjectModel.representativeKey: 'DeliveryDocumentItem'

@EndUserText.label: 'Sales Doc Fulfillment: Delivery Doc Item'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@Search.searchable: false
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CSOFDELIVDOCITEM'

define view C_SlsDocFlfmtDelivDocItem 

as select from I_DeliveryDocumentItem as Item

//Extensibility

association [0..1] to E_DeliveryDocumentItem as _Extension on  $projection.DeliveryDocument     = _Extension.DeliveryDocument
                                                           and $projection.DeliveryDocumentItem = _Extension.DeliveryDocumentItem
{
  //Key

  //SDF4 

  @Consumption.valueHelpDefinition: [{ entity:  { name: 'I_DeliveryDocumentStdVH', element: 'DeliveryDocument' }}]
  @ObjectModel.foreignKey.association: '_DeliveryDocument'
  key Item.DeliveryDocument,
  key Item.DeliveryDocumentItem,
    
  //Category 

  Item.DeliveryDocumentItemCategory,
  Item.DeliveryDocumentItemText,
  
  //Product

  //SDF4    

  @Consumption.valueHelpDefinition: [{ entity:  { name: 'I_ProductStdVH', element: 'Product' }}]
  @ObjectModel.text.element: [ 'MaterialName' ]
  @Consumption.semanticObject: 'Material'
  cast(Item.Material as productnumber preserving type ) as Material,
  @UI.hidden: true
  Item._Material._Text[1:Language=$session.system_language].MaterialName,
  Item.MaterialByCustomer,
  cast(Item.MaterialGroup as productgroup preserving type ) as MaterialGroup, 
  @Consumption.semanticObject: 'Batch'
  Item.Batch,                                 
  Item.Plant,
  //SDF4   

  @Consumption.valueHelpDefinition: [{ entity:  { name: 'I_WarehouseStdVH', element: 'Warehouse' }}]
  @ObjectModel.text.element: 'WarehouseName'
  Item.Warehouse,
  @UI.hidden: true
  Item._Warehouse._Text[1:Language=$session.system_language].WarehouseName,
  Item.StorageLocation,
     
  //Delivery

  @DefaultAggregation: #NONE
  Item.ActualDeliveryQuantity,
  Item.DeliveryQuantityUnit,
  @DefaultAggregation: #NONE
  Item.ItemGrossWeight,
  @DefaultAggregation: #NONE
  Item.ItemNetWeight,
  Item.ItemWeightUnit,
  @DefaultAggregation: #NONE    
  Item.ItemVolume,
  Item.ItemVolumeUnit,
  Item.LoadingGroup,
  Item.TransportationGroup,
  Item.GoodsMovementType,
  Item.InventorySpecialStockType,
  Item.StockType,
  @Consumption.valueHelpDefinition: [{ entity:  { name: 'I_WarehouseStagingAreaStdVH', element: 'WarehouseStagingArea' },
                                       additionalBinding: [{ localElement: 'Warehouse', element: 'Warehouse' }]}]
  @ObjectModel.text.element: 'WarehouseStagingAreaName'
  Item.WarehouseStagingArea,
  @UI.hidden: true
  Item._WarehouseStagingArea._Text[1:Language=$session.system_language].WarehouseStagingAreaName,
  Item.OverdelivTolrtdLmtRatioInPct,   
  Item.UnderdelivTolrtdLmtRatioInPct,
    
  //Billing

  Item.ItemBillingBlockReason,
  
  //Status

  Item.PickingStatus,
  Item.DeliveryRelatedBillingStatus,
  Item.PackingStatus,
  Item.PickingConfirmationStatus,
  Item.WarehouseActivityStatus,
  Item.GoodsMovementStatus,
  @ObjectModel.foreignKey.association: '_ChmlCmplncStatus'
  cast( Item.ChmlCmplncStatus     as mon_tdd_pcsta preserving type ) as ChmlCmplncStatus,
  @ObjectModel.foreignKey.association: '_DangerousGoodsStatus'
  cast( Item.DangerousGoodsStatus as mon_tdd_dgsta preserving type ) as DangerousGoodsStatus,
  @ObjectModel.foreignKey.association: '_SafetyDataSheetStatus'
  cast( Item.SafetyDataSheetStatus as mon_tdd_sdssta preserving type ) as SafetyDataSheetStatus,
  @ObjectModel.foreignKey.association: '_TrdCmplncEmbargoSts'
  cast( Item.TrdCmplncEmbargoSts as embargochksts preserving type ) as TrdCmplncEmbargoSts,
  @ObjectModel.foreignKey.association: '_TrdCmplncSnctndListChkSts'
  cast( Item.TrdCmplncSnctndListChkSts as watchlistscrngchksts preserving type ) as TrdCmplncSnctndListChkSts,
  @ObjectModel.foreignKey.association: '_TrdCmplncLegalControlSts'
  cast( Item.TrdCmplncLegalControlSts as trdcmplnclglctrlchksts preserving type ) as TrdCmplncLegalControlSts,
         
  //Associations 

  @Consumption.filter.hidden: true
  _DeliveryDocument,
  @Consumption.filter.hidden: true
  _ItemCategory,
  @Consumption.filter.hidden: true 
  _MaterialGroup,
  @Consumption.filter.hidden: true 
  _Plant,
  @Consumption.filter.hidden: true 
  _StorageLocation,
  @Consumption.filter.hidden: true
  _DeliveryQuantityUnit,
  @Consumption.filter.hidden: true
  _ItemWeightUnit,
  @Consumption.filter.hidden: true
  _ItemVolumeUnit,
  @Consumption.filter.hidden: true
  _LoadingGroup,
  @Consumption.filter.hidden: true
  _TransportationGroup,
  @Consumption.filter.hidden: true
  _GoodsMovementType,
  @Consumption.filter.hidden: true
  _InventorySpecialStockType,
  @Consumption.filter.hidden: true
  _ItemBillingBlockReason,
  @Consumption.filter.hidden: true
  _PickingStatus,
  @Consumption.filter.hidden: true
  _DeliveryRelatedBillingStatus,
  @Consumption.filter.hidden: true
  _PackingStatus,
  @Consumption.filter.hidden: true
  _PickingConfirmationStatus,
  @Consumption.filter.hidden: true
  _WarehouseActivityStatus,
  @Consumption.filter.hidden: true
  _GoodsMovementStatus,
  @Consumption.filter.hidden: true
  Item._ChmlCmplncStatus,
  @Consumption.filter.hidden: true
  Item._DangerousGoodsStatus,
  @Consumption.filter.hidden: true 
  Item._SafetyDataSheetStatus,
  @Consumption.filter.hidden: true
  Item._TrdCmplncEmbargoSts,
  @Consumption.filter.hidden: true
  Item._TrdCmplncSnctndListChkSts,
  @Consumption.filter.hidden: true 
  Item._TrdCmplncLegalControlSts  
   };