C_SalesContrForCreateWithRefVH

DDL: C_SALESCONTRFORCREATEWITHREFVH Type: view_entity CONSUMPTION

Sales Contract for Create Wth Reference

C_SalesContrForCreateWithRefVH is a Consumption CDS View that provides data about "Sales Contract for Create Wth Reference" in SAP S/4HANA. It reads from 1 data source (I_SalesContract) and exposes 14 fields with key field SalesContract. It has 2 associations to related views.

1 data source(s) 14 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesContract SalesContract from

Associations (2)

CardinalityTargetAliasCondition
[0..*] I_OverallSDProcessStatusText _OverallSDProcessStatusText $projection.OverallSDProcessStatus = _OverallSDProcessStatusText.OverallSDProcessStatus
[0..*] I_OverallSDDocReferenceStatusT _OverallSDDocReferenceStatusT $projection.OverallSDDocReferenceStatus = _OverallSDDocReferenceStatusT.OverallSDDocReferenceStatus

Annotations (10)

NameValueLevelField
VDM.viewType #CONSUMPTION view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
Search.searchable true view
Consumption.ranked true view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Sales Contract for Create Wth Reference view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY SalesContract I_SalesContract SalesContract
SoldToParty I_SalesContract SoldToParty
SoldToPartyName Sold-to Party Name
PurchaseOrderByCustomer I_SalesContract PurchaseOrderByCustomer
SalesContractValidityStartDate I_SalesContract SalesContractValidityStartDate
SalesContractValidityEndDate I_SalesContract SalesContractValidityEndDate
OverallSDProcessStatus I_SalesContract OverallSDProcessStatus
OverallSDDocReferenceStatus I_SalesContract OverallSDDocReferenceStatus
SalesContractType I_SalesContract SalesContractType
SalesOrganization I_SalesContract SalesOrganization
DistributionChannel I_SalesContract DistributionChannel
OrganizationDivision I_SalesContract OrganizationDivision
_OverallSDProcessStatusText _OverallSDProcessStatusText
_OverallSDDocReferenceStatusT _OverallSDDocReferenceStatusT 
@VDM: {
  viewType: #CONSUMPTION
}

@ObjectModel: {
  dataCategory:#VALUE_HELP,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #M
  }
}

@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK

@UI.presentationVariant: [{
  sortOrder: [{ 
    by: 'SalesContract',
    direction: #DESC 
  }]
}]

@EndUserText.label: 'Sales Contract for Create Wth Reference'
define view entity C_SalesContrForCreateWithRefVH  
  as select from I_SalesContract as SalesContract
  
  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus      = _OverallSDProcessStatusText.OverallSDProcessStatus
  association [0..*] to I_OverallSDDocReferenceStatusT as _OverallSDDocReferenceStatusT on $projection.OverallSDDocReferenceStatus = _OverallSDDocReferenceStatusT.OverallSDDocReferenceStatus
  
{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH 
      }
  key SalesContract.SalesContract,
  
      @UI: {
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_SoldToValueHelp',
          element: 'Customer'
        }
      }]
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesContract.SoldToParty,

      @Semantics.text: true
      @EndUserText.label : 'Sold-to Party Name'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSCONTR_UI_PARTNER_UTIL'
      cast('' as ad_namtext )                                                        as SoldToPartyName,
             
      @UI: {
        selectionField: [{ position: 30 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM 
      }
      SalesContract.PurchaseOrderByCustomer,
      
      @UI: {
        selectionField: [{ position: 40 }]
      }
      SalesContract.SalesContractValidityStartDate,
      
      @UI: {
        selectionField: [{ position: 50 }]
      }
      SalesContract.SalesContractValidityEndDate,
      
      @UI: {
        selectionField: [{ position: 60 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.association: '_OverallSDProcessStatusText'
      SalesContract.OverallSDProcessStatus,
      
      @UI: {
        selectionField: [{ position: 70 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDDocReferenceStatus',
          element: 'OverallSDDocReferenceStatus'
        }
      }]
      @ObjectModel.text.association: '_OverallSDDocReferenceStatusT'
      SalesContract.OverallSDDocReferenceStatus,
    
      //Properties for DCL

      @UI.hidden: true
      SalesContract.SalesContractType,
      @UI.hidden: true
      SalesContract.SalesOrganization,
      @UI.hidden: true
      SalesContract.DistributionChannel,
      @UI.hidden: true
      SalesContract.OrganizationDivision,
      
      //Associations

      @Consumption.filter.hidden: true
      _OverallSDProcessStatusText,
      @Consumption.filter.hidden: true
      _OverallSDDocReferenceStatusT
} 
 where 
   SalesDocApprovalStatus        <> 'A' and  // In Approval

   SalesDocApprovalStatus        <> 'C' and  // Rejected

   SalesDocApprovalStatus        <> 'D'      // To Be Reworked

Learn More