C_ProjDmndWorkPackageDisplay

DDL: C_PROJDMNDWORKPACKAGEDISPLAY SQL: CPROJDMNDWPDISP Type: view CONSUMPTION

WBS Element Details

C_ProjDmndWorkPackageDisplay is a Consumption CDS View that provides data about "WBS Element Details" in SAP S/4HANA. It reads from 1 data source (I_PPM_Task) and exposes 19 fields with key field ProjectElementUUID. It has 1 association to related views.

1 data source(s) 19 fields

Data Sources (1)

SourceAliasJoin Type
I_PPM_Task _Task from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_PPM_ProjectProcgStatusVH _ProjectProcessingStatus $projection.TaskProcessingStatus = _ProjectProcessingStatus.ProcessingStatus

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName CPROJDMNDWPDISP view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label WBS Element Details view
AbapCatalog.preserveKey true view
AccessControl.personalData.blocking #REQUIRED view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey ProjectElementUUID view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.sizeCategory #L view

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY ProjectElementUUID TaskUUID
TaskName TaskName WBS Element Name
ExternalId ExternalId WBS Element ID
ProcessingStatusText
ProjectProcessingStatus _ProjectProcessingStatus ProcessingStatus WBS Element Processing Status
TaskProcessingStatus TaskProcessingStatus
ActualStartDate ActualStartDate WBS Element Actual Start
ActualFinishDate ActualFinishDate WBS Element Actual Finish
PlannedStartDate EarliestStartDate WBS Element Planned Start
PlannedEndDate EarliestFinishDate WBS Element Planned End
ProjectInternalID ProjectInternalID
IsProjectMilestone IsProjectMilestone
ProjectUUID ProjectUUID
WBSElementInternalID WBSElementInternalID
_ProjObj _ProjObj
_AuthUser _AuthUser
_AuthSubst _AuthSubst
_AuthRole _AuthRole
_AuthGroup _AuthGroup 
@AbapCatalog.sqlViewName: 'CPROJDMNDWPDISP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'WBS Element Details'
@AbapCatalog.preserveKey: true

@AccessControl.personalData.blocking:#REQUIRED
@VDM.viewType: #CONSUMPTION

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   semanticKey:       [ 'TaskName' ],
   representativeKey: 'ProjectElementUUID',
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #L
    }
}
define view C_ProjDmndWorkPackageDisplay
  as select from I_PPM_Task as _Task


  association [0..1] to I_PPM_ProjectProcgStatusVH as _ProjectProcessingStatus on $projection.TaskProcessingStatus = _ProjectProcessingStatus.ProcessingStatus

{
      @UI.facet: [
       {
         purpose: #QUICK_VIEW,
         type: #FIELDGROUP_REFERENCE,
         targetQualifier: 'WPPOPOVER1',
         label: 'General Information'
       },
       {
        purpose: #QUICK_VIEW,
         type: #FIELDGROUP_REFERENCE,
         targetQualifier: 'WPPOPOVER2',
         label: 'Dates'
       }
      ]
      @UI.hidden: true
  key TaskUUID                                                                                   as ProjectElementUUID,
      @EndUserText.label: 'WBS Element Name'
      @EndUserText.quickInfo: 'WBS Element Name'
      @Consumption.valueHelpDefinition: [{
          entity: {   name:    'C_ProjectDemandWorkPackageVH',
                      element: 'ProjectElementDescription' }
      }]
      TaskName,
      
      @EndUserText.label: 'WBS Element ID'
      @Consumption.valueHelpDefinition: [{
          entity: {   name:    'C_ProjectDemandWorkPackageVH',
                      element: 'ProjectElement' }
      }]
      ExternalId,

      _ProjectProcessingStatus._Text[1:Language = $session.system_language].ProcessingStatusText as ProcessingStatusText,

      @EndUserText.label: 'WBS Element Processing Status'
      @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER1', position: 10, label: 'Processing Status'}]
      }
      @ObjectModel.text.element: 'ProcessingStatusText'
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [{entity: {name: 'I_PPM_ProjectProcgStatusVH', element: 'ProcessingStatus'}}]
      _ProjectProcessingStatus.ProcessingStatus                                                  as ProjectProcessingStatus,

      @UI.hidden: true
      TaskProcessingStatus,

      @EndUserText.label: 'WBS Element Actual Start'
      @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER2', position: 50, label: 'Actual Start'}]
      }
      @Consumption.filter.hidden: true
      ActualStartDate,
      @EndUserText.label: 'WBS Element Actual Finish'
      @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER2', position: 60, label: 'Actual Finish'}]
      }
      @Consumption.filter.hidden: true
      ActualFinishDate,
      @EndUserText.label: 'WBS Element Planned Start'
      @UI: {
       fieldGroup:     [{ qualifier:'WPPOPOVER2', position: 30, label: 'Planned Start'}]
      }
      @Consumption.filter.selectionType: #INTERVAL
      EarliestStartDate                                                                          as PlannedStartDate,
      @EndUserText.label: 'WBS Element Planned End'
      @UI: {
       fieldGroup:     [{ qualifier:'WPPOPOVER2', position: 40, label: 'Planned End'}]
      }
      @Consumption.filter.selectionType: #INTERVAL
      EarliestFinishDate                                                                         as PlannedEndDate,
      @UI.hidden: true
      ProjectInternalID,
      @UI.hidden: true
      IsProjectMilestone,

      @UI.hidden: true
      ProjectUUID,

      @UI.hidden: true
      WBSElementInternalID,

      //_I_Project ,

      _ProjObj,
      // Authorization Association, do not expose externally

      @Consumption.hidden: true
      _AuthUser,
      @Consumption.hidden: true
      _AuthSubst,
      @Consumption.hidden: true
      _AuthRole,
      @Consumption.hidden: true
      _AuthGroup
}

Learn More