C_ShopFloorOrderDefect

@AbapCatalog.sqlViewName: 'CMPESFODEFECT'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Defects for Shop Floor Order'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@VDM: {viewType: #CONSUMPTION}
@UI.headerInfo.typeName: 'Defect'
@UI.headerInfo.typeNamePlural: 'Defects'
@UI.headerInfo.title.label: 'Defect'

define view C_ShopFloorOrderDefect
  as select from           I_MfgOrderDefectRecord     as Defect

  //  I_SFIOfOriginalReplacedSFI as ShopFloorItem

  //

  //    inner join             I_MfgOrderDefectRecord     as Defect                 on Defect.ShopFloorItem = ShopFloorItem.ShopFloorItem



  //    left outer to one join I_Equipment                as Equipment              on Defect.Equipment = Equipment.Equipment

  //    left outer to one join I_ShopFloorItem            as ShopFloorItem1         on  ShopFloorItem1.Material           = Equipment.Material

  //                                                                                and ShopFloorItem1.SerialNumber       = Equipment.SerialNumber

  //                                                                                and ShopFloorItem1.ManufacturingOrder = Defect.ProductionOrder

    left outer to one join I_SFIOfOriginalReplacedSFI as ShopFloorItem          on ShopFloorItem.ShopFloorItem = Defect.ShopFloorItem
    left outer to one join I_MfgOrderOperationBasic   as MfgOrderOperationBasic on  MfgOrderOperationBasic.OrderInternalBillOfOperations = Defect.OrderInternalID
                                                                                and MfgOrderOperationBasic.OrderIntBillOfOperationsItem  = Defect.InspPlanOperationInternalID

  association [0..1] to I_SitnInstceIndicator   as _Sitn                  on  _Sitn.SitnInstceAnchorObjectKey = $projection.Defect
                                                                          and _Sitn.SitnDefAnchorObject       = 'Defect'
  association [1..1] to I_OperationActivityText as _OperationActivityText on  $projection.ProductionOrderOperationActy = _OperationActivityText.OperationActivity
                                                                          and $projection.ProductionOrderOpActyVers    = _OperationActivityText.OperationActyVersionCounter
                                                                          and _OperationActivityText.Language          = $session.system_language
  association [0..1] to I_DefectCodeText        as _DefectCodeText        on  $projection.DefectCodeGroup = _DefectCodeText.DefectCodeGroup
                                                                          and $projection.DefectCode      = _DefectCodeText.DefectCode
                                                                          and _DefectCodeText.Language    = $session.system_language

  association [0..1] to I_MaterialText          as _MaterialText          on  $projection.Material   = _MaterialText.Material
                                                                          and _MaterialText.Language = $session.system_language
  association [0..1] to I_MaterialText          as _ProducedMatText       on  $projection.ProducedMaterial = _ProducedMatText.Material
                                                                          and _ProducedMatText.Language    = $session.system_language
{


         @UI.hidden: true
  key    Defect.DefectInternalID,
         @UI: {
          lineItem: [{position: 30}]
         }
  key    Defect.NotificationItem,
         @UI: {
           textArrangement: #TEXT_FIRST,
           lineItem: [{position: 10}]
         }
         @ObjectModel.text.element: ['DefectText']
         @Consumption.semanticObject:'Defect'
         Defect.Defect,
         @UI.hidden: true
         @Semantics.text: true
         Defect.DefectText,
         @ObjectModel.text.element: ['NotificationText']
         @UI: {
           lineItem: [{position: 20}]
         }
         @Consumption.semanticObject:'QualityNotification'
         Defect.Notification,
         @Semantics.text: true
         @UI.hidden: true
         @EndUserText.label: 'Notification Text'
         Defect.NotificationText,
         @UI.hidden: true
         ShopFloorItem.OriginalReplacedShopFloorItem,
         @UI.hidden: true
         ShopFloorItem.ShopFloorItem,
         Defect.DefectCategory,
         @UI.hidden: true
         Defect.NotificationType,

         @UI.hidden: true
         Defect.DefectCodeCatalog,
         @UI.hidden: true
         Defect.DefectCodeGroup,
         @ObjectModel.text.element: ['DefectCodeText']
         @UI: {
           textArrangement: #TEXT_FIRST,
           lineItem: [{position: 40}]
         }
         Defect.DefectCode,
         @Semantics.text: true
         @UI.hidden: true
         _DefectCodeText.DefectCodeText,
         @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'
         Defect.DefectiveQuantity,
         @Semantics.unitOfMeasure: true
         @UI.hidden: true
         Defect.DefectiveQuantityUnit,
         @UI.hidden: true
         Defect.DefectIsCreatedAutomatically,
         @UI.hidden: true
         Defect.OpActyNtwkInstance,
         @UI.hidden: true
         Defect.OpActyNtwkElement,
         @UI.hidden: true
         Defect.ProductionOrderOperationActy,
         @UI.hidden: true
         Defect.ProductionOrderOpActyVers,
         @ObjectModel.text.element: ['MfgDefectDecisionName']
         @UI: {
           textArrangement: #TEXT_ONLY,
           lineItem: [{position: 50}]
          }
         Defect.MfgDefectDecision,
         @UI.hidden: true
         @Semantics.text: true
         Defect.MfgDefectDecisionName,
         @ObjectModel.text.element: ['MfgOrderOperationText']
         @UI: {
           lineItem: [{position: 60}]
         }
         MfgOrderOperationBasic.ManufacturingOrderOperation_2 as ManufacturingOrderOperation,
         @Semantics.text: true
         @UI.hidden: true
         MfgOrderOperationBasic.MfgOrderOperationText,
         @ObjectModel.text.element: ['OperationActivityName']
         @UI: {
           textArrangement: #TEXT_FIRST,
           lineItem: [{position: 70}]
         }
         Defect.OpActyNtwkElementExternalID,
         @Semantics.text: true
         @UI.hidden: true
         _OperationActivityText.OperationActivityName,
         Defect.ProductionOrder,
         Defect.InspectionCharacteristic,
         @ObjectModel.virtualElement: true
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_NONCF_COMP_SADL_EXIT'
         cast('' as vmp_ref_des)                                                               as ReferenceDesignatorValue,
         @UI.hidden: true
         Defect.IsDeleted,
         @UI: {
           textArrangement: #TEXT_FIRST
         }
         @ObjectModel.text.element: ['MaterialName']
         Defect.Material,
         @Semantics.text: true
         @UI.hidden: true
         _MaterialText.MaterialName,
         @UI.hidden: true
         Defect.Plant,
         @EndUserText.label: 'Defective Serial Number'
         Defect.DefectiveSingleUnit,
         @UI: {
          textArrangement: #TEXT_FIRST
         }
         @ObjectModel.text.element: ['ProducedMaterialName']
         @EndUserText.label: 'Produced Material'
         Defect.ProducedMaterial,
         @Semantics.text: true
         @UI.hidden: true
         _ProducedMatText.MaterialName                                                         as ProducedMaterialName,
         @EndUserText.label: 'Produced Serial Number'
         Defect.ProducedSerialNumber,
         @ObjectModel.text.element: 'DefectLifecycleStatusText'
         @UI: {
           textArrangement: #TEXT_ONLY
         }
         Defect.DefectLifecycleStatus,
         @Semantics.text: true
         @UI.hidden: true
         Defect._DefectStatus._DefectStatusText[1: Language=$session.system_language].DefectLifecycleStatusText,
         @ObjectModel.text.element: 'NotifProcessingPhaseDesc'
         @UI: {
           textArrangement: #TEXT_ONLY
         }
         Defect.NotifProcessingPhase,
         @Semantics.text: true
         @UI.hidden: true
         Defect._NotifProcessingPhase._Text[1: Language=$session.system_language].NotifProcessingPhaseDesc,
         @UI.hidden: true
         Defect.BOMItemInstanceUUID,
         Defect.CreatedByUser,
//         @Consumption.hidden: true

         Defect.CreationDate,
         Defect.LastChangedByUser,
         Defect.LastChangeDate,
//         @Consumption.hidden: true

         Defect.CreationTime,
//         cast(dats_tims_to_tstmp( Defect.CreationDate,Defect.CreationTime, abap_system_timezone($session.client, 'NULL'),$session.client, 'NULL') as timestamp) as CreationDateTime,

         Defect.LastChangeTime,
         @UI.hidden: true
         Defect.ChangedDateTime,
         /* For DCL */
         @UI.hidden: true
         Defect.InspectionLot,
         @UI.hidden: true
         Defect.MainWorkCenter,
         @UI.hidden: true
         Defect.MainWorkCenterPlant,
         Defect.BatchBySupplier,
         Defect.ManufacturerSerialNumber,
         @ObjectModel.virtualElement: true
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_NONCF_COMP_SADL_EXIT'
         cast('' as mpe_mrs_designator_name)                                                   as MfgRefStrucItmRefDsgntrName,

         /* Associations */
         _DefectCodeText,
         _OperationActivityText,
         _Sitn,
         _MaterialText,
         _ProducedMatText,
         Defect._Notification,
         Defect._InspectionLot, //For DCL

         Defect._DefectStatus,
         Defect._CreatedByUserContactCard,
         Defect._DefectCode,
         Defect._DefectCodeCatalog,
         Defect._DefectCodeGroup,
         Defect._LastChangedByUserContactCard,
         Defect._NotifProcessingPhase,
         Defect._DefectCategory,
         Defect._DefectDecisionVH

}