@AbapCatalog.sqlViewName: 'CSETTLMTACTVAPSM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Settled values with public sector fields'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
define view C_SettlmtActlSetldValPubSec
as select from P_SettlementActualSettledValue
{
key ControllingObject,
@UI.lineItem.position: 10
key Ledger,
@ObjectModel.text.element: ['SettlementSenderText']
@UI.textArrangement: #TEXT_LAST
@UI.lineItem.position: 20
key SettlementSenderObject,
@ObjectModel.text.element: ['SettlementReceiverText']
@UI.textArrangement: #TEXT_LAST
@UI.lineItem.position: 40
key SettlementReceiverObject,
@ObjectModel.text.element: ['SettlementTypeDesc']
@UI.textArrangement: #TEXT_ONLY
@UI.lineItem.position: 60
key SettlementType,
@UI.lineItem : [{ position: 121 }]
key PartnerFunctionalArea,
@UI.lineItem : [{ position: 122 }]
key PartnerFund,
@UI.lineItem : [{ position: 123 }]
key PartnerBudgetPeriod,
@UI.lineItem : [{ position: 124 }]
key PartnerGrant,
@UI.lineItem : [{ position: 125 }]
key FunctionalArea,
@UI.lineItem : [{ position: 126 }]
key Fund,
@UI.lineItem : [{ position: 127 }]
key BudgetPeriod,
@UI.lineItem : [{ position: 128 }]
key GrantID,
@UI.hidden: true
@Semantics.currencyCode:true
key CompanyCodeCurrency,
@UI.hidden: true
@Semantics.currencyCode:true
key GlobalCurrency,
// @UI.hidden: true
// @Semantics.currencyCode:true
// ControllingObjectCurrency,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency1,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency2,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency3,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency4,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency5,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency6,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency7,
@UI.hidden: true
@Semantics.currencyCode:true
key FreeDefinedCurrency8,
@UI.hidden: true
@Semantics.currencyCode:true
key FunctionalCurrency,
@UI.hidden: true
WBSElementInternalID,
@UI.hidden: true
ProjectInternalID,
SettlementSenderText,
@ObjectModel: {
readOnly: true,
virtualElement,
virtualElementCalculatedBy: 'ABAP:CL_FCO_SETTL_VALUES_CDS_EXIT'
}
cast( '' as fco_stlmnt_receiver_txt ) as SettlementReceiverText,
// needed for virtual element
@UI.hidden: true
OriginObjectType,
@UI.hidden: true
cast (OriginCtrlgDebitCreditCode as beknz_mask) as OriginCtrlgDebitCreditCode,
@UI.hidden: true
AccountAssignmentType,
@UI.hidden: true
PartnerAccountAssignmentType,
@UI.hidden: true
FixedAsset,
@UI.hidden: true
MasterFixedAsset,
@UI.hidden: true
CompanyCode,
@UI.hidden: true
GLAccount,
@UI.hidden: true
SalesDocument,
@UI.hidden: true
SalesDocumentItem,
@UI.hidden: true
CostCenter,
@UI.hidden: true
OrderID,
@UI.hidden: true
ProjectNetwork,
@UI.hidden: true
BusinessProcess,
@UI.hidden: true
Product,
@UI.hidden: true
SettlementSenderType,
@UI.lineItem.position: 30
SettlementSenderTypeText,
@UI.hidden: true
SettlementReceiverType,
@UI.lineItem.position: 50
cast( _SettlementReceiverTypeT.AccountAssignmentTypeName as fco_settlmt_rec_type_text ) as SettlementReceiverTypeText,
@UI.hidden: true
_SettlementTypeText.SettlementTypeDesc,
@UI.hidden: true
ControllingArea,
@UI.lineItem.position: 100
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
cast ( sum( AmountInCompanyCodeCurrency ) as alloc_run_fins_vhcur12 preserving type ) as AmountInCompanyCodeCurrency,
@UI.lineItem.position: 110
@Semantics.amount.currencyCode: 'GlobalCurrency'
cast ( sum( AmountInGlobalCurrency ) as alloc_run_fins_vkcur12 preserving type ) as AmountInGlobalCurrency,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
cast ( sum( AmountInFreeDefinedCurrency1 ) as fis_osl preserving type ) as AmountInFreeDefinedCurrency1,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
cast ( sum( AmountInFreeDefinedCurrency2 ) as fis_vsl preserving type ) as AmountInFreeDefinedCurrency2,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
cast ( sum( AmountInFreeDefinedCurrency3 ) as fis_bsl preserving type ) as AmountInFreeDefinedCurrency3,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
cast ( sum( AmountInFreeDefinedCurrency4 ) as fis_csl preserving type ) as AmountInFreeDefinedCurrency4,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
cast ( sum( AmountInFreeDefinedCurrency5 ) as fis_dsl preserving type ) as AmountInFreeDefinedCurrency5,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
cast ( sum( AmountInFreeDefinedCurrency6 ) as fis_esl preserving type ) as AmountInFreeDefinedCurrency6,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
cast ( sum( AmountInFreeDefinedCurrency7 ) as fis_fsl preserving type ) as AmountInFreeDefinedCurrency7,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
cast ( sum( AmountInFreeDefinedCurrency8 ) as fis_gsl preserving type ) as AmountInFreeDefinedCurrency8,
@Semantics.amount.currencyCode: 'FunctionalCurrency'
cast ( sum( AmountInFunctionalCurrency ) as fis_vfccur12 preserving type ) as AmountInFunctionalCurrency
}
group by
ControllingObject,
WBSElementInternalID,
ProjectInternalID,
Ledger,
SettlementSenderObject,
SettlementSenderText,
SettlementReceiverObject,
SettlementReceiverText,
SettlementSenderType,
SettlementSenderTypeText,
SettlementReceiverType,
_SettlementReceiverTypeT.AccountAssignmentTypeName,
SettlementType,
_SettlementTypeText.SettlementTypeDesc,
ControllingArea,
FunctionalArea,
Fund,
BudgetPeriod,
GrantID,
PartnerFunctionalArea,
PartnerFund,
PartnerBudgetPeriod,
PartnerGrant,
CompanyCodeCurrency,
GlobalCurrency,
ControllingObjectCurrency,
FreeDefinedCurrency1,
FreeDefinedCurrency2,
FreeDefinedCurrency3,
FreeDefinedCurrency4,
FreeDefinedCurrency5,
FreeDefinedCurrency6,
FreeDefinedCurrency7,
FreeDefinedCurrency8,
FunctionalCurrency,
OriginObjectType,
OriginCtrlgDebitCreditCode,
AccountAssignmentType,
PartnerAccountAssignmentType,
FixedAsset,
MasterFixedAsset,
CompanyCode,
GLAccount,
SalesDocument,
SalesDocumentItem,
CostCenter,
OrderID,
ProjectNetwork,
BusinessProcess,
Product