C_ProdSubstnSet

@AccessControl:{
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}
@EndUserText.label: 'Product Substitution Set'
@ObjectModel:{
  representativeKey: 'MDSubstnUUID',
  semanticKey: [ 'Product', 'SubstituteProduct', 'Plant', 'MDSubstnGroup', 'MDSubstnReason' ],
  usageType:{
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  }
}
@VDM: {
  viewType: #CONSUMPTION
}

@UI: {
  headerInfo: {
    typeNamePlural: 'Product Substitutions'
  }
}

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity C_ProdSubstnSet
  as select from I_ProdSubstnSet
{
      @UI: {
        hidden: true
      }
  key MDSubstnUUID,

      @UI: {
        hidden: true
      }
      MDSubstnObjectType,

      @Consumption: {
        semanticObject: 'Material'
      }
      @ObjectModel.text.element: ['ProductDescription']
      Product,

      @UI: {
        hidden: true
      }
      _Product._Text[1:Language=$session.system_language].ProductName           as ProductDescription,

      @Consumption: {
        semanticObject: 'Material'
      }
      @ObjectModel.text.element: ['SubstituteProductDescription']
      @UI: {
        lineItem: [
          { position: 10, importance: #HIGH }
        ],
        textArrangement: #TEXT_LAST
      }
      SubstituteProduct,

      @UI: {
        hidden: true
      }
      _SubstituteProduct._Text[1:Language=$session.system_language].ProductName as SubstituteProductDescription,

      @UI: {
        hidden: true
      }
      MDSubstnContextObjectType,

      @ObjectModel.text.element: ['PlantName']
      @UI: {
        hidden: true
      }
      Plant,
      @UI: {
        hidden: true
      }
      I_ProdSubstnSet._Plant.PlantName,

      @UI: {
        hidden: true
      }
      MDSubstnContextObjectType2,

      @ObjectModel.text.element: ['MDSubstnGroupDescription']
      @UI: {
        hidden: true
      }
      MDSubstnGroup,

      @UI: {
        hidden: true
      }
      _Group._GroupText[1:Language=$session.system_language].MDSubstnGroupDescription,

      @UI: {
        hidden: true
      }
      MDSubstnVersionValue,

      @UI: {
        hidden: true
      }
      MDSubstnSet,

      @UI: {
        lineItem: [
          { position: 40, importance: #HIGH }
        ]
      }
      MDSubstnIsExit,

      @UI: {
        lineItem: [
          { position: 20, importance: #HIGH }
        ]
      }
      MDSubstnIsLeading,

      @UI: {
        lineItem: [
          { position: 30, importance: #HIGH }
        ]
      }
      MDSubstnSequenceValue,

      @UI: {
        lineItem: [
          { position: 50, importance: #MEDIUM }
        ]
      }
      MDSubstnConversionNumerator,

      @UI: {
        lineItem: [
          { position: 60, importance: #MEDIUM }
        ]
      }
      MDSubstnConversionDenominator,

      @UI: {
        lineItem: [
          { position: 70, importance: #MEDIUM }
        ]
      }
      MDSubstnConversionPercent,
      @UI: {
        hidden: true
      }
      MDSubstnValidityStartDate,
      @UI: {
        hidden: true
      }
      MDSubstnValidityStartTime,
      @UI: {
        hidden: true
      }
      MDSubstnValidityEndDate,
      @UI: {
        hidden: true
      }
      MDSubstnValidityEndTime,
      @UI: {
        hidden: true
      }
      TimeZoneID,

      @ObjectModel.text.element: ['MDSubstnReasonDescription']
      @UI: {
        lineItem: [
          { position: 80, importance: #HIGH }
        ]
      }
      MDSubstnReason,

      @UI: {
        hidden: true
      }
      _Reason._Text[1:Language=$session.system_language].MDSubstnReasonDescription,

      @ObjectModel.text.element: ['MDSubstnStatusDescription']
      @UI: {
        lineItem: [
          { position: 100, importance: #MEDIUM, criticality: 'MDSubstnStatusCriticality', criticalityRepresentation: #WITHOUT_ICON }
        ],
        textArrangement: #TEXT_ONLY
      }
      MDSubstnStatus,

      @UI: {
        hidden: true
      }
      case MDSubstnStatus
        when 'A' then 3
        else 0
      end                                                                       as MDSubstnStatusCriticality,

      _Status._Text[1:Language=$session.system_language].MDSubstnStatusDescription,
      
      MDSubstnIsRlvtForATPProd,

      @UI: {
        hidden: true
      }
      MDSubstnIsRelevantForESPP,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,

      /* Associations */
      _MDObjectType,
      _ContextObjectTypeCode,
      _ContextObjectTypeCode2,
      _Product,
      _SubstituteProduct,
      _Plant,
      _Group,
      _ExitIndicator,
      _LeadIndicator,
      _TimeZone,
      _Reason,
      _Status,
      _MDSubstnIsRlvtForATPProd,
      _MDSubstnIsRelevantForESPP
}
where
       MDSubstnObjectType         = 'Product'
  and  MDSubstnContextObjectType  = 'Plant'
  and(
       MDSubstnContextObjectType2 is initial
    or MDSubstnContextObjectType2 is null
  )
  and  MDSubstnSet                is not initial