C_ReconAccountVHTemp

@AbapCatalog.sqlViewName: 'CRECONACCTVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.representativeKey: 'ReconciliationAccount'
@Search.searchable: true
@EndUserText.label: 'Reconciliation Account'

//THIS IS FOR SUPPLIERS ONLY

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER


define view C_ReconAccountVHTemp
as  

select
from I_GLAccountInChartOfAccounts -- G/L Account Master Record (Chart of Accounts)
join I_GLAccountInCompanyCode-- G/L Account Master Record (Company Code)
  on I_GLAccountInCompanyCode.GLAccount = I_GLAccountInChartOfAccounts.GLAccount
join I_CompanyCode -- Company Code
  on I_GLAccountInCompanyCode.CompanyCode = I_CompanyCode.CompanyCode and I_GLAccountInChartOfAccounts.ChartOfAccounts = I_CompanyCode.ChartOfAccounts -- Chart of Accounts

association [0..*] to C_ReconAccountTextVHTemp as _Text on I_GLAccountInChartOfAccounts.GLAccount = _Text.GLAccount
                                                             and I_GLAccountInChartOfAccounts.ChartOfAccounts = _Text.ChartOfAccounts
                                                             
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode

{
  @ObjectModel.text.association: '_Text'
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.75
  @Search.ranking: #HIGH
  key I_GLAccountInChartOfAccounts.GLAccount as ReconciliationAccount, -- Reconcialition Account key
      //--[ GENERATED:012:GlBfhyJl7kY4i6}7dD1KRG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.75
  @Search.ranking: #HIGH
  @ObjectModel.foreignKey.association: '_CompanyCode'
  key I_GLAccountInCompanyCode.CompanyCode as CompanyCode, -- Company Code
  @UI.hidden: true
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.75
  @Search.ranking: #HIGH
  I_GLAccountInChartOfAccounts.ChartOfAccounts as ChartOfAccounts, -- Chart of Accounts
  _Text,
  _CompanyCode

}
where I_GLAccountInCompanyCode.ReconciliationAccountType = 'K' -- Reconciliation indicator = 'K' (Suppliers)