C_QltyNotificationFDP

@AbapCatalog.sqlViewName: 'CQLTYNOTIFFDP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_StsObjConcatActiveStsILL']
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Header Data of Quality Notification'
@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
  representativeKey: 'QualityNotification',
  supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #OUTPUT_FORM_DATA_PROVIDER ],
    usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #C
    }
}

define view C_QltyNotificationFDP
  as select from I_QltyNotification
  association [0..*] to C_QltyNotificationTaskFDP as _QltyNotificationTaskFDP    on  $projection.QualityNotification = _QltyNotificationTaskFDP.QualityNotification
  association [0..*] to C_QltyNotificationTaskFDP as _QltyNotificationHdrTaskFDP on  $projection.QualityNotification              = _QltyNotificationHdrTaskFDP.QualityNotification
                                                                                 and _QltyNotificationHdrTaskFDP.NotificationItem is initial
  association [0..*] to C_QltyNotificationItemFDP as _QltyNotificationItemFDP    on  $projection.QualityNotification = _QltyNotificationItemFDP.QualityNotification
 //Extension

  association [1..1] to E_QualityNotification        as _Extension                   on $projection.QualityNotification = _Extension.QualityNotification


{

  key QualityNotification,
      MasterLanguage,
      NotificationOrigin,
      NotificationType,
      NotifProcessingPhase,
      NotificationText,
      NotificationPriorityType,
      NotificationPriority,
      NotificationStatusObject,
      IsBusinessPurposeCompleted,
      IsDeleted,
      CreatedByUser,
      LastChangedByUser,
      NotificationCatalog,
      NotificationCodeGroup,
      NotificationCodeID,
      NotificationComplaintQuantity,
      NotificationInternalQuantity,
      NotificationExternalQty,
      NotificationQuantityUnit,
      NotificationReferenceQuantity,
      NotifReturnDeliveryQuantity,
      CreationDate,
      LastChangedDate,
      NotificationCreationTime,
      NotificationReportingDate,
      NotificationCompletionDate,
      NotificationRequiredStartDate,
      NotificationRequiredStartTime,
      NotificationRequiredEndDate,
      NotificationRequiredEndTime,
      CustomerPurchaseOrderDate,
      NotificationReturnDeliveryDate,
      Supplier,
      Customer,
      ReportedByUser,
      Material,
      MaterialGroup,
      Plant,
      ProductionOrder,
      MfgOrderInternalID,
      ProductionVersion,
      PurchasingDocument,
      PurchasingDocumentItem,
      PurchasingOrganization,
      PurchasingGroup,
      ActiveDivision,
      SalesOrganization,
      DistributionChannel,
      WBSElementInternalID,
      WorkCenterTypeCode,
      MainWorkCenterInternalID,
      MainWorkCenterPlant,
      InspectionLot,
      OrderOperationInternalID,
      Batch,
      Manufacturer,
      MaterialDocumentYear,
      MaterialDocument,
      MaterialDocumentItem,
      AdditionalDeviceData,
      NotificationLinkedNotification,
      NotificationExtReferenceNumber,
      OrderDocument,
      DeliveryDocument,
      DeliveryDocumentItem,
      PurchaseOrderByCustomer,

      case
      when InspectionLot is not initial and OrderOperationInternalID is not initial
        then cast( _InspectionOperation.InspectionOperation as vdm_vornr preserving type )
      when InspectionLot is not initial and MfgOrderInternalID is not initial
        then cast( _OrderOperationBasic.Operation as vdm_vornr preserving type )
      else cast( '    ' as vdm_vornr preserving type ) end as OrderOperation,

      case
      when InspectionLot is not initial and OrderOperationInternalID is not initial
        then _InspectionOperation.OperationText
      when InspectionLot is not initial and MfgOrderInternalID is not initial
        then _OrderOperationBasic.OperationText
      else '' end as OperationText,

      /* Associations */
      _CreatedByUserContactCard,
      _Customer,
      _InspectionLot,
      _LastChangedByUserContactCard,
      _NotificationCatalog,
      _NotificationCode,
      _NotificationCodeGroup,
      _NotificationItem,
      _NotificationPriority,
      _NotificationQuantityUnit,
      _NotificationType,
      _NotifProcessingPhase,
      _Plant,
      _Product,
      _ProductGroup,
      _ProductGroup_2,
      _PurchasingDocument,
      _QltyNotificationActivity,
      _QltyNotificationHdrActivity,
      _QltyNotificationHdrTaskFDP,
      _QltyNotificationLongText,
      _QltyNotificationTaskFDP,
      _QltyNotificationItemFDP,
      _QualityNotificationPartner,
      _StsObjConcatActiveStsILL,
      _Supplier,
      _InspectionOperation,
      _OrderOperationBasic,
      _WBSElement
}