C_ProbSolvingProcDefectRef

@AbapCatalog.sqlViewName: 'CPRSOLPROCDFR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Problem-Solving Process Defect Reference'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #B },
    representativeKey: 'DefectInternalID',
    semanticKey:  [ 'ProbSolvingProc', 'DefectInternalID' ],
// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated:true,
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false 
}
@Metadata.allowExtensions: true

@UI.presentationVariant: { 
                sortOrder: [{ by: 'DefectIsBaseOfProbSolvingProc', direction: #DESC }],
                visualizations: [{type: #AS_LINEITEM }],
                requestAtLeast: ['DefectIsBaseOfProbSolvingProc']
}

define view C_ProbSolvingProcDefectRef as select from I_ProbSolvingProcDefectRefTP as _ProbSolvingProcDefectRefTP 

//=== parent / root node  

    association [1..1] to C_ProbSolvingProcExect as _ProbSolvingProc on $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc

//=== defect detailed description

    association [0..1] to I_DefectLongText as _DefectDetailedDescription on $projection.DefectInternalID           = _DefectDetailedDescription.DefectInternalID
                                                                        and $projection.masterlanguage             = _DefectDetailedDescription.Language
                                                                        and _DefectDetailedDescription.LongTextInternalNumber = 1
{
//=== key fields

  @ObjectModel.readOnly: true
  key _ProbSolvingProcDefectRefTP.ProbSolvingProc,
  @ObjectModel.readOnly: true
  key _ProbSolvingProcDefectRefTP.DefectInternalID,
  
//=== common fields

     @ObjectModel.readOnly: true
     @Consumption.filter.hidden: true
     _ProbSolvingProcDefectRefTP.DefectIsBaseOfProbSolvingProc,

//=== Defect specific fields

  @ObjectModel: { 
            readOnly:       true
            //text.element:   ['DefectText']

  }
  @Consumption.semanticObject: 'Defect'
  // UX Inc

  @Consumption.valueHelpDefinition: [ 
  { entity: { name:    'I_DefectVH',
              element: 'Defect' }
  }]
      _ProbSolvingProcDefectRefTP._Defect.Defect,
  @ObjectModel.readOnly: true
      _ProbSolvingProcDefectRefTP._Defect.DefectText,
  @ObjectModel.readOnly: true
      _ProbSolvingProcDefectRefTP._Defect.DefectCategory,
  @ObjectModel.readOnly: true
  @Consumption.filter.hidden: true
      _ProbSolvingProcDefectRefTP._Defect.Material,
  @ObjectModel.readOnly: true
  @Consumption.filter.hidden: true
      _ProbSolvingProcDefectRefTP._Defect.MasterLanguage,
            
 //=== exposed associations

  @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
  _ProbSolvingProc,
  @Consumption.filter.hidden: true
  _ProbSolvingProcDefectRefTP._Defect._DefectCategory,
  @Consumption.filter.hidden: true
  _ProbSolvingProcDefectRefTP._Defect._Product,
  @Consumption.filter.hidden: true
  _DefectDetailedDescription
}