C_ProdStrucNode

@AbapCatalog.sqlViewName: 'CPSNODE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@Search.searchable: true

@VDM.lifecycle: {
//  contract: {

//    type: #PUBLIC_LOCAL_API

//  },

  status: #DEPRECATED,
  successor: 'I_ProductStructureVariant_2'
}
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
//@OData.publish: true


//@ObjectModel:{

//    semanticKey: ['ProductStructure'],

//    compositionRoot: true

//}


@EndUserText.label: 'Product Structure Node List'
define view C_ProdStrucNode as select from I_ProductStructureNode_2 as _Node
  association [0..1] to C_ProdStrucNodeType                 as _NodeType on $projection.ProductStructureNodeType = _NodeType.ProductStructureNodeType
  association [0..1] to I_ProdStrucClassVH                  as _Class    on _Node.ClassInternalID = _Class.ClassInternalID
  association [0..1] to I_ProdStrucLogAccMActive  as _LogAccMObjectTypeActive  on  $projection.ProductStructureGnrcObjType = _LogAccMObjectTypeActive.LogAccMObjectType
  association [0..1] to I_ProdStrucObjSecureIDAssgmt as _LogAccMObjSecureIDAssgmt on  $projection.ProductStructureNodeUniqueID           = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                and $projection.ProductStructureGnrcObjType              = _LogAccMObjSecureIDAssgmt.LogAccMObjectType
  association [0..*] to I_ProdStrucObjectUserAuthzn  as _LogAccMObjectUserAuthzn  on  $projection.ProductStructureNodeUniqueID           = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                and _LogAccMObjectUserAuthzn.LogAccMObjectType           = $projection.ProductStructureGnrcObjType
{
  key ProductStructureNodeUUID,
      ProductStructureNodeUniqueID,
      @Search.defaultSearchElement: true
      _Class.Class,
      @Search.defaultSearchElement: true
      _Class[1:Language = $session.system_language].ClassName,
      _Class.ClassInternalID,
      @Search.defaultSearchElement: true
      _Class.ClassType,
      @Semantics.user.lastChangedBy: true
      ProductStrucLastChangedByUser,
      ProductStrucLastChangedDate,
      ProductStructureCreatedByUser,
      ProductStructureCreationDate,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
      @ObjectModel.mandatory: true
      ProductStructureNodeName,
      ProductStructureNodeType,
      _Text[1:Language = $session.system_language].ProdStrucNodeDescription,
      _NodeType.ProdStrucNodeTypeDescription,
      @UI.hidden: true
      _Node.ProductStructureGnrcObjType,

      _LogAccMObjectTypeActive,
      _LogAccMObjSecureIDAssgmt,
      _LogAccMObjectUserAuthzn
}