C_OutbDelivProcFlow

@AbapCatalog.sqlViewName: 'COBDLVPROCFLOW'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Outbound Delivery Process Flow'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.compositionRoot:true
@Consumption.dbHints: ['NO_AGGR_THRU_JOIN']

define view C_OutbDelivProcFlow
  // Lane 2 (Delivery Creation): Anchor Document

  as select distinct from I_DeliveryDocument as Delivery
{
  key Delivery.DeliveryDocument                           as OutboundDelivery,
  key cast(Delivery.DeliveryDocument as preced_doc)       as PrecedingDocument,
  key cast(Delivery.SDDocumentCategory as preced_doc_cat) as PrecedingDocumentCategory,
  key cast(' ' as subsequ_doc)                            as SubsequentDocument,
  key cast(' ' as subsequ_doc_cat)                        as SubsequentDocumentCategory,

      Delivery.ShippingPoint,
      Delivery.SDDocumentCategory,

      cast('' as vbeln_va)                                as SalesDocument,
      cast('' as ebeln)                                   as PurchaseOrder,

      cast('' as lgnum)                                   as WarehouseNumber,
      cast('0000000000' as wm_transfer_order)             as WrhsMgmtTransferOrder,

      cast('' as mblnr )                                  as MaterialDocument,
      cast('0000' as mjahr)                               as MaterialDocumentYear,

      cast('' as vbeln)                                   as BillingDocument,
      cast('' as /scmtms/tor_id)                          as FreightOrder,
      cast('' as vbeln_vl)                                as InboundDelivery

}
where
  Delivery.SDDocumentCategory = 'J'

// Relatives of Outbound Delivery

// Lane 1 (Order Creation):     Sales Order/ Purchase Order -> Outbound Delivery

// Lane 1.1 (NJIT):             JIT Call -> Outbound Delivery

// Lane 3 (Picking):            Outbound Delivery > Non-cancelled WM Transfer Orders

// Lane 4 (Goods Movement):     Outbound Delivery > Latest Material Document Goods Issue/ Cancel Goods Issue

// Lane 5 (Invoicing):          Outbound Delivery > Billing Document

// Lane 6 (Delivery Creation):  Goods Issue > Inbound Delivery (STO 2-step with Inbound Delivery)

// Lane 7 (Putaway): Inbound    Delivery > WM Transfer Order (STO 2-step with Inbound Delivery)

// Lane 8 (Goods Movement):     Inbound Delivery > Goods Receipt (STO 2-step with Inbound Delivery)

// Lane 9 (Invoicing):          Inbound Delivery > Supplier Invoice (STO 2-step with Inbound Delivery)

// Lane 8 (Goods Movement):     Purchase Order -> GoodsReceipt  (STO 2-step w/o Inbound Delivery)

// Lane 8 (Goods Movement):     Purchase Order -> GoodsIssue (rSTO 2-step with Returns Delivery)

union all select distinct from P_OutbDelivProcFlowNoAnchr as OutbDelivProcFlowNoAnchr
// join with I_DeliveryDocument to get  Shipping Point

  inner join                   I_DeliveryDocument         as Delivery on Delivery.DeliveryDocument = OutbDelivProcFlowNoAnchr.DeliveryDocument
{
  key OutbDelivProcFlowNoAnchr.DeliveryDocument as OutboundDelivery,
  key PrecedingDocument,
  key PrecedingDocumentCategory,
  key SubsequentDocument,
  key SubsequentDocumentCategory,

      Delivery.ShippingPoint,
      OutbDelivProcFlowNoAnchr.SDDocumentCategory,

      SalesDocument,
      PurchaseOrder,

      WarehouseNumber,
      WrhsMgmtTransferOrder,

      MaterialDocument,
      MaterialDocumentYear,

      BillingDocument,
      FreightOrder,
      InboundDelivery

}
where
  Delivery.SDDocumentCategory = 'J'