C_ProductionVersion

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Production Version List'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel.usageType:{ serviceQuality: #X, sizeCategory: #S, dataClass: #MIXED }
@Search.searchable: true
@Metadata.allowExtensions: true

define root view entity C_ProductionVersion
  provider contract transactional_query
  as projection on R_ProductionVersionTP
  association [0..*] to C_TaskListSequence as _TaskListSequence on  $projection.BillOfOperationsType    = _TaskListSequence.BillOfOperationsType
                                                                and $projection.BillOfOperationsGroup   = _TaskListSequence.BillOfOperationsGroup
                                                                and $projection.BillOfOperationsVariant = _TaskListSequence.BillOfOperationsVariant
  //Associated Task List Operations

  association [0..*] to C_TaskListActivity as _Operation        on  $projection.BillOfOperationsType    = _Operation.BillOfOperationsType
                                                                and $projection.BillOfOperationsGroup   = _Operation.BillOfOperationsGroup
                                                                and $projection.BillOfOperationsVariant = _Operation.BillOfOperationsVariant
{

          @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.9, ranking: #HIGH }
          ////          @UI.fieldGroup:[{qualifier:'MaterialFieldGroup', position:10 }]

          @Consumption.semanticObject: 'Material'
          @ObjectModel.text.element: ['MaterialName']
          @UI.textArrangement: #TEXT_LAST
  key     Material,
          @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.9, ranking: #HIGH }
  key     Plant,
  key     ProductionVersion,
          @EndUserText.label: 'Production Version Description'
          ProductionVersionText,
          ChangeHistoryCount,
          ChangeNumber,
          CreationDate,
          CreatedByUser,
          LastChangeDate,
          LastChangedByUser,
          @ObjectModel.text.element: ['BillOfOperationsTypeName']
          BillOfOperationsType,
          //          @ObjectModel.text.element: ['BillOfOperationsVariant']

          BillOfOperationsGroup,
          @Semantics.text: true
          BillOfOperationsVariant,
          BillOfMaterialVariantUsage,
          BillOfMaterialVariant,
          ProductionLine,
          ProductionSupplyArea,
          ProductionVersionGroup,
          MainProduct,
          MaterialCostApportionmentStruc,
          IssuingStorageLocation,
          ReceivingStorageLocation,
          OriginalBatchReferenceMaterial,
          QuantityDistributionKey,
          ProductionVersionStatus,
          RoutingCheckStatusText,
          ProductionVersionLastCheckDate,
          RateBasedPlanningStatus,
          PreliminaryPlanningStatus,
          //          BOMCheckStatus,

          ValidityStartDate,
          ValidityEndDate,
          @ObjectModel:{text.element:  [ 'ProductionVersionLockText' ]  }
          @ObjectModel.foreignKey.association: '_ProdnVersLockVH'
          ProductionVersionLock,
          ProdnVersIsAllowedForRptvMfg,
          HasVersionCtrldBOMAndRouting,
          PlanningAndExecutionBOMIsDiff,
          ExecBillOfMaterialVariantUsage,
          ExecBillOfMaterialVariant,
          ExecBillOfOperationsType,
          ExecBillOfOperationsGroup,
          ExecBillOfOperationsVariant,
          EWMWarehouse,
          DestinationStorageBin,
          ProcurementType,
          MaterialProcurementProfile,
          UsgeProbltyWthVersCtrlInPct,
          MaterialBaseUnit,
          @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
          MaterialMinLotSizeQuantity,
          @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
          MaterialMaxLotSizeQuantity,
          @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
          CostingLotSize,
          TargetProductionSupplyArea,
          _ProductPlant.MRPResponsible,
          _Plant.PlantName,
          cast(MRPController as pph_dispo preserving type )                                   as MRPController,
          @Search.defaultSearchElement: true
          //          @UI.lineItem: [{ label: 'Material', position: 10, type: #AS_FIELDGROUP, valueQualifier: 'MaterialFieldGroup'}]

          //          @UI.fieldGroup:[{qualifier:'MaterialFieldGroup', position:20, emphasized: true}]


          _MaterialText.MaterialName                                                          as MaterialName,
          BillOfOperationsTypeName,
          _ProdnVersLockText.ProductionVersionLockText,

          @UI.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_PPH_PRV_OVERALL_CHECKSTATUS'
  virtual CheckStatusCriticality : abap.int1,


          cast(BOMCheckStatus as mpe_pv_bom_chksts preserving type )                          as BOMCheckStatus,
          OvrlProdnVersChkSts,
          _MaterialBOM.BillOfMaterial,
          _MaterialBOM.BillOfMaterialCategory,

          //Consistency Check Status

          _ConstcyLogCount[1:ProdnVersConstcyIssSvrtyLvl = 'W'].NumberOfProdnVersConstcyIssue as NmbrOfProdnVersConstcyWarning,
          _ConstcyLogCount[1:ProdnVersConstcyIssSvrtyLvl = 'E'].NumberOfProdnVersConstcyIssue as NumberOfProdnVersConstcyError,
          _ConstcyLogCount[1:ProdnVersConstcyIssSvrtyLvl = 'S'].NumberOfProdnVersConstcyIssue as NmbrOfProdnVersConstcySuccess,

          /* Associations */
          _BillOfOperations,
          _BillOfOperationsGroup,
          _BillOfOperationsType,
          _BillOfOperationsTypeText,
          _ChangeMaster,
          _IssuingStorageLocation,
          _MainProduct,
          _Material,
          _MaterialBaseUnit,
          _MatlCostApportionmentStruc,
          _MatlProcurementProfile,
          _OriglBatchReferenceMaterial,
          _Plant,
          _MaterialText,
          _Product,
          _ProductionLine,
          _ProductionSupplyArea,
          _ProductionVersionGroup,
          _ProductPlant,
          _QuantityDistributionKey,
          _ReceivingStorageLocation,
          _TargetProductionSupplyArea,
          _ProdnVersLockText,
          _ProdnVersLockVH,
          _TaskListSequence,
          _Operation,

          /*Compositional Association*/
          _ConstcyLog : redirected to composition child C_ProdnVersConsistencyLog
}

where
  (
       BillOfOperationsType = '2'
    or BillOfOperationsType = 'N'
    or BillOfOperationsType = 'S'
    or BillOfOperationsType = ' '
  )