C_PurchasingOrgValueHelp

DDL: C_PURCHASINGORGVALUEHELP SQL: CPURORG_VH Type: view CONSUMPTION

Purchasing Organization

C_PurchasingOrgValueHelp is a Consumption CDS View that provides data about "Purchasing Organization" in SAP S/4HANA. It reads from 1 data source (I_PurchasingOrganization) and exposes 6 fields with key field PurchasingOrganization. It has 1 association to related views. It is exposed through 3 OData services (MM_PUR_PROCESS_PR_V4, UI_CNTRLCONTRITMSELECT_MANAGE, UI_TRDGCONTR_MANAGEV4).

1 data source(s) Exposed by 3 service(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
I_PurchasingOrganization PurchasingOrganization from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_CompanyCode _CompanyCode $projection.CompanyCode = _CompanyCode.CompanyCode

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CPURORG_VH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #CONSUMPTION view
Search.searchable true view
ObjectModel.semanticKey PurchasingOrganization view
ObjectModel.representativeKey PurchasingOrganization view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #VALUE_HELP view
EndUserText.label Purchasing Organization view
ClientHandling.algorithm #SESSION_VARIABLE view
Consumption.ranked true view

OData Services (3)

ServiceBindingVersionContractRelease
MM_PUR_PROCESS_PR_V4 MM_PUR_PR_PROCESS_V4 V4 C1 NOT_RELEASED
UI_CNTRLCONTRITMSELECT_MANAGE UI_CNTRLCONTRITMSEL_MANAGE V2 C1 NOT_RELEASED
UI_TRDGCONTR_MANAGEV4 UI_TRDGCONTR_MANAGEV4 V4 C1 NOT_RELEASED

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY PurchasingOrganization I_PurchasingOrganization PurchasingOrganization
PurchasingOrganizationName I_PurchasingOrganization PurchasingOrganizationName Purchasing Organization Name
CompanyCode I_PurchasingOrganization CompanyCode
_CompanyCode _CompanyCode
CompanyCodeName _CompanyCode CompanyCodeName
ConfigDeprecationCode I_PurchasingOrganization ConfigDeprecationCode 
@AbapCatalog.sqlViewName: 'CPURORG_VH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.semanticKey: 'PurchasingOrganization'
@ObjectModel.representativeKey: 'PurchasingOrganization'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.dataCategory:#VALUE_HELP
//@EndUserText.label: 'Purchasing Organization Value Help'

@EndUserText.label: 'Purchasing Organization'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true

define view C_PurchasingOrgValueHelp
  as select from I_PurchasingOrganization as PurchasingOrganization

  //association [0..*] to I_SupplierPurchasingOrg as _SupplierPurchasingOrg

  //    on $projection.PurchasingOrganization = _SupplierPurchasingOrg.PurchasingOrganization


  association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode

{

      @ObjectModel.text.element:  [ 'PurchasingOrganizationName' ]
      @Search: { defaultSearchElement:true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @EndUserText.quickInfo: 'Purchasing Organization'
  key PurchasingOrganization.PurchasingOrganization     as PurchasingOrganization,

      //  Purchasing Organization is denormalized by supplier

      //    @Search: { defaultSearchElement: true, ranking: #MEDIUM }

      //    key _SupplierPurchasingOrg.Supplier as Supplier,


      @Semantics.text: true
      @EndUserText.label: 'Purchasing Organization Name'
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7  }
      @EndUserText.quickInfo: 'Purchasing Organization Name'
      PurchasingOrganization.PurchasingOrganizationName as PurchasingOrganizationName,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      @ObjectModel.text.element:  [ 'CompanyCodeName' ]
      @Search: { defaultSearchElement:true, ranking: #LOW, fuzzinessThreshold: 0.7  }
      @EndUserText.quickInfo: 'Company Code'
      PurchasingOrganization.CompanyCode                as CompanyCode,
      _CompanyCode,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7  }
      _CompanyCode.CompanyCodeName                      as CompanyCodeName,
      
      PurchasingOrganization.ConfigDeprecationCode      as ConfigDeprecationCode
      
} where
  ConfigDeprecationCode <> 'E'

Learn More