C_RFM_SlsOrdPrgrsMntrSupGnrc

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'CRFMSOPMSUPGN',
  preserveKey:true,
  compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #X,
     sizeCategory:   #L
   }
}
@Metadata.allowExtensions: true
@EndUserText.label: 'Supply Details at Generic Article Item'
define view C_RFM_SlsOrdPrgrsMntrSupGnrc
  as select from I_RFM_SlsOrdPrgrsMntrSupGnrc
  association [1..*] to C_RFM_SlsOrdPrgrsMntrSupItm   as _SupItem           on  $projection.SalesOrder             = _SupItem.SalesOrder
                                                                            and $projection.SalesOrderItem         = _SupItem.HigherLevelItem
                                                                            and $projection.RFMSupplyNumber        = _SupItem.RFMMasterSupplyNumber
                                                                            and $projection.SlsOrdPrgrsMntrSupType = _SupItem.RFMMasterSupplyType
  association [1..1] to I_RFM_SlsOrdPrgrsMntrSupTypeT as _SupType           on  $projection.SlsOrdPrgrsMntrSupType = _SupType.SlsOrdPrgrsMntrSupType
                                                                            and _SupType.Language                  = $session.system_language
  association [1..1] to I_RFM_SlsOrdPrgrsMntrSupCatT  as _SupCat            on  $projection.SlsOrdPrgrsMntrSupCat = _SupCat.SlsOrdPrgrsMntrSupCat
                                                                            and _SupCat.Language                  = $session.system_language
  association [0..1] to I_ProductText                 as _ProductText       on  $projection.Material  = _ProductText.Product
                                                                            and _ProductText.Language = $session.system_language
  association [0..1] to I_RFM_SlsOrdPrgrsMntrConfign  as _UserSpecficConfig on  _UserSpecficConfig.CreatedByUser = $session.user
  association [0..1] to I_RFM_SlsOrdPrgrsMntrConfign  as _GlobalConfig      on  _GlobalConfig.CreatedByUser = ''
{

  key    SalesOrder,
  key    SalesOrderItem,
  key    RFMSupplyNumber,
         @ObjectModel.text.association: '_SupType'
         SlsOrdPrgrsMntrSupType,
         @ObjectModel.text.association: '_SupCat'
         SlsOrdPrgrsMntrSupCat,
         RFMSupplyCategoryCriticality,
         @ObjectModel.text.association: '_ProductText'
         Material,
         _ProductText.ProductName,
         TotalSupplyQuantity,
         ProcessedSupplyQuantity,
         BaseUnit,
         ExpectedSupplyDeliveryDate,
         case
           when SupplyDeliveryDate is not initial
           then SupplyDeliveryDate
           else ExpectedSupplyDeliveryDate
         end              as ActualSupplyDeliveryDate,
         case
           when SupplyDeliveryDate is not initial
           then cast(Dats_Days_Between( ExpectedSupplyDeliveryDate, SupplyDeliveryDate ) as due_days)
           else cast(Dats_Days_Between( ExpectedSupplyDeliveryDate, cast($session.system_date as dats) ) as due_days)
         end              as DeliveryDateOffsetInDays,
         case
           when ExpectedSupplyDeliveryDate <= $session.system_date
           then 'X'
           else ''
         end              as DeliveryIsOverdue,
         case
           when _UserSpecficConfig.SupDelivDteOffsetKPI != 0
           then _UserSpecficConfig.SupDelivDteOffsetKPI
           when _GlobalConfig.SupDelivDteOffsetKPI != 0
           then _GlobalConfig.SupDelivDteOffsetKPI
           else cast( '7' as rfm_msop_offset_days)
         end              as SupDelivDteOffsetKPI,
         case SlsOrdPrgrsMntrSupType
           when '01'
           then cast( LTRIM(RFMSupplyNumber,'0') as banfn )
         else ''      end as PurchaseRequisition,
         case SlsOrdPrgrsMntrSupType
           when '02'
           then cast( LTRIM(RFMSupplyNumber,'0') as vdm_purchaseorder )
         else '' end      as PurchaseOrder,
         case SlsOrdPrgrsMntrSupType
           when '03'
           then cast( LTRIM(RFMSupplyNumber,'0') as plnum )
         else '' end      as PlannedOrder,
         case SlsOrdPrgrsMntrSupType
           when '04'
           then RFMSupplyNumber
         else '' end      as MasterPlannedOrder,
         case SlsOrdPrgrsMntrSupType
           when '05'
           then RFMSupplyNumber
         else '' end      as ProductionOrder,
         case SlsOrdPrgrsMntrSupType
           when '06'
           then RFMSupplyNumber
         else '' end      as MasterProductionOrder,
         _SupCat,
         _SupType,
         _SupItem,
         _ProductText
}