C_ProbSolvingProcStpCmnt

@AbapCatalog.sqlViewName: 'CPRSLPRSTCMNT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedByUserContactCard', '_LastChangedByUserContactCard' ]

@EndUserText.label: 'Problem-Solving Process Step Comment'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #B },
    representativeKey: 'ProbSolvingProcCommentID',
    semanticKey:  [ 'ProbSolvingProc', 'ProbSolvingProcStp', 'ProbSolvingProcCommentID' ],

// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated:true,
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false 
// End Draft

}

@Metadata.allowExtensions: true

define view C_ProbSolvingProcStpCmnt as select from I_ProbSolvingProcStpCmntTP as _ProbSolvingProcStpCmnt

  association [1..1] to C_ProbSolvingProcExect as _ProbSolvingProc on $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc
  association [1..1] to C_ProbSolvingProcStepExect as _ProbSolvingProcStp on $projection.ProbSolvingProc    = _ProbSolvingProcStp.ProbSolvingProc
                                                                         and $projection.ProbSolvingProcStp = _ProbSolvingProcStp.ProbSolvingProcStp
{
  key _ProbSolvingProcStpCmnt.ProbSolvingProc,
  key _ProbSolvingProcStpCmnt.ProbSolvingProcStp,
  key _ProbSolvingProcStpCmnt.ProbSolvingProcCommentID,
  
      _ProbSolvingProcStpCmnt.Language,
      
      @ObjectModel.readOnly: true
      _ProbSolvingProcStpCmnt.ProbSolvingProcCommentText,
    
      _ProbSolvingProcStpCmnt.CreatedByUser,
      _ProbSolvingProcStpCmnt.ProbSolvingCmntCrtedDteTme,
      _ProbSolvingProcStpCmnt.LastChangedByUser,
      _ProbSolvingProcStpCmnt.ProbSolvingCmntLastChgdDteTme,
      
//=== exposed associations

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT ]
      _ProbSolvingProc,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _ProbSolvingProcStp,
      
      @Consumption.filter.hidden: true
      _ProbSolvingProcStpCmnt._Language,
      @Consumption.filter.hidden: true
      _ProbSolvingProcStpCmnt._CreatedByUserContactCard,
      @Consumption.filter.hidden: true
      _ProbSolvingProcStpCmnt._LastChangedByUserContactCard
}