C_RAContractPriceAllocationTP

@EndUserText.label: 'Price Allocation RA Contract'
@AccessControl.authorizationCheck: #CHECK

@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard']

@Metadata.allowExtensions: true

@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel.usageType: {sizeCategory: #XXL, serviceQuality: #C, dataClass: #TRANSACTIONAL}
@ObjectModel.semanticKey: ['RevenueAccountingContract']

@Search.searchable: true

define root view entity C_RAContractPriceAllocationTP
  provider contract transactional_query
  as projection on R_RevenueAccountingContractTP
{
      @Consumption.semanticObject: 'RevenueAccountingContract'
  key RevenueAccountingContract,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      @ObjectModel.text.element: ['CompanyCodeName']
      CompanyCode,
      _CompanyCode.CompanyCodeName,


      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_AccountingPrinciple',
                     element: 'AccountingPrinciple' }
        }]
      @ObjectModel.text.element: ['AccountingPrincipleName']
      AccountingPrinciple,
      _AccountingPrinciple._Text.AccountingPrincipleName                               : localized,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BusinessPartnerVH',
                     element: 'BusinessPartner' }
        }]
      @Consumption.semanticObject: 'BusinessPartner'
      @ObjectModel.text.element: ['BusinessPartnerName']
      BusinessPartner,
      _BusinessPartner.BusinessPartnerName,

      @ObjectModel.text.element: ['CustomerName']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Consumption.semanticObject: 'Customer'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'D_CustomerCVH',
                     element: 'Customer' }
        }]
      Customer,
      _Customer.CustomerName                            as CustomerName,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'C_SalesOrganizationVH',
          element: 'SalesOrganization' }
      }]
      @ObjectModel.text.element: ['SalesOrganizationName']
      RevnAcctgSalesOrganization,
      _SalesOrganization._Text.SalesOrganizationName                                   : localized,

      @Consumption.filter.hidden: true
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      TotContractualPrcInSlsDocCrcy,

      @Consumption.filter.hidden: true
      SalesDocumentCurrency,

      @Consumption.filter.hidden: true
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      AllocEffctAmountInSalesDocCrcy,

      @Consumption.filter.hidden: true
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      ContrToBeAllcdAmtInSlsDocCrcy,

      @Consumption.filter.hidden: true
      NumberOfPerformanceObligations,

      RAContractIsManuallyAllocated,

      RAContractHasAllocationEffect,

      @ObjectModel.text.element: ['RevnAcctgContractStatusName']
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_RAContractStatusVH',
                         element: 'RevnAcctgContractStatus' }
            }]
      RevnAcctgContractStatus,

      @Consumption.filter.hidden: true
      _RAContractStatusText.RevnAcctgContractStatusName as RevnAcctgContractStatusName : localized,

      RAContractStatusCriticality,

      RAContractLastSavedDateTime,

      @Consumption.filter.hidden: true
      RevnAcctgContractCreationDate,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_RAContractCreatedByUserVH',
                     element: 'RevnAcctgContractCreatedByUser' }
        }]
      RevnAcctgContractCreatedByUser,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      CreatedByUserDescription,

      IsBusinessPurposeCompleted,

      @Consumption.filter.hidden: true
      RAContractCompletionDate,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_RAContractChangedByUserVH',
                     element: 'RAContractLastChangedByUsr' }
        }]
      RAContractLastChangedByUsr,

      LastChangedByUserDescription,

      @Consumption.filter.selectionType: #INTERVAL
      RAContractLastChangeDate,

      RAContractIsSetToSystemAlloc,

      RAContrHasMnlPrcAllocConflict,

      RAAttributeHasConflict,

      @Consumption.filter.hidden: true
      PerfOblgnHasSprdgConflict,

//      @EndUserText.label: 'Universal Revenue Contract'

      @Consumption.filter.hidden: true
      RAContractIsUniversal,

      /* Associations */
      _CreatedByUserContactCard,

      _PerformanceObligation : redirected to composition child C_RAPerfOblgnPrcAllocTP,
      _Mapping               : redirected to composition child C_RAContrPrcAllocMappgOplDocTP,
      _BusinessPartner,
      _Customer


}
where
  RAContractHasAssetsImpairment = ''