C_ReExAssignWBS

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CREEXASSIGNWBS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking: #REQUIRED }
@EndUserText.label: 'WBS Element'
@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MIXED
@Search.searchable: true
define view C_ReExAssignWBS as select from I_WBSElement


{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key I_WBSElement.WBSElement                                                     as WBSElement,
      I_WBSElement.WBSElementInternalID                                           as WBSElementInternalID,
      I_WBSElement.ProjectInternalID                                              as ProjectInternalID,
      I_WBSElement.Project                                                        as Project,
      @Semantics.text: true
      I_WBSElement.WBSDescription                                                 as WBSDescription,
      I_WBSElement.WBSElementObject                                               as WBSElementObject,
//      I_WBSElement.ResponsiblePerson                                              as ResponsiblePerson,

//      I_WBSElement.ResponsiblePersonName                                          as ResponsiblePersonName,

      cast(  case
               when ResponsiblePerson = '00000000' or ResponsiblePerson is null
                  then _EntProjectResponsiblePerson.PersonWorkAgreement
                else
                  ResponsiblePerson
              end as ps_s4_vernr preserving type ) as ResponsiblePerson,
            
      cast(  case
               when ResponsiblePerson = '00000000' or ResponsiblePerson is null
                  then _EntProjectResponsiblePerson._WorkforcePerson.PersonFullName
                else
                  ResponsiblePersonName
              end as ad_namtext preserving type ) as ResponsiblePersonName,
      I_WBSElement.CompanyCode                                                    as CompanyCode,
      I_WBSElement.BusinessArea                                                   as BusinessArea,
      I_WBSElement.ControllingArea                                                as ControllingArea,
      I_WBSElement.ProfitCenter                                                   as ProfitCenter,
      I_WBSElement.ProjectType                                                    as ProjectType,
      I_WBSElement.RequestingCostCenter                                           as RequestingCostCenter,
      I_WBSElement.ResponsibleCostCenter                                          as ResponsibleCostCenter,
      I_WBSElement.Currency                                                       as Currency,
      I_WBSElement.Plant                                                          as Plant,
      I_WBSElement.FunctionalArea                                                 as FunctionalArea,
      I_WBSElement.Location                                                       as Location,
      I_WBSElement.Equipment                                                      as Equipment,
      I_WBSElement.FunctionalLocation                                             as FunctionalLocation,
      I_WBSElement.BasicStartDate                                                 as BasicStartDate,
      I_WBSElement.ForecastedStartDate                                            as ForecastedStartDate,
      I_WBSElement.ActualStartDate                                                as ActualStartDate,
      I_WBSElement.BasicEndDate                                                   as BasicEndDate,
      I_WBSElement.ForecastedEndDate                                              as ForecastedEndDate,
      I_WBSElement.ActualEndDate                                                  as ActualEndDate,

      @Semantics.unitOfMeasure: true
      cast ( I_WBSElement.ActualDurationUnit as ps_ieinh preserving type )               as ActualDurationUnit,
      @Semantics.unitOfMeasure: true
      cast ( I_WBSElement.ForecastedDurationUnit as ps_s4_eeinh preserving type )        as ForecastedDurationUnit,
      @Semantics.unitOfMeasure: true
      cast ( I_WBSElement.BasicDurationUnit as ps_s4_peinh preserving type )             as BasicDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'BasicDurationUnit'
      cast ( I_WBSElement.BasicDuration as ps_s4_pdaur preserving type )                 as BasicDuration,
      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'ForecastedDurationUnit'
      cast( I_WBSElement.ForecastedDuration as ps_s4_edaur preserving type )             as ForecastedDuration,
      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'ActualDurationUnit'
      cast ( I_WBSElement.ActualDuration as ps_s4_idaur preserving type )                as ActualDuration,

      I_WBSElement.WBSElementShortID                                                     as WBSElementShortID,
      I_WBSElement.ReqgCostCenterControllingArea                                         as ReqgCostCenterControllingArea,
      I_WBSElement.RespCostCenterControllingArea                                         as RespCostCenterControllingArea,
      I_WBSElement.Language                                                              as Language,
      cast ( I_WBSElement.CostCenter as ps_kostl preserving type )                       as CostCenter,
      I_WBSElement.CostObject                                                            as CostObject,
      @UI.hidden: true
      @Consumption.filter.hidden: true      
      _ResponsiblePerson.ResponsiblePersonIsBlocked,
//      _ResponsiblePerson,

      @UI.hidden: true
      @Consumption.filter.hidden: true  
      _EntProjectResponsiblePerson


}