C_MaterialDocumentSerialNoFDP

DDL: C_MATERIALDOCUMENTSERIALNOFDP Type: view CONSUMPTION

Material Document Serial Numbers Output Forms

C_MaterialDocumentSerialNoFDP is a Consumption CDS View that provides data about "Material Document Serial Numbers Output Forms" in SAP S/4HANA. It reads from 2 data sources (I_MaintenanceItemObject, I_MaintItmObjListMaterialDoc) and exposes 14 fields with key fields Material, SerialNumber, MaterialDocument, MaterialDocumentItem, MaterialDocumentYear. It has 2 associations to related views.

2 data source(s) 14 fields

Data Sources (2)

SourceAliasJoin Type
I_MaintenanceItemObject _MaintenanceItemObject inner
I_MaintItmObjListMaterialDoc _SerialMaterialDoc from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_Material _Material $projection.Material = _Material.Material
[0..1] I_Equipment _Equipment $projection.Equipment = _Equipment.Equipment

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CMATDOCSERNUMFDP view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #NOT_REQUIRED view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #CONSUMPTION view
VDM.lifecycle.contract.type #NONE view
Search.searchable true view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Material Document Serial Numbers Output Forms view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY Material Material
KEY SerialNumber SerialNumber
KEY MaterialDocument MaterialDocument
KEY MaterialDocumentItem MaterialDocumentItem
KEY MaterialDocumentYear MaterialDocumentYear
Equipment Equipment
Plant _MaterialDocumentItem Plant
StorageLocation _MaterialDocumentItem StorageLocation
GoodsMovementType _MaterialDocumentItem GoodsMovementType
PurchaseOrder _MaterialDocumentItem PurchaseOrder
PurchaseOrderItem _MaterialDocumentItem PurchaseOrderItem
_MaterialDocumentItem _MaterialDocumentItem
_Material _Material
_Equipment _Equipment 
/*
  This CDS View is consumed in Form Data Providers to fetch Serial Numbers with additional details
*/

@AbapCatalog: {
                sqlViewName: 'CMATDOCSERNUMFDP',
                compiler.compareFilter: true,
                preserveKey: true
              }

@AccessControl: {
                  authorizationCheck: #CHECK,
                  personalData.blocking: #NOT_REQUIRED
                 }

@ObjectModel: {
                usageType: {
                             sizeCategory: #XL,
                             serviceQuality: #C,
                             dataClass:#TRANSACTIONAL
                           },
                supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                        #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE]
               }

@VDM: {
        viewType: #CONSUMPTION,
        lifecycle.contract.type: #NONE
      }

@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Material Document Serial Numbers Output Forms'

define view C_MaterialDocumentSerialNoFDP
  as select from I_MaintItmObjListMaterialDoc as _SerialMaterialDoc

    inner join   I_MaintenanceItemObject      as _MaintenanceItemObject on _SerialMaterialDoc.MaintenanceItemObjectList = _MaintenanceItemObject.MaintenanceItemObjectList

  association[0..1] to I_MaterialDocumentItem_2 as _MaterialDocumentItem  on  $projection.MaterialDocument     = _MaterialDocumentItem.MaterialDocument
                                                                          and $projection.MaterialDocumentItem = _MaterialDocumentItem.MaterialDocumentItem
                                                                          and $projection.MaterialDocumentYear = _MaterialDocumentItem.MaterialDocumentYear

  association [1..1] to I_Material               as _Material             on  $projection.Material = _Material.Material

  association [0..1] to I_Equipment              as _Equipment            on  $projection.Equipment = _Equipment.Equipment
{
      @ObjectModel.foreignKey.association: '_Material'
  key Material,
  key SerialNumber,
  key MaterialDocument,
  key MaterialDocumentItem,
  key MaterialDocumentYear,
      @ObjectModel.foreignKey.association: '_Equipment'
      Equipment,
      _MaterialDocumentItem.Plant             as Plant,
      _MaterialDocumentItem.StorageLocation   as StorageLocation,
      _MaterialDocumentItem.GoodsMovementType as GoodsMovementType,
      _MaterialDocumentItem.PurchaseOrder     as PurchaseOrder,
      _MaterialDocumentItem.PurchaseOrderItem as PurchaseOrderItem,

      /* Associations */
      _MaterialDocumentItem,
      _Material,
      _Equipment
}

Learn More