@AbapCatalog.sqlViewName: 'CGRCDELSUPOPNITM'
@EndUserText.label: 'Supplier Marked for Deletion Open Item'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
define view C_MrkdDeltnSuplrOpenItem
as select from I_OperationalAcctgDocItem
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_SupplierCompany as _SupplierCompany on $projection.Supplier = _SupplierCompany.Supplier
and $projection.CompanyCode = _SupplierCompany.CompanyCode
association [1..1] to I_FiscalYearPeriodForCmpnyCode as _FiscalYearPeriodForCmpnyCode on $projection.CompanyCode = _FiscalYearPeriodForCmpnyCode.CompanyCode
and $projection.FiscalYear = _FiscalYearPeriodForCmpnyCode.FiscalYear
and $projection.FiscalPeriod = _FiscalYearPeriodForCmpnyCode.FiscalPeriod
{
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeVH', element:'CompanyCode' } }]
@ObjectModel.foreignKey.association: '_CompanyCode'
key CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'
key FiscalYear,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_JournalEntryStdVH', element: 'AccountingDocument' },
additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode' },
{ localElement: 'FiscalYear', element: 'FiscalYear' }]
}]
@ObjectModel.foreignKey.association: '_JournalEntry'
key AccountingDocument as JournalEntry,
key AccountingDocumentItem,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_Supplier_VH', element:'Supplier' } }]
@Consumption.semanticObject: 'Supplier'
@ObjectModel.foreignKey.association: '_Supplier'
Supplier,
@Semantics.text: true
_Supplier.SupplierName,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
AmountInCompanyCodeCurrency,
_Supplier.SupplierAccountGroup,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_GLAcctInChtOfAcctsStdVH', element: 'GLAccount' },
additionalBinding: [{ localElement: 'ChartOfAccounts', element: 'ChartOfAccounts' }]
}]
@ObjectModel.foreignKey.association: '_GLAccountInCompanyCode'
GLAccount,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_AccountingDocumentTypeStdVH', element: 'AccountingDocumentType' } }]
@ObjectModel.text.association: '_AccountingDocumentTypeText'
@ObjectModel.foreignKey.association: '_AccountingDocumentType'
AccountingDocumentType,
PostingDate,
@Semantics.fiscal.yearPeriod: true
_FiscalYearPeriodForCmpnyCode.FiscalYearPeriod,
@Consumption.semanticObject: 'User'
@Semantics.user.id: true
_JournalEntry.AccountingDocCreatedByUser,
_JournalEntry.TransactionCode,
_JournalEntry.ReverseDocument,
_JournalEntry.DocumentReferenceID,
@ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
AccountingDocumentCategory,
@ObjectModel.foreignKey.association: '_ReferenceDocumentType'
ReferenceDocumentType,
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
@Semantics.currencyCode:true
CompanyCodeCurrency,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ChartOfAccountsStdVH', element: 'ChartOfAccounts' } }]
@ObjectModel.text.association: '_ChartOfAccountsText'
@ObjectModel.foreignKey.association: '_ChartOfAccounts'
ChartOfAccounts,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ControllingAreaStdVH', element: 'ControllingArea' } }]
@ObjectModel.text.element: ['ControllingAreaName']
@ObjectModel.foreignKey.association: '_ControllingArea'
ControllingArea,
@Semantics.text: true
_ControllingArea.ControllingAreaName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProfitCenterVH', element: 'ProfitCenter' },
additionalBinding: [{ localElement: 'ControllingArea', element: 'ControllingArea' }] }]
@ObjectModel.foreignKey.association: '_ProfitCenter'
ProfitCenter,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingArea', element: 'ControllingArea' }] }]
@ObjectModel.foreignKey.association: '_CostCenter'
CostCenter,
DocumentDate,
_JournalEntry.AccountingDocumentCreationDate as AccountingDocumentCreationDate,
_JournalEntry.LastChangeDate as LastChangeDate,
@ObjectModel.foreignKey.association: '_PostingKey'
PostingKey,
@ObjectModel.foreignKey.association: '_SpecialGLCode'
SpecialGLCode,
SpecialGLTransactionType,
@Semantics.text: true
_CompanyCode.CompanyCodeName as CompanyCodeName,
@Semantics.fiscal.yearVariant: true
_FiscalYearPeriodForCmpnyCode.FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalPeriod'
@Semantics.fiscal.period: true
FiscalPeriod,
@ObjectModel.foreignKey.association: '_DebitCreditCode'
DebitCreditCode,
@ObjectModel.text.association: '_FinancialAccountTypeText'
@ObjectModel.foreignKey.association: '_FinancialAccountType'
FinancialAccountType,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
@ObjectModel.foreignKey.association: '_Customer'
Customer,
IsCompletelyDelivered,
ClearingIsReversed,
IsSalesRelated,
IsUsedInPaymentTransaction,
_CompanyCode,
_FiscalYear,
_JournalEntry,
_Supplier,
_AccountingDocumentTypeText,
_AccountingDocumentType,
_GLAccountInCompanyCode,
_AccountingDocumentCategory,
_ReferenceDocumentType,
_CompanyCodeCurrency,
_ChartOfAccountsText,
_ChartOfAccounts,
_ControllingArea,
@Consumption.filter.businessDate.at: true
_ProfitCenter,
@Consumption.filter.businessDate.at: true
_CostCenter,
_PostingKey,
_SpecialGLCode,
_FiscalPeriod,
_DebitCreditCode,
_FinancialAccountTypeText,
_FinancialAccountType,
_Customer
}
where
FinancialAccountType = 'K'
and ClearingAccountingDocument = ''
and _SupplierCompany.DeletionIndicator = 'X'