C_QualityTaskProcessCalc

@AbapCatalog.sqlViewName: 'CQLTYTSKPROCCALC'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Qlty. Task Process Calculated Attributes'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey:  [ 'QualityTask' ],
    representativeKey: 'QualityTaskInternalId',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #B }   
}

@Consumption.semanticObject: 'QualityTask'

define view C_QualityTaskProcessCalc as select from I_QualityTaskTP 

//=== associations to other QM views                                                                                 

    association [1..1] to I_QltyTaskOrigin as _QualityTaskOrigin on $projection.QualityTaskOrigin = _QualityTaskOrigin.QualityTaskOrigin
{

//=== Key Fields

    key QualityTaskInternalId,
 
 //=== Common Fields

        @ObjectModel.readOnly: true  
        QualityTask,
        @ObjectModel.readOnly: true
        QualityTaskOrigin,
        QltyTaskFllwUpActionSts,
        
 //=== Quality Task Origin Extended Text Determination - needed for dynamic creation of task origin text with task origin object e.g. Defect (4711)

        @ObjectModel.readOnly: true
        @ObjectModel.text.element: ['QltyTaskOriginObject']
        @UI.textArrangement: #TEXT_LAST
        cast(_QualityTaskOrigin._Text[1:Language = $session.system_language].QualityTaskOriginText as vdm_qtaskoriginextdtext preserving type) as QualityTaskOriginText,
                
//=== Quality Task Origin Object Determination

        @ObjectModel.readOnly: true
        DefectInternalID,
        @ObjectModel.readOnly: true
        ProbSolvingProc,
          
        @ObjectModel.readOnly: true
        @UI.hidden: true
        cast(case I_QualityTaskTP.QualityTaskOrigin
               when '01' then cast(substring(DefectInternalID,2,11) as qdefectid preserving type )
               when '02' then ProbSolvingProc
               else '' 
             end as vdm_qtaskoriginobject) as QltyTaskOriginObject,

//=== Quality Task Origin Semantic Object Determination

        @ObjectModel.readOnly: true
        @UI.hidden: true
        cast(case I_QualityTaskTP.QualityTaskOrigin
               when '01' then 'Defect'
               when '02' then 'ProblemSolvingProcess'
               else ''
             end as vdm_qtaskoriginsemanticobject) as QltyTaskOriginSemanticObject,

//=== Quality Task Follow-Up Action - Latest Application Log Number Determination

        @ObjectModel: {  
            readOnly: true,
            sort.enabled: false,
            filter.enabled: false,
            virtualElement: true,
            virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_PROC_CALC_EXIT'
       }
       cast( '' as balognr ) as FllwUpActionLatestLogNumber,
//       @ObjectModel: {  

//            readOnly: true,

//            sort.enabled: false,

//            filter.enabled: false,

//            virtualElement: true,

//            virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_PROC_CALC_EXIT'

//       }

//       // Use same data element APL_LOG_HANDLE as in entity ApplicationLogHeader property LogHandle of service APL_LOG_MANAGEMENT_SRV.

//       // This avoids unwanted conversion of uuid in gateway.

//       cast( '' as apl_log_handle ) as FllwUpActionLatestLogHandle,


//=== Expose associations 

        @Consumption.filter.hidden: true
        _QualityTaskOrigin

} where IsDeleted <> 'X'