C_PPM_TaskSuccessor

@EndUserText.label: 'Task Successor'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPPMTASKSUCC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

@UI.headerInfo:{
  typeName:       'Project Task',
  typeNamePlural: 'Project Tasks'
}

@Consumption.semanticObject: 'ProjectTask'

define view C_PPM_TaskSuccessor
  as select from    I_PPM_TaskRelationship        as rel
    left outer join I_PPM_SingleResponsibleForObj as bupa     on bupa.ReferencedObjectUUID = rel.SuccessorTaskUUID
    left outer join I_PPM_TaskText                as text     on text.TaskUUID = rel.SuccessorTaskUUID

   // associations to authorization views

    association [0..*] to I_PPM_AuthznByUsrH        as _AuthUser
            on      _AuthUser.ReferencedObjectUUID   = $projection.TaskUUIDRaw
             and    _AuthUser.UserID                 = $session.user
             and (  _AuthUser.Activity = 'Admin'     or _AuthUser.Activity = 'Write'      or _AuthUser.Activity = 'Read' )
    association [0..*] to I_PPM_AuthznBySubstitH    as _AuthSubst
            on      _AuthSubst.ReferencedObjectUUID  = $projection.TaskUUIDRaw
             and    _AuthSubst.UserID                = $session.user
             and (  _AuthSubst.Activity = 'Admin'    or _AuthSubst.Activity = 'Write'     or _AuthSubst.Activity = 'Read' )
    association [0..*] to I_PPM_AuthznByUserRoleH   as _AuthRole
            on      _AuthRole.ReferencedObjectUUID   = $projection.TaskUUIDRaw
             and    _AuthRole.UserID                 = $session.user
             and (  _AuthRole.Activity = 'Admin'     or _AuthRole.Activity = 'Write'      or _AuthRole.Activity = 'Read' )
    association [0..*] to I_PPM_AuthznByUsrGrpH     as _AuthGroup
            on      _AuthGroup.ReferencedObjectUUID  = $projection.TaskUUIDRaw
             and    _AuthGroup.UserID                = $session.user
             and (  _AuthGroup.Activity = 'Admin'    or _AuthGroup.Activity = 'Write'     or _AuthGroup.Activity = 'Read' )


{
      @UI.hidden: true
      @Consumption.semanticObject: 'ProjectTask'
  key bintohex(rel.SuccessorTaskUUID)          as TaskUUID,

      @UI.hidden: true
  key bintohex(rel.PredecessorTaskUUID)        as PredecessorTaskUUID,

      @UI.hidden: true
      rel.SuccessorTaskUUID                    as TaskUUIDRaw,

      @UI.lineItem: { position: 10, importance: #HIGH }
      @EndUserText: {
        label: 'Element',
        quickInfo: 'Element'
      }
      text.ObjectName,

      @UI.lineItem: { position: 20, importance: #HIGH }
      @EndUserText.label: 'Latest Start'

      case
        //Scheduled start not visualized for duration zero

        when rel._SuccessorTask.ProjectElementDuration = 0 then
          // needed to make the date disappear on the UI.

          tstmp_to_dats(
            cast('000000000000' as /s4ppm/tv_latest_start),
            abap_system_timezone( $session.client,'NULL' ),
            $session.client,
            'NULL' )
        else
          tstmp_to_dats(
            rel._SuccessorTask.LatestStartDateTime,
            abap_system_timezone( $session.client,'NULL' ),
            $session.client,
            'NULL' )
      end as LatestStartDate,

      @UI.lineItem: { position: 30, importance: #HIGH }
      @EndUserText.label: 'Responsible'
      bupa.BusinessPartnerName,
      @UI.hidden: true
      bupa.BusinessPartnerUUID,

      @UI.hidden: true
      EPPMSettingsDefaultValue,
      // never expose the following associations, only used for authorization checks

     @UI.hidden:true
     bupa._BusinessUser,
     @UI.hidden:true
     _AuthUser,
     @UI.hidden:true
     _AuthSubst,
     @UI.hidden:true
     _AuthRole,
     @UI.hidden:true
     _AuthGroup
}