C_MfgOrderObjPg

@AbapCatalog.sqlViewName: 'CMFGORDEROBJPAG'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manufacturing Order Object Page'
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata.allowExtensions: true
@Search.searchable: true
@Consumption.semanticObject: 'ProductionOrder'

@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ProductionOrder'
@ObjectModel.semanticKey: 'ProductionOrder'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}

/* UI annotations for header area of object page*/
@UI.headerInfo.typeName: 'Production Orders'
@UI.headerInfo.typeNamePlural: 'List of Production Orders'
@UI.headerInfo.title.label: 'Production Orders'
@UI.headerInfo.title.value: 'Material'
@UI.headerInfo.description.value: 'MaterialName'

define view C_MfgOrderObjPg
  as select from I_MfgOrderWithStatus

  association [0..*] to C_MfgOrderObjPgOpr      as _MfgOrderOperations // Operations

                                                                          on  $projection.ProductionOrder = _MfgOrderOperations.ManufacturingOrder
  association [0..*] to C_MfgOrderObjPgComp     as _MfgOrderComponents // Components

                                                                          on  $projection.ProductionOrder = _MfgOrderComponents.ManufacturingOrder
  association [0..*] to C_MfgOrderObjPgItem     as _MfgOrderItems // Items

                                                                          on  $projection.ProductionOrder = _MfgOrderItems.ManufacturingOrder

  association [0..*] to C_MfgOrderItemSerialNumber     as _MfgOrderItemSerialNumber   on  $projection.ProductionOrder = _MfgOrderItemSerialNumber.ManufacturingOrder

  association [0..*] to C_MfgOrderObjPgContacts as _MfgOrderContactDetails // Contact Details

                                                                          on  $projection.ProductionOrder = _MfgOrderContactDetails.ManufacturingOrder
  association [0..*] to I_MfgOrderObjPgStatus   as _MfgOrderSystemStatus // Status

                                                                          on  $projection.ProductionOrder = _MfgOrderSystemStatus.ManufacturingOrder
  association [0..*] to C_MfgOrderObjPgPRT      as _MfgOrderObjPgPRT //PRT

                                                                          on  $projection.ProductionOrder = _MfgOrderObjPgPRT.ManufacturingOrder
  association [0..*] to C_MfgOrdDocdGoodsMvt   as _MfgOrderDocGoodsMvt //Documented Goods movement

                                                                          on  $projection.ProductionOrder = _MfgOrderDocGoodsMvt.ManufacturingOrder
                                                                          and _MfgOrderDocGoodsMvt.ManufacturingOrderCategory = '10'
  association [1..1] to I_CostingVariant        as _PlannedCostingVariant on  $projection.PlannedCostsCostingVariant = _PlannedCostingVariant.CostingVariant

  association [1..1] to I_CostingVariant        as _ActualCostingVariant  on  $projection.ActualCostsCostingVariant = _ActualCostingVariant.CostingVariant

  association [0..1] to I_SystemStatusText      as _StatusTextI0001 // Status Created

                                                                          on  _StatusTextI0001.SystemStatus = 'I0001'
                                                                          and _StatusTextI0001.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0002 // Status Released

                                                                          on  _StatusTextI0002.SystemStatus = 'I0002'
                                                                          and _StatusTextI0002.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0009 // Status Confirmed

                                                                          on  _StatusTextI0009.SystemStatus = 'I0009'
                                                                          and _StatusTextI0009.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0010 // Status Partially confirmed

                                                                          on  _StatusTextI0010.SystemStatus = 'I0010'
                                                                          and _StatusTextI0010.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0012 // Status Delivered

                                                                          on  _StatusTextI0012.SystemStatus = 'I0012'
                                                                          and _StatusTextI0012.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0013 // Status Deleted

                                                                          on  _StatusTextI0013.SystemStatus = 'I0013'
                                                                          and _StatusTextI0013.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0016 // Status Pre-costed

                                                                          on  _StatusTextI0016.SystemStatus = 'I0016'
                                                                          and _StatusTextI0016.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0028 // Status Settlement rule created

                                                                          on  _StatusTextI0028.SystemStatus = 'I0028'
                                                                          and _StatusTextI0028.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0042 // Status Partially released

                                                                          on  _StatusTextI0042.SystemStatus = 'I0042'
                                                                          and _StatusTextI0042.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0045 // Status Technically completed

                                                                          on  _StatusTextI0045.SystemStatus = 'I0045'
                                                                          and _StatusTextI0045.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0046 // Status Closed

                                                                          on  _StatusTextI0046.SystemStatus = 'I0046'
                                                                          and _StatusTextI0046.Language     = $session.system_language
  association [0..1] to I_SystemStatusText      as _StatusTextI0076 // Status Marked for Deletion

                                                                          on  _StatusTextI0076.SystemStatus = 'I0076'
                                                                          and _StatusTextI0076.Language     = $session.system_language
  association [1..1] to I_Plant                 as _PlantProdOrder                 on  $projection.Plant = _PlantProdOrder.Plant
{

      //General Information

      @UI.dataPoint:{ title: 'Production Order'}
      @UI.selectionField.position: 10
      @Consumption.semanticObject: 'ProductionOrder'
      @UI.lineItem: [{position:10, type: #WITH_INTENT_BASED_NAVIGATION,semanticObjectAction: 'display'}]
      @UI.identification:[{position: 0}]
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @EndUserText.label: 'Production Order'
  key ManufacturingOrder                                                                                                                                                                                 as   ProductionOrder,

      @UI.selectionField.position: 20
      @UI.dataPoint:{ title: 'Production Plant'}
      @Consumption.semanticObject: 'ProductionPlant'
      @UI.lineItem: [{position:20, type: #WITH_INTENT_BASED_NAVIGATION,semanticObjectAction: 'display'}]
      @UI.identification:[{position:60}]

      ProductionPlant,
      @EndUserText.label: 'Operation Task List No.'
      MfgOrderInternalID as OrderInternalBillOfOperations,

      // Status on Header

      @UI.dataPoint: {title: 'Status'}

      case
        when OrderIsDeleted              = 'X'
            then _StatusTextI0013.SystemStatusName
        when OrderIsClosed               = 'X'
            then _StatusTextI0046.SystemStatusName
        when OrderIsTechnicallyCompleted = 'X'
            then _StatusTextI0045.SystemStatusName
        when OrderIsDelivered            = 'X'
            then _StatusTextI0012.SystemStatusName
        when OrderIsConfirmed            = 'X'
            then _StatusTextI0009.SystemStatusName
        when OrderIsPartiallyConfirmed   = 'X'
            then _StatusTextI0010.SystemStatusName
        when OrderIsMarkedForDeletion    = 'X'
            then _StatusTextI0076.SystemStatusName
        when OrderIsReleased             = 'X'
            then _StatusTextI0002.SystemStatusName
        when OrderIsPartiallyReleased    = 'X'
            then _StatusTextI0042.SystemStatusName
        when OrderIsCreated              = 'X'
            then _StatusTextI0001.SystemStatusName
        when OrderIsPreCosted = 'X'
            then _StatusTextI0016.SystemStatusName
        when SettlementRuleIsCreated = 'X'
            then _StatusTextI0028.SystemStatusName
       else ''
      end
                                                                                                                                                                                                         as   SystemStatusText,
      @Consumption.semanticObject: 'Material'
      @UI.lineItem: [{position:30, type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'display'}]
      @UI.identification:[{position: 10}] //Intent Based Navigation

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      Material,
      @UI.hidden: true
      _Material._Text[1: Language=$session.system_language].MaterialName                                                                                                                                 as   MaterialName,
      @Semantics.unitOfMeasure: true
      ProductionUnit,

      @UI.identification: [{position:20}]
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @UI.dataPoint: {title: 'Total Quantity'}
      MfgOrderPlannedTotalQty                                                                                                                                                                            as   TotalQuantity,
      @UI.identification: [{position:40}]
      @UI.selectionField.position: 30

      ManufacturingOrderType,
      @UI.identification: [{position:70}]

      MRPArea,

      ManufacturingObject,

      @UI.identification: [{position:80}]
      PlanningPlant                                                                                                                                                                                      as   Plant,

      @UI.identification: [{position:30}]
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedYieldQty,

      //Dates/Times

      @UI.lineItem: [{position:40}]

      @UI.fieldGroup: [{qualifier:'DateTime',position:10}]
      MfgOrderPlannedStartDate,

      @UI.lineItem: [{position:50}]
      @UI.fieldGroup: [{qualifier:'DateTime',position:20}]
      MfgOrderPlannedStartTime,

      @UI.lineItem: [{position:60}]
      @UI.fieldGroup: [{qualifier:'DateTime',position:30}]
      MfgOrderPlannedEndDate,

      @UI.lineItem: [{position:70}]
      @UI.fieldGroup: [{qualifier:'DateTime',position:40}]
      MfgOrderPlannedEndTime,

      @UI.fieldGroup: [{qualifier:'DateTime',position:50}]
      MfgOrderScheduledStartDate,

      @UI.fieldGroup: [{qualifier:'DateTime',position:60}]
      MfgOrderScheduledStartTime,

      @UI.fieldGroup: [{qualifier:'DateTime',position:70}]
      MfgOrderScheduledEndDate,

      @UI.fieldGroup: [{qualifier:'DateTime',position:80}]
      MfgOrderScheduledEndTime,
      @UI.fieldGroup: [{qualifier:'DateTime',position:90}]
      cast(_PlantProdOrder._OrganizationAddress[AddressRepresentationCode = ''].AddressTimeZone as co_plant_timezone ) as AddressTimeZone,
      @Consumption.semanticObject: 'ProductionVersion'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionVersionStdVH', element: 'ProductionVersion' } } ]
      @UI.lineItem: [{position:80, type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'display'}]
      @UI.fieldGroup: [{qualifier:'Assignments',position:5}]
//       @ObjectModel.foreignKey.association: '_ProductionVersion'

      ProductionVersion,

      @UI.fieldGroup: [{qualifier:'Assignments',position:10,type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'display'}]
      @UI.selectionField.position: 60
      @Consumption.semanticObject: 'SalesOrder'
      @UI.lineItem:[{type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'display'}] //Intent Based Navigation

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
      SalesOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderItemStdVH', element: 'SalesOrderItem' } } ]
      SalesOrderItem,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlannedOrderStdVH', element: 'PlannedOrder' } } ]
      PlannedOrder,
      @UI.fieldGroup: [{qualifier:'Assignments',position:20,type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'display'}]
      _SalesDocument._SoldToParty.CustomerName                                                                                                                                                               as   CustomerName,

      @UI.fieldGroup: [{qualifier:'Assignments',position:30, type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'displayFactSheet'}]
      @UI.selectionField.position: 70
      @Consumption.semanticObject: 'WBSElement'
//     /@ObjectModel.text.element: 'WBSDescription'

      cast( _WBSElement.WBSElement as rcpe_ps_posnr  preserving type )                                                                                                                                   as   WBSElement,
      @UI.hidden: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElmntByIntKeyStdVH', element: 'WBSElementInternalID' } } ]
      WBSElementInternalID,
      @Semantics.text: true
      _WBSElement.WBSDescription,

      @UI.fieldGroup: [{qualifier:'Assignments',position:40}]
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      CompanyCode,

      @UI.fieldGroup: [{qualifier:'Assignments',position:50}]
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      FunctionalArea,
      @UI.fieldGroup: [{qualifier:'Assignments',position:60}]
      @EndUserText.label: 'Planned Costing Variant'
      @ObjectModel.foreignKey.association: '_PlannedCostingVariant'
      @ObjectModel.text.element: 'CostingVariantName'
      PlannedCostsCostingVariant,
      @UI.hidden: true
      _PlannedCostingVariant._Text[1: Language=$session.system_language].CostingVariantName                                                                                                              as   CostingVariantName,

      @UI.fieldGroup: [{qualifier:'Assignments',position:70}]
      @EndUserText.label: 'Actual Costing Variant'
      @ObjectModel.foreignKey.association: '_ActualCostingVariant'
      @ObjectModel.text.element: 'TargetCostVariantName'
      ActualCostsCostingVariant,
      @UI.hidden: true
      _ActualCostingVariant._Text[1: Language=$session.system_language].CostingVariantName                                                                                                               as   TargetCostVariantName,
      @UI.fieldGroup: [{qualifier:'Assignments',position:75}]
      cast(OrderIsEventBasedPosting as mpe_ebpost)                                                                  as   OrderIsEventBasedPosting,


      _MRPController.UserID                                                                                                                                                                              as   UserID,
//      @Consumption.semanticObject: 'ProductionVersion'

//      @UI.fieldGroup:[{type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'manage', qualifier:'Assignments'}]

//      ProductionVersion,

      //Responsibilities


      @UI.fieldGroup: [{position:10,qualifier:'Responsibilities'}]
      @UI.selectionField.position: 40
      MRPController,

      @UI.fieldGroup: [{qualifier:'Responsibilities',position:20}]
      @UI.selectionField.position: 50
      @EndUserText.label: 'Production Supervisor'
      ProductionSupervisor,

      ManufacturingOrderCategory,

      _MfgOrderOperations,
      _MRPController,
      _MfgOrderComponents,
      _MfgOrderSystemStatus,
      _MfgOrderContactDetails,
      _MfgOrderObjPgPRT,
      _MfgOrderItems,
      _ProductionPlant as _Plant,
      _CompanyCode,
      _FunctionalArea,
      _ProductionSupervisor,
      _PlannedOrder,
      _SalesOrderItem,
      _MfgOrderCategory,
      _OrderInternalID as _OrdInternalBillOfOperations,
      _SalesOrder,
      _MRPArea,
      _WBSElement,
      _PlanningPlant as _MRPPlant,
      _Material,
      _MfgOrderType,
      _ProductionVersion,
      _PlannedCostingVariant,
      _ActualCostingVariant,
      _MfgOrderDocGoodsMvt,
      _MfgOrderItemSerialNumber,
      _PlantProdOrder
}

where
  ManufacturingOrderCategory = '10';