C_ReturnsReferenceSalesOrderVH

DDL: C_RETURNSREFERENCESALESORDERVH Type: view_entity CONSUMPTION

Return Reference Sales Order

C_ReturnsReferenceSalesOrderVH is a Consumption CDS View that provides data about "Return Reference Sales Order" in SAP S/4HANA. It reads from 1 data source (I_SalesOrder) and exposes 11 fields with key field SalesOrder. It has 1 association to related views. It is exposed through 1 OData service (UI_CUSTOMERRETURNMANAGE).

1 data source(s) Exposed by 1 service(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesOrder SalesOrder from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_OverallSDProcessStatusText _OverallSDProcessStatusText $projection.OverallSDProcessStatus = _OverallSDProcessStatusText.OverallSDProcessStatus

Annotations (11)

NameValueLevelField
VDM.viewType #CONSUMPTION view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey SalesOrder view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #L view
Search.searchable true view
Consumption.ranked true view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Return Reference Sales Order view

OData Services (1)

ServiceBindingVersionContractRelease
UI_CUSTOMERRETURNMANAGE UI_CUSTOMERRETURNMANAGE V4 C1 NOT_RELEASED

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder I_SalesOrder SalesOrder
SoldToParty I_SalesOrder SoldToParty
SoldToPartyName
PurchaseOrderByCustomer I_SalesOrder PurchaseOrderByCustomer
SalesOrderDate I_SalesOrder SalesOrderDate
OverallSDProcessStatus I_SalesOrder OverallSDProcessStatus
OverallSDProcessStatusDesc
SalesOrderType I_SalesOrder SalesOrderType
SalesOrganization I_SalesOrder SalesOrganization
DistributionChannel I_SalesOrder DistributionChannel
OrganizationDivision I_SalesOrder OrganizationDivision 
@VDM.viewType: #CONSUMPTION

@ObjectModel: {
  dataCategory:#VALUE_HELP,
  representativeKey: 'SalesOrder',
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #L
  }
}

@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #MANDATORY

@UI.presentationVariant: [{
  sortOrder: [{
    by: 'SalesOrder',
    direction: #DESC
  }]
}]
@EndUserText.label: 'Return Reference Sales Order'
define view entity C_ReturnsReferenceSalesOrderVH

  as select from I_SalesOrder as SalesOrder

  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus      = _OverallSDProcessStatusText.OverallSDProcessStatus

{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
  key SalesOrder.SalesOrder,

      @UI: {
        lineItem: [{ position: 20,  importance: #HIGH }],
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST
      }

      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'D_SlsDocSoldToPartyCVH',
        element: 'Customer' } }]
      }
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesOrder.SoldToParty,

      @Semantics.text: true
      @UI.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSORD_UI_PARTNER_UTIL'
      cast('' as ad_namtext )                                                        as SoldToPartyName,

      @UI: {
        selectionField: [{ position: 30 }],
        lineItem: [{ position: 30,  importance: #HIGH }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM
      }
      SalesOrder.PurchaseOrderByCustomer,

      @UI: {
        lineItem: [{ position: 40,  importance: #HIGH }],
        selectionField: [{ position: 40 }]
      }
      @Consumption.filter: {
        selectionType: #INTERVAL
      }
      SalesOrder.SalesOrderDate,

      @UI: {
        lineItem: [{ position: 50,  importance: #HIGH }],
        selectionField: [{ position: 50 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.element: ['OverallSDProcessStatusDesc']
      SalesOrder.OverallSDProcessStatus,

      @UI.hidden: true
      @Semantics.text: true
      _OverallSDProcessStatusText[1: Language=$session.system_language].OverallSDProcessStatusDesc,

      //Properties for DCL

      @UI.hidden: true
      SalesOrder.SalesOrderType,
      @UI.hidden: true
      SalesOrder.SalesOrganization,
      @UI.hidden: true
      SalesOrder.DistributionChannel,
      @UI.hidden: true
      SalesOrder.OrganizationDivision
}
 where
     SalesDocApprovalStatus        <> 'A' and  // In Approval

     SalesDocApprovalStatus        <> 'C' and  // Rejected

     SalesDocApprovalStatus        <> 'D'      // To Be Reworked

Learn More