@AbapCatalog.sqlViewName: 'CMPEEXECHIST'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_MRPController', '_CreatedByUserContactCard', '_ProductionSupervisor', '_CreatedByUser', '_ExecutionUser', '_SASSchema' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:
{
usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED},
semanticKey: ['ManufacturingOrder', 'ManufacturingOrderOperation', 'OpActyNtwkElementExternalID', 'SerialNumber', 'ManufacturingExecutionDocument', 'MfgExecutionDocumentItem', 'MfgProcgExecAction']
}
@VDM.viewType: #CONSUMPTION
@VDM.private: false
@Metadata.allowExtensions: true
@EndUserText.label: 'Manufacturing Execution Event History'
define view C_MfgExecEventHistory
as select from P_MfgExecEventHistoryCnsmpn as h
association [0..1] to I_Plant as _WorkCenterPlant on $projection.WorkCenterPlant = _WorkCenterPlant.Plant
association [0..1] to I_WorkCenterBySemanticKey as _WorkCenterBySemanticKey on $projection.WorkCenterPlant = _WorkCenterBySemanticKey.Plant
and $projection.WorkCenter = _WorkCenterBySemanticKey.WorkCenter
association [0..*] to I_MfgProcgExecActionText as _MfgProcgExecActionText on $projection.MfgProcgExecAction = _MfgProcgExecActionText.MfgProcgExecAction
association [0..*] to I_MfgObjectLogEventTypeText as _MfgObjectLogEventTypeText on $projection.MfgExecDocumentCategory = 9
and $projection.MfgObjectLogEventType = _MfgObjectLogEventTypeText.MfgObjectLogEventType
association [0..1] to I_OpActyNtwkInternalID as _OpActyNtwkInternalId on $projection.OperationActivityNetwork = _OpActyNtwkInternalId.OperationActivityNetwork
association [0..1] to I_OperationActivityNetwork as _OperationActivityNetwork on $projection.OperationActivityNetwork = _OperationActivityNetwork.OperationActivityNetwork
and $projection.OpActyNtwkVersionCounter = _OperationActivityNetwork.OpActyNtwkVersionCounter
association [0..1] to I_OpActyNtwkSegmentTypeText as _OpActyNtwkSegmentTypeText on $projection.OpActyNtwkSegmentType = _OpActyNtwkSegmentTypeText.OpActyNtwkSegmentType
and _OpActyNtwkSegmentTypeText.Language = $session.system_language
association [0..*] to I_SASSchemaText as _SASSchemaText on $projection.StatusAndActionSchema = _SASSchemaText.StatusAndActionSchema
-- contact card
association [0..1] to I_UserContactCard as _CreatedByUserContactCard on $projection.ShopFloorExecutionUser = _CreatedByUserContactCard.ContactCardID
{
@Consumption.filter.hidden: true
//@Consumption.hidden: true
key h.MfgExecDocumentCategory as MfgExecDocumentCategory,
@Consumption.filter.hidden: true
//@Consumption.hidden: true
key h.ManufacturingExecutionDocument as ManufacturingExecutionDocument,
@Consumption.filter.hidden: true
//@Consumption.hidden: true
key h.MfgExecutionDocumentItem as MfgExecutionDocumentItem,
@ObjectModel.foreignKey.association: '_MfgProcgExecAction'
@ObjectModel.text.element: 'MfgProcgExecActionName'
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_MfgProcgExecActionVH', element: 'MfgProcgExecAction' } } ]
key h.MfgProcgExecAction as MfgProcgExecAction,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
key h.ManufacturingOrder as ManufacturingOrder,
key h.OrderOperationInternalID as OrderOperationInternalID,
key h.InspectionCharacteristic as InspectionCharacteristic,
key h.InspectionSubsetInternalID as InspectionSubsetInternalID,
key h.InspResultValueInternalID as InspResultValueInternalID,
key h.ChangeDocDatabaseTableField as ChangeDocDatabaseTableField,
key h.ChangeDocument as ChangeDocument,
-------------------------------------------------------------------------------------------------------
-- Administrative Data --------------------------------------------------------------------------------
@ObjectModel: {
virtualElement: true,
virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_MESSAGE'
}
h.MfgObjectLogEventType as MfgObjectLogEventType,
@Consumption.filter.hidden: true
h.SortField as SortField,
@Semantics.businessDate.at: true
h.EventDateTime as EventDateTime,
@ObjectModel.text.element: 'ShopFloorExecutionUserName'
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
h.ShopFloorExecutionUser as ShopFloorExecutionUser,
@Semantics.text: true
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
h.ShopFloorExecutionUserName as ShopFloorExecutionUserName,
@Semantics.systemDateTime.createdAt: true
h.CreationDateTime as CreationDateTime,
@Semantics.user.createdBy: true
h.CreatedByUser as CreatedByUser,
h.RespyMgmtTeamID as RespyMgmtTeamID,
@ObjectModel.text.element: 'RespyMgmtTeamDescription'
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as rsm_de_team_name) as RespyMgmtTeamName,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as rsm_de_team_descr) as RespyMgmtTeamDescription,
@ObjectModel.text.element: 'RespyMgmtFunctionDescription'
h.RespyMgmtFunction as RespyMgmtFunction,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as rsm_de_function_descr) as RespyMgmtFunctionDescription,
-------------------------------------------------------------------------------------------------------
-- Action Info ----------------------------------------------------------------------------------------
---- Message Data -------------------------------------------------------------------------------------
h.SystemMessageNumber as SystemMessageNumber,
h.SystemMessageIdentification as SystemMessageIdentification,
cast(h.MfgExecHistMsgVarblField1 as mpe_log_variable1 preserving type ) as MfgExecHistMsgVarblField1,
cast(h.MfgExecHistMsgVarblField2 as mpe_log_variable2 preserving type ) as MfgExecHistMsgVarblField2,
cast(h.MfgExecHistMsgVarblField3 as mpe_log_variable3 preserving type ) as MfgExecHistMsgVarblField3,
cast(h.MfgExecHistMsgVarblField4 as mpe_log_variable4 preserving type ) as MfgExecHistMsgVarblField4,
h.MfgProcgExecAttachmentName as MfgProcgExecAttachmentName,
@Semantics.text: true
@ObjectModel: {
virtualElement: true,
virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_MESSAGE'
}
cast( '' as mpe_action_message_description ) as SystemMessageDescription,
h.MfgBuyOffAction as MfgBuyOffAction,
---- Action Data --------------------------------------------------------------------------------------
@Semantics.text: true
cast( _MfgProcgExecActionText[1: Language=$session.system_language].MfgProcgExecActionName
as mpe_action_description_type ) as MfgProcgExecActionName,
@ObjectModel.foreignKey.association: '_SASSchema'
@Consumption.filter.hidden: true
h.StatusAndActionSchema as StatusAndActionSchema,
h.PostingIsRetroactive as PostingIsRetroactive,
---- Quantity Data ------------------------------------------------------------------------------------
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
h.BusinessProcessConfirmedQty as BusinessProcessConfirmedQty,
@Semantics.unitOfMeasure: true
-- @ObjectModel.text.element: 'UnitOfMeasureName'
h.ProductionUnit as ProductionUnit,
-- @Semantics.text: true
-- UI.hidden: true
-- h._ProductionUnit._Text[1: Language=$session.system_language].UnitOfMeasureName as UnitOfMeasureName,
---- Duration Data ------------------------------------------------------------------------------------
@Semantics.durationInSeconds: true
h.OpActyActualDurnInSeconds as OpActyActualDurnInSeconds,
@Semantics.quantity.unitOfMeasure: 'ActualDurationUnit'
@ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_MPE_OA_ACTL_EXEC_DURN' }
cast(0 as mpe_status_duration_quan) as ActualDuration,
@ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_MPE_OA_ACTL_EXEC_DURN' }
@Semantics.unitOfMeasure: true
cast('' as durationunit) as ActualDurationUnit,
---- Component Data -----------------------------------------------------------------------------------
--@ObjectModel.foreignKey.association: '_MaterialComponent'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material'} } ]
@ObjectModel.text.element: 'MaterialComponentName'
--@Consumption.semanticObject: 'Material'
h.MaterialComponent as MaterialComponent,
@Semantics.text: true
h.MaterialComponentName as MaterialComponentName,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material'} } ]
@ObjectModel.text.element: 'SubstitutedProductName'
h.SubstitutedProduct as SubstitutedProduct,
@Semantics.text: true
h.SubstitutedProductName as SubstitutedProductName,
h.AlternativeItemGroup as AlternativeItemGroup,
---- Assembly Data ------------------------------------------------------------------------------------
@ObjectModel.foreignKey.association: '_AssembledShopFloorItem'
h.AssembledShopFloorItem as AssembledShopFloorItem,
h.AssembledSerialNumber as AssembledSerialNumber,
h.AssembledMfrSerialNumber as AssembledMfrSerialNumber,
h.AssembledBatch as AssembledBatch,
h.ReplacedShopFloorItem as ReplacedShopFloorItem,
h.ReplacedSerialNumber as ReplacedSerialNumber,
h.ReplacedBatch as ReplacedBatch,
h.MfgOrderSplitChildOrder as MfgOrderSplitChildOrder,
h.BOMExplosionDate as BOMExplosionDate,
@ObjectModel: {
virtualElement: true,
virtualElementCalculatedBy: 'ABAP:CL_MPE_ASSLDBATCHBYSUPPLIER_VE'
}
cast(' ' as lichn preserving type ) as AssembledBatchBySupplier,
h.ReferenceDesignatorValue as ReferenceDesignatorValue,
@ObjectModel.text.element: 'StorageLocationName'
@ObjectModel.foreignKey.association: '_StorageLocation'
h.StorageLocation as StorageLocation,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as lgort_name) as StorageLocationName,
--h._StorageLocation.StorageLocationName as StorageLocationName,
@ObjectModel.text.element: 'InventoryUsabilityCodeName'
h.InventoryUsabilityCode as InventoryUsabilityCode,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as mpe_insmk_name) as InventoryUsabilityCodeName,
--h._PlannedInvtryUsblyCodeText[1: Language=$session.system_language].PlannedInvtryUsabilityCodeName as InventoryUsabilityCodeName,
@ObjectModel.text.element: 'CompDisassemblyPermanenceName'
h.CompDisassemblyPermanence as CompDisassemblyPermanence,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as mpe_disassembly_permanence_nam) as CompDisassemblyPermanenceName,
h.MaterialComponentHasReltdComp as MaterialComponentHasReltdComp,
---- Equipment ----------------------------------------------------------------------------------------
h.Equipment as Equipment,
---- Reason Code Data ---------------------------------------------------------------------------------
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_MfgActnRsnCodeGrpCtlgVH', element: 'MfgActionReasonCodeGroupCtlg'} } ]
h.MfgActionReasonCodeGroupCtlg as MfgActionReasonCodeGroupCtlg,
--@ObjectModel.foreignKey.association: '_MfgActionReasonCodeGroup'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgActnRsnCodeGrpStdVH', element: 'MfgActionReasonCodeGroup'} } ]
--@Consumption.semanticObject: 'ManufacturingActionReasonGroup'
h.MfgActionReasonCodeGroup as MfgActionReasonCodeGroup,
--@ObjectModel.foreignKey.association: '_MfgActionReasonCode'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgActionReasonCodeStdVH', element: 'ManufacturingActionReasonCode' } } ]
@ObjectModel.text.element: 'MfgActionReasonCodeName'
--@Consumption.semanticObject: 'ManufacturingActionReason'
h.ManufacturingActionReasonCode as ManufacturingActionReasonCode,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as qtxt_code) as MfgActionReasonCodeName,
--h._MfgActionReasonCode._Text[1: Language=$session.system_language].MfgActionReasonCodeName as MfgActionReasonCodeName,
cast(h.MfgExecDocReasonCodeIsExisting as boolean preserving type ) as MfgExecDocReasonCodeIsExisting,
---- Note Data ----------------------------------------------------------------------------------------
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_MESSAGE'
cast('' as mpe_note_exists preserving type) as MfgExecDocNoteIsExisting,
@Semantics.text: true
h.MfgExecutionDocumentNote as MfgExecutionDocumentNote,
---- SFI@OA-Group Data --------------------------------------------------------------------------------
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_OpActivitySFIGroupStdVH', element: 'OperationActivitySFIGroup' } } ]
@ObjectModel.text.element: 'OpActySFIGroupName'
h.OperationActivitySFIGroup as OperationActivitySFIGroup,
@Semantics.text: true
h._OperationActivitySFIGroup.OpActySFIGroupName as OpActySFIGroupName,
-------------------------------------------------------------------------------------------------------
-- Organizational Data --------------------------------------------------------------------------------
---- Production Plant ---------------------------------------------------------------------------------
--@ObjectModel.foreignKey.association: '_ProductionPlant'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant'} } ]
@ObjectModel.text.element: 'ProductionPlantName'
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 1}
h.ProductionPlant as ProductionPlant,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as werks_name) as ProductionPlantName,
--h._ProductionPlant.PlantName as ProductionPlantName,
---- Production Supervisor-----------------------------------------------------------------------------
@ObjectModel.foreignKey.association: '_ProductionSupervisor'
cast(h.ProductionSupervisor as mpe_fevor preserving type) as ProductionSupervisor,
---- MRP Plant ----------------------------------------------------------------------------------------
@ObjectModel.foreignKey.association: '_MRPPlant'
h.MRPPlant as MRPPlant,
---- MRP Controller -----------------------------------------------------------------------------------
@ObjectModel.foreignKey.association: '_MRPController'
h.MRPController as MRPController,
---- Work Center Data ---------------------------------------------------------------------------------
h.WorkCenterInternalID as WorkCenterInternalID,
@ObjectModel.foreignKey.association: '_WorkCenterType'
h.WorkCenterTypeCode as WorkCenterTypeCode,
--@ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_WrkCtrBySemanticKeyStdVH', element: 'WorkCenter'} } ]
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
--@Consumption.semanticObject: 'WorkCenter'
_WorkCenter.WorkCenter as WorkCenter,
--@ObjectModel.foreignKey.association: '_WorkCenterPlant'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant'} } ]
@ObjectModel.text.element: 'WorkCenterPlantName'
h.WorkCenterPlant as WorkCenterPlant,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as werks_name) as WorkCenterPlantName,
--_WorkCenterPlant.PlantName as WorkCenterPlantName,
h.DefectInternalID as DefectInternalID,
h.Notification as Notification,
h.NotificationItem as NotificationItem,
-------------------------------------------------------------------------------------------------------
-- Order Reference Data -------------------------------------------------------------------------------
---- Order Header Data --------------------------------------------------------------------------------
h.ManufacturingOrderText as ManufacturingOrderText,
h.ManufacturingOrderType as ManufacturingOrderType,
h.ManufacturingOrderCategory as ManufacturingOrderCategory,
h.OrderInternalID as OrderInternalID,
@Semantics.text: true
-- For performance reading when accessing JEST, this is done as virtual element
@ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_MPE_MAIN_STATUS_NAME' }
cast( '' as mpe_order_main_status_text ) as OrderMainStatusName,
--@ObjectModel.foreignKey.association: '_Material'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material'} } ]
@ObjectModel.text.element: 'MaterialName'
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
--@Consumption.semanticObject: 'Material'
h.Material as Material,
@Semantics.text: true
h.MaterialName as MaterialName,
---- Order Operation Data -----------------------------------------------------------------------------
--@ObjectModel.foreignKey.association: '_MfgOrderSequence'
--@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
--@UI.fieldGroup.qualifier: 'ORDER'
--@UI.fieldGroup.position: 40
--@UI.hidden: true -- Since at least for the time being MPE Orders just have the standard sequence
--h.ManufacturingOrderSequence as ManufacturingOrderSequence,
@ObjectModel.text.element: 'MfgOrderOperationText'
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.95}
h.ManufacturingOrderOperation as ManufacturingOrderOperation,
@Semantics.text: true
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
h.MfgOrderOperationText as MfgOrderOperationText,
@Semantics.text: true
@ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_MPE_MAIN_STATUS_NAME' }
-- For performance reading when accessing JEST, this is done as virtual element
cast( '' as mpe_oper_main_status_text ) as OrderOperationMainStatusName,
---- Operation Activity Data --------------------------------------------------------------------------
@ObjectModel.text.element: 'OpActyNtwkSegmentTypeText'
@ObjectModel.foreignKey.association: '_OpActyNtwkSegmentType'
h.OpActyNtwkSegmentType as OpActyNtwkSegmentType,
@Semantics.text: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_ACTION_LOG_BUFD_TBL_ACC'
cast('' as mpe_oan_segment_type_name) as OpActyNtwkSegmentTypeText,
--cast(h._OpActyNtwkSegmentType._Text[1: Language=$session.system_language].OpActyNtwkSegmentTypeText
-- as mpe_oan_segment_type_name preserving type ) as OpActyNtwkSegmentTypeText,
@ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInstanceStdVH', element: 'OpActyNtwkInstance'} } ]
h.OpActyNtwkInstance as OpActyNtwkInstance,
@ObjectModel.foreignKey.association: '_OperationActivityInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyInstceStdVH', element: 'OpActyNtwkElement'} } ]
h.OpActyNtwkElement as OpActyNtwkElement,
@ObjectModel.foreignKey.association: '_OpActyNtwkInternalId'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInternalIDStdVH', element: 'OperationActivityNetwork'} } ]
h.OperationActivityNetwork as OperationActivityNetwork,
@ObjectModel.foreignKey.association: '_OperationActivityNetwork'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OANStdVH', element: 'OpActyNtwkVersionCounter'} } ]
h.OpActyNtwkVersionCounter as OpActyNtwkVersionCounter,
@Semantics.text: true
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
h.OperationActivityName as OperationActivityName,
--@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.95}
@ObjectModel.text.element: 'OperationActivityName'
cast(h.OpActyNtwkElementExternalID as mpe_oa_number_ext preserving type) as OpActyNtwkElementExternalID,
---- SFI Data -----------------------------------------------------------------------------------------
@ObjectModel.foreignKey.association: '_ShopFloorItem'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShopFloorItemStdVH', element: 'ShopFloorItem'} } ]
h.ShopFloorItem as ShopFloorItem,
--@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.95}
h._ShopFloorItem.SerialNumber as SerialNumber,
---- Buyoff & Defect Data---------------------------------------------------------------------------------------
h.Defect as Defect,
h.DefectText as DefectText,
h.QltyTaskFollowUpAction as QltyTaskFollowUpAction,
cast(case
when h.MfgExecDocumentCategory = 4 then case
when h.MfgBuyOffReferencedStep = 0 then h.MfgBuyOffDescription
else h.MfgBuyOffAdhocStepDescription
end
else h.MfgBuyOffDescription
end as mpe_buyoffsqnc_desc preserving type) as MfgBuyOffDescription,
h.MfgBuyOffCycle as MfgBuyOffCycle,
---- Inspection Characteristics Data-----------------------------------------------------------------------------------------
h.InspectionSpecificationText as InspectionSpecificationText,
h.ChangeDocPreviousFieldValue as ChangeDocPreviousFieldValue,
h.ChangeDocNewFieldValue as ChangeDocNewFieldValue,
h.InspectionResultMeanValue as InspectionResultMeanValue,
h.InspectionResultMeasuredValue as InspectionResultMeasuredValue,
h.CharacteristicAttributeCode as CharacteristicAttributeCode,
h.InspectionValuationResult as InspectionValuationResult,
@Semantics.unitOfMeasure: true
h.InspectionSpecificationUnit as InspectionSpecificationUnit,
h.InspSpecDecimalPlaces as InspSpecDecimalPlaces,
-------------------------------------------------------------------------------------------------------
-- Associations ---------------------------------------------------------------------------------------
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_CreatedByUser,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ExecutionUser,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgOrder,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgOrderType,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgOrderCategory,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgOrderOperation,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OpActyNtwkInstance,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OperationActivityInstance,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ShopFloorItem,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_AssembledShopFloorItem,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgProcgExecAction,
// _MfgObjectLogEventType,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ProductionUnit,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgActionReasonCodeGroupCtlg,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgActionReasonCodeGroup,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgActionReasonCode,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ManufacturingObjectLog,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OpActyConfirmationAction,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OpActyNtwkSegmentType,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ShopFloorItemConfirmation,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgOrderComponentAssembly,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OpActyNtwkElement,
--@UI.fieldGroup.exclude: true
--@Consumption.filter.hidden: true
--_MfgOrderSequence,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ProductionPlant,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MRPPlant,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_StorageLocation,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_Material,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MaterialComponent,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_WorkCenter,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_WorkCenterType,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MRPController,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_ProductionSupervisor,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_WorkCenterBySemanticKey,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_WorkCenterPlant,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgProcgExecActionText,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_MfgObjectLogEventTypeText,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OpActyNtwkInternalId,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OperationActivityNetwork,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_OpActyNtwkSegmentTypeText,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_SASSchema,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_SASSchemaText,
@Consumption.filter.hidden: true
_CreatedByUserContactCard,
@UI.fieldGroup.exclude: true
@Consumption.filter.hidden: true
_PlannedInvtryUsblyCodeText
}