C_ReqnToOrderCycleTime

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@AbapCatalog.sqlViewName: 'CMMREQORDCYCL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Requisition To Order Cycle Time'
@VDM.viewType: #CONSUMPTION
@OData.publish: true

define view C_ReqnToOrderCycleTime

  with parameters
    @Consumption.defaultValue: 'EUR'
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'I_Currency',
        element:'Currency'
      }
    }]
    P_DisplayCurrency        : displaycurrency,
    @Consumption.defaultValue: 'PREVIOUSYEARTODATE'
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'C_GregorianCalDateFuncVH',
        element:'DateFunction'
      }
    }]
    P_DateFunction           : datefunctionid,

    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction',
    resultElement: 'DateFunctionStartDate', binding: [ {
      targetParameter: 'P_DateFunction', type: #PARAMETER, value : 'P_DateFunction' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ]
    }
    @Consumption.hidden: true
    P_StartDate              : badat,

    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction',
    resultElement: 'DateFunctionEndDate', binding: [ {
      targetParameter: 'P_DateFunction', type: #PARAMETER, value : 'P_DateFunction' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ]
    }
    @Consumption.hidden: true
    P_EndDate                : badat,

    P_PriceForLowCostItem    : mm_a_low_cost_value,

    P_PriceForMediumCostItem : mm_a_medium_cost_value,

    P_PriceForHighCostItem   : mm_a_high_cost_value

  as select from    P_ReqnToOrderCycleTime2( P_DisplayCurrency: $parameters.P_DisplayCurrency,
                                             P_StartDate : $parameters.P_StartDate,
                                             P_EndDate : $parameters.P_EndDate) as RequisitionItem

    left outer join I_PurchasingCategoryMatlGroup                               as PurchasingCategoryMatlGroup on RequisitionItem.MaterialGroup = PurchasingCategoryMatlGroup.MaterialGroup

//    left outer join I_CalendarYear on I_CalendarYear.NumberOfDays =1  //3053587

    left outer to one join I_CalendarDate                                              as CalendarDate      on RequisitionItem.PurReqCreationDate = CalendarDate.CalendarDate

  association [1..1] to I_Purreqvaluationarea    as _PurReqValuationArea    on $projection.Plant = _PurReqValuationArea.ValuationArea

  association [1..1] to I_Material               as _Material               on $projection.Material = _Material.Material

  association [1..1] to I_MaterialGroup          as _MaterialGroup          on $projection.MaterialGroup = _MaterialGroup.MaterialGroup

  association [1..1] to I_Supplier               as _Supplier               on $projection.Supplier = _Supplier.Supplier

  association [1..1] to I_Country                as _Country                on $projection.SupplierCountry = _Country.Country

  association [1..1] to I_Plant                  as _Plant                  on $projection.Plant = _Plant.Plant

  association [1..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [1..1] to I_PurchasingGroup        as _PurchasingGroup        on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

{
      @EndUserText.label: 'Purchase Requisition'
  key PurchaseRequisition,

      @EndUserText.label: 'Purchase Requisition Item'
  key PurchaseRequisitionItem,
      
      @EndUserText.label: 'Purchase Order'
  key PurchaseOrder,

 // key PurchaseOrderItem,


      /* Org Data */
      @ObjectModel.text.element: ['PurchasingGroupName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'PurchasingGroupName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_PurchasingGroupValueHelp', element : 'PurchasingGroup' } }]
      PurchasingGroup,
      @Semantics.text: true
      _PurchasingGroup.PurchasingGroupName,

      @ObjectModel.text.element: ['PurchasingOrganizationName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'PurchasingOrganizationName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_PurchasingOrgValueHelp', element : 'PurchasingOrganization' } }]
      PurchasingOrganization,
      @Semantics.text: true
      _PurchasingOrganization.PurchasingOrganizationName,

      @ObjectModel.text.element: ['PurgCatName']
      @Consumption.labelElement: 'PurgCatName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'I_PurchasingCategoryValueHelp', element : 'PurchasingCategory' } }]
      cast(coalesce(PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory,'') as /srmsmc/purchasing_category_id) as PurchasingCategory,
      @Semantics.text: true
      PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName                                                             as PurgCatName,

      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_CompanyCodeValueHelp', element : 'CompanyCode' } }]
      _PurReqValuationArea.CompanyCode,

      /* Supplier */
      @ObjectModel.text.element: ['SupplierName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'SupplierName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_SmplSupplierValueHelp', element : 'Supplier' } }]
      Supplier,
      @Semantics.text: true
      _Supplier.SupplierName,

      @ObjectModel.text.element: ['CountryName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'CountryName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_CountryValueHelp', element : 'SupplierCountry' } }]
      SupplierCountry,
      @Semantics.text: true
      _Country._Text[1: Language = $session.system_language].CountryName,

      /* Item Data */
      @ObjectModel.text.element: ['MaterialName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'MaterialName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_MaterialValueHelp', element : 'Material' } }]
      Material,
      @Semantics.text: true
      _Material._Text[1: Language = $session.system_language].MaterialName,

      @ObjectModel.text.element: ['MaterialGroupName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'MaterialGroupName'
      RequisitionItem.MaterialGroup,
      @Semantics.text: true
      _MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName,

      @ObjectModel.text.element: ['PlantName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'PlantName'
      Plant,
      @Semantics.text: true
      _Plant.PlantName,

      //   cast(PurchaseRequisitionPrice as mm_a_purchase_reqn_price) as PurchaseRequisitionPrice,


      /*Dates*/

//      RequisitionItem.CalendarYear,                         //^3053587 

//      RequisitionItem.CalendarQuarter,

//      RequisitionItem.CalendarMonth,

//      RequisitionItem.CalendarWeek,                         //v3053587


 //     CostCenter,


      CreatedByUser,
      
      CalendarDate.CalendarWeek,
      CalendarDate.CalendarMonth,
      CalendarDate.CalendarQuarter,
      CalendarDate.CalendarYear,

      @DefaultAggregation: #AVG
      cast(CycleTime as mm_a_order_cycle_time)                                                                                as PurReqnAverageCycleTime,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice  <=  $parameters.P_PriceForLowCostItem
                      then CycleTime
//                      else I_CalendarYear.NumberOfDays      //3053587

               end as mm_a_approvaldays_lowcostitems )                                                                        as ApprovalDaysForLowCostItems,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice >$parameters.P_PriceForLowCostItem  and PurchaseRequisitionPrice <= $parameters.P_PriceForMediumCostItem
                       then CycleTime
//                       else I_CalendarYear.NumberOfDays     //3053587

                end as mm_a_apprvldays_mediumcostitem )                                                                       as ApprovalDaysForMediumCostItems,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice > $parameters.P_PriceForMediumCostItem and PurchaseRequisitionPrice <= $parameters.P_PriceForHighCostItem
                      then CycleTime
//                      else I_CalendarYear.NumberOfDays      //3053587

               end as mm_a_apprvldays_highcostitem )                                                                          as ApprovalDaysForHighCostItems,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice > $parameters.P_PriceForHighCostItem
                      then CycleTime
//                      else I_CalendarYear.NumberOfDays      //3053587

               end as mm_a_apprvldaysforvhcostitem )                                                                          as ApprvlDaysForVeryHighCostItems

}